configure.in.in

将konqueror浏览器移植到ARM9 2410中

dnl KDE JavaScript specific configure tests

AC_CHECK_HEADERS(ieeefp.h float.h)
AC_CHECK_LIB(m, isinf, [
  AC_DEFINE_UNQUOTED(HAVE_FUNC_ISINF, 1, [Define if you have isinf])
])
AC_CHECK_LIB(m, finite, [
  AC_DEFINE_UNQUOTED(HAVE_FUNC_FINITE, 1, [Define if you have finite])
])
AC_CHECK_LIB(m, _finite, [
  AC_DEFINE_UNQUOTED(HAVE_FUNC__FINITE, 1, [Define if you have _finite])
])
AC_CHECK_LIB(m, isnan, [
  AC_DEFINE_UNQUOTED(HAVE_FUNC_ISNAN, 1, [Define if you have isnan])
])

AC_DEFUN(AC_CHECK_PCREPOSIX,
[
  AC_MSG_CHECKING([for pcreposix])
  AC_CACHE_VAL(ac_cv_have_pcreposix,
  [
    ac_save_libs="$LIBS"
    KDE_FIND_PATH(pcre-config, PCRE_CONFIG, [${prefix}/bin /usr/local/bin /opt/local/bin], [PCRE_CONFIG="" ])
    if test -n "$PCRE_CONFIG" && $PCRE_CONFIG --libs >/dev/null 2>&1; then
        LIBS=`$PCRE_CONFIG --libs --libs-posix`
        CPPFLAGS="$CPPFLAGS `$PCRE_CONFIG --cflags`"
    else
        LIBS="-lpcre -lpcreposix"
    fi
    ac_CPPFLAGS_save="$CPPFLAGS"
    CPPFLAGS="$CPPFLAGS $all_includes"
    ac_LDFLAGS_save="$LDFLAGS"
    LDFLAGS="$LDFLAGS $all_libraries"
    AC_TRY_LINK(
      [#include <pcreposix.h>],
      [regfree(0);],
      [ac_cv_have_pcreposix="yes"],
      [ac_cv_have_pcreposix="no"]
    )
    LIBS="$ac_save_libs"
    LDFLAGS="$ac_LDFLAGS_save"
    CPPFLAGS="$ac_CPPFLAGS_save"
  ])
  AC_MSG_RESULT($ac_cv_have_pcreposix)
  if test "$ac_cv_have_pcreposix" = "yes"; then
    LIBPCRE="-lpcre -lpcreposix"
    AC_DEFINE(HAVE_PCREPOSIX, 1, [Define if you have pcreposix libraries and header files.])
  fi
])
AC_CHECK_PCREPOSIX
AC_SUBST(LIBPCRE)