build.bat

手机控制邮件以及附件的发送

@echo off


rem Should have the following variables set:
rem
rem  set JAVA_HOME=<path to J2SDK installation root>
rem  set TOMCAT_HOME=<path to jwsdp-1.2 installation root> 

set PATH=%TOMCAT_HOME%/bin;%TOMCAT_HOME%/jaxrpc/bin;%JAVA_HOME%/bin;%TOMCAT_HOME%\jwsdp-shared\bin

rem check variables correctness
if ""%TOMCAT_HOME%""=="""" goto no_tomcat
if not exist %TOMCAT_HOME%\jaxrpc\bin\wscompile.bat goto no_tomcat2
if ""%JAVA_HOME%""=="""" goto no_java
if not exist %JAVA_HOME%/bin/javac.exe goto no_java2

mkdir WEB-INF
mkdir WEB-INF\classes
echo running javac.exe
javac.exe -d WEB-INF\classes -classpath .\lib\jaxrpc-api.jar;.\lib\servlet-api.jar;.\lib\mail.jar;.\lib\activation.jar src\remote\*.java 
if NOT %ERRORLEVEL%==0 goto error

mkdir tmp_src 
echo running wscompile.bat
call wscompile.bat -gen:server -d WEB-INF\classes -keep -model WEB-INF\model.gz  -s tmp_src -f:wsi -f:documentliteral -classpath WEB-INF\classes src\config.xml
if NOT %ERRORLEVEL%==0 goto error

copy src\web.xml WEB-INF
copy src\jaxrpc-ri.xml WEB-INF
echo running jar.exe
jar.exe -cf remote.jar WEB-INF
echo running wsdeploy.bat
call wsdeploy.bat remote.jar -o remote.war

goto exit

:no_tomcat
 echo TOMCAT_HOME variable is not set
:no_tomcat2
 echo TOMCAT_HOME should point to JWSDP-1.2 installation
 echo You can download it from:
 echo http://java.sun.com/webservices/downloads/webservicespack.html
 goto error

:no_java
 echo JAVA_HOME variable is not set
:no_java2
 echo JAVA_HOME should point to J2SDK installation
:error
:exit
 pause