将vfp的dbf导出到word.prg

EXCEL、dbf、word文件互转.rar VFP环境下文件转换原码

Clear All
Close All
lcFile=Getfile('Dbf')
If Len(lcFile)=0
	Return
Endif
llUse=.T.
Select 0
Try
	Use (lcFile) Excl
Catch
	llUse=.F.
Finally
Endtry
If llUse=.F.
	Messagebox( "打开文件出错！",0+64,"宏伟软件")
	Return
Endif
Wait "正在访问 Word 软件……" Window Nowait
llWord=.T.
Try
	WordApp=Createobject("Word.application") &&访问WORD
Catch
	llWord=.F.
Finally
Endtry
If llWord=.F.
	Messagebox( "访问Word失败！请检查你的系统是否正确安装 Word 软件！",0+64,"宏伟软件")
	Return
Endif
Wait "正在生成表格……" Window Nowait
WordApp.Visible =.F.
WordApp.Caption ='宏伟软件制作 VFP表 导出到Word'
WordApp.Documents.Add
WordApp.Documents(1).Range.Text=Alias()
WordApp.Documents(1).Range.Font.Size=15
WordApp.Documents(1).Range.Font.Name="黑体"
WordApp.Documents(1).Range.Paragraphs.Alignment= 1
WordAppRang=WordApp.Documents(1).Range(Lenc(WordApp.Documents(1).Range.Text)-1,Lenc(WordApp.Documents(1).Range.Text)-1)
WordTable=WordApp.Documents(1).Tables.Add(WordAppRang,Reccount()+1,Fcount())
WordTable.Range.Paragraphs.Alignment= 0
WordTable.Range.Font.Name="宋体"
WordTable.Range.Font.Size=11
WordTable.BorderS.Enable=1
WordTable.BorderS(1).LineWidth = 12
WordTable.BorderS(2).LineWidth = 12
WordTable.BorderS(3).LineWidth = 12
WordTable.BorderS(4).LineWidth = 12
WordTable.Rows(1).BorderS(3).LineWidth = 12
WordTable.Rows(1).Range.Font.Bold=.T.
WordTable.Rows(1).Cells.VerticalAlignment= 1
WordTable.Rows(1).Range.Paragraphs.Alignment = 1
WordTable.Rows(1).HeadingFormat=.T.

For i=1 To Fcount()
	WordTable.Cell(1,i).Range.Text=Field(i)
	For i2=2 To Reccount()+1
		Go i2-1
		WordCellText=Evaluate(Field(i))
		Do Case
		Case Isnull(WordCellText)
			WordCellText=""
		Case Type("WordCellText")="N"
		Case Type("WordCellText")="D"
			WordCellText=Dtoc(WordCellText)
		Case Type("WordCellText")="T"
			WordCellText=Ttoc(WordCellText)
		Case Empty(WordCellText)
			WordCellText=""
		Otherwise
* WordCellText=""
		Endcase
		WordTable.Cell(i2,i).Range.Text=WordCellText
	Next
	WordTable.Columns(i).AutoFit
Next
WordApp.Visible=.T.
Return