akiglcd.inc

AVR单片机实现FFT

.macro	FMULS16	;19clk
	fmuls	@0H, @1H
	movw	@2L, T0L
	fmul	@0L, @1L
	movw	@3L, T0L
	adc	@2L, _0
	fmulsu	@0H, @1L
	sbc	@2H, _0
	add	@3H, T0L
	adc	@2L, T0H
	adc	@2H, _0
	fmulsu	@1H, @0L
	sbc	@2H, _0
	add	@3H, T0L
	adc	@2L, T0H
	adc	@2H, _0
.endmacro


.macro	SQRT32	;526..542clk
	clr	T6L
	clr	T6H
	clr	T8L
	clr	T8H
	ldi	AL, 1
	ldi	AH, 0
	clr	BL
	clr	BH
	ldi	CL, 16
	lsl	T2L
	rol	T2H
	rol	T4L
	rol	T4H
	rol	T6L
	rol	T6H
	rol	T8L
	rol	T8H
	lsl	T2L
	rol	T2H
	rol	T4L
	rol	T4H
	rol	T6L
	rol	T6H
	rol	T8L
	rol	T8H
	brpl	PC+6
	add	T6L, AL
	adc	T6H, AH
	adc	T8L, BL
	adc	T8H, BH
	rjmp	PC+5
	sub	T6L, AL
	sbc	T6H, AH
	sbc	T8L, BL
	sbc	T8H, BH
	lsl	AL
	rol	AH
	rol	BL
	andi	AL, 0b11111000
	ori	AL, 0b00000101
	sbrc	T8H, 7
	subi	AL, 2
	dec	CL
	brne	PC-34
	lsr	BL
	ror	AH
	ror	AL
	lsr	BL
	ror	AH
	ror	AL
.endmacro


.macro	SQRT16	;176..184clk
	clr	T4L
	clr	T4H
	ldi	AL, 1
	ldi	AH, 0
	ldi	BL, 8
	lsl	T2L
	rol	T2H
	rol	T4L
	rol	T4H
	lsl	T2L
	rol	T2H
	rol	T4L
	rol	T4H
	brpl	PC+4
	add	T4L, AL
	adc	T4H, AH
	rjmp	PC+3
	sub	T4L ,AL
	sbc	T4H ,AH
	lsl	AL
	rol	AH
	andi	AL, 0b11111000
	ori	AL, 0b00000101
	sbrc	T4H, 7
	subi	AL, 2
	dec	BL
	brne	PC-21
	lsr	AH
	ror	AL
	lsr	AH
	ror	AL
.endmacro