⭐ 欢迎来到虫虫下载站！ | 📦 资源下载 📁 资源专辑 ℹ️ 关于我们
⭐ 虫虫下载站
📤 上传资源

📄 admin_skin.asp

📁 本系统是一套开源WEB的网站管理系统
💻 ASP
字号:
🔍 
<!--#include file="admin_conn.asp"-->
<!--#include file="../include/admin_setting.asp"-->
<!--#include file="admin_function.asp"-->
<%
'==============================================================
'程序名称：茂盛网站管理系统(Maoin CSM)
'当前版本：Maosin CMS Version 1.1   Powered by maosin.com
'程序作者：阿茂（李胜茂）
'网站地址：www.maosin.com   www.maosin.net
'      QQ：57861417  
'电子邮箱：maosin@163.com  maosin@maosin.com
'--------------------------------------------------------------
'Copyright (C) 2006 maosin.com All Rights Reserved.
'免费版本请在程序首页保留(Powered by：Maosin CMS)版权链接信息；
'您可以对此版本进行修改，美化，但请保留此ASP文件内的版权信息；
'茂盛设计网保留此软件的法律追究权利
'==============================================================
Call admin_top()
Call navMenu()
dim skinPath,xmlPath,xslPath
skinPath=Server.MapPath("../skins/")
xmlPath=Server.MapPath("../skins/skin.maosin")
xslPath=Server.MapPath("../skins/admin_skin.xslt")
if getPopedom("skinAdmin")=false then
	popedomMsg
else
Select Case Lcase(Request("action"))
	Case Lcase("skinSet")
		Call skinSet()
	Case Lcase("addSkin")
		Call addSkin()
	Case Lcase("reName")
		Call reName()
	Case Lcase("copySkin")
		Call copySkin()
	Case Lcase("delSkin")
		Call delSkin()
	Case Lcase("editSkin")
		Call editSkin()
	Case Lcase("saveSkin")
		Call saveSkin()
	Case Lcase("delFile")
		Call delFile()
	Case Else
		Call adminSkin()
End Select
end if	 
Call admin_foot()
Sub navMenu()%>
<table width="100%" border="0" cellpadding="3" cellspacing="1" class="text table_border mainTable">
  <tr><td colspan="2" class="td_titleT">其它管理</td></tr>
  <tr><td width="95" height="30" class="td_bgcolor">管理快捷导航：</td><td class="td_bgcolor">
  <a href="admin_file.asp">栏目公共上传文件管理</a>&nbsp;|&nbsp;
  <a href="admin_datafile.asp">数据库备份文件管理</a>&nbsp;|&nbsp;
  <a href="admin_skin.asp">网站样式风格管理</a>
  </td></tr>
</table>
<%table(5)
End Sub
Sub adminSkin()
dim xml,xsl
set xml=Server.CreateObject("Microsoft.XMlDOM")
xml.async="false"
xml.load(xmlPath)
set xsl=Server.CreateObject("Microsoft.XMLDOM")
xsl.async="false"
xsl.load(xslPath)
response.write(xml.transformNode(xsl))
set xml=nothing
set xsl=nothing
End Sub

Sub skinSet()
dim id,url,xml,xsl
id=Request("id")
url=Request("url")
set xml=Server.CreateObject("Microsoft.XMLDOM")
xml.async="false"
xml.load(xmlPath)
set xmlroot=xml.documentElement
xmlroot.getattributeNode("default").value=url
xml.save(xmlPath)
set xml=nothing
response.Redirect Request.ServerVariables("HTTP_REFERER")
End Sub
Sub addSkin()
dim skinName,skinUrl,xml,xmlroot,skinObj,id
skinName=Request("skinName")
skinUrl=Request("skinUrl")
set xml=Server.CreateObject("Microsoft.XMLDOM")
xml.async="false"
xml.load(skinPath&"\"&"skin.xml")
set xmlroot=xml.documentElement
if xmlroot.hasChildNodes then
	id=cint(xmlroot.lastChild.getAttributeNode("id").value)+1
else
	id=1
end if
set skinObj=xml.createElement("skin")
skinObj.text=skinName
skinObj.setAttribute "id",id
skinObj.setAttribute "url",skinUrl
xmlroot.appendChild(skinObj)
xml.save(skinPath&"\"&"skin.xml")
Set fso=Server.CreateObject("Scripting.FileSystemObject")
if not fso.folderExists(skinPath&"\"&skinUrl) then
fso.CreateFolder(skinPath&"\"&skinUrl)
end if
set fso=nothing
response.Redirect Request.ServerVariables("HTTP_REFERER")
End Sub
Sub reName()
	dim id,skinName,xml
	id=trim(Request("skinOption"))
	skinName=trim(Request("skinName"))
	Set xml=Server.CreateObject("Microsoft.XMLDOM")
	xml.async="false"
	xml.load(xmlPath)
	for each skinObj in xml.documentElement.childNodes
		if cint(skinObj.getAttributeNode("id").value)=cint(id) then
			skinObj.text=skinName
		end if
	next
	xml.save(xmlPath)
	set xml=nothing
	response.Redirect Request.ServerVariables("HTTP_REFERER")
End Sub
Sub copySkin()
	dim id,url,skinValue,skinName,xml,fso,xmlroot,skinObj
	skinValue=split(trim(Request("skinOption")),"|")
	id=skinValue(0)
	url=skinValue(1)
	skinName=trim(Request("skinName"))
	set xml=Server.CreateObject("Microsoft.XMLDOM")
	xml.async="false"
	xml.load(skinPath&"\"&"skin.xml")
	set xmlroot=xml.documentElement
	if xmlroot.hasChildNodes then
		id=cint(xmlroot.lastChild.getAttributeNode("id").value)+1
	else
		id=1
	end if
	set skinObj=xml.createElement("skin")
	skinObj.text=skinName
	skinObj.setAttribute "id",id
	skinObj.setAttribute "url",url&"Copy"
	xmlroot.appendChild(skinObj)
	xml.save(skinPath&"\"&"skin.xml")
	Set xml=Nothing
	Set fso=Server.CreateObject("Scripting.FileSystemObject")
	fso.CopyFolder skinPath&"\"&url,skinPath&"\"&url&"Copy",true
	Set fso=Nothing
	response.Redirect Request.ServerVariables("HTTP_REFERER")
End Sub
Sub delSkin()
	dim url,id,fso,xml,skinObj
	url=trim(Request("url"))
	id=trim(Request("id"))
	Set xml=Server.CreateObject("Microsoft.XMLDOM")
	xml.async="false"
	xml.Load(xmlPath)
	for each skinObj in xml.documentElement.childNodes
		if cint(skinObj.getAttributeNode("id").value)=cint(id) then
			xml.documentElement.removeChild(skinObj)
		end if
	next
	xml.save(xmlPath)
	Set xml=Nothing
	Set fso=Server.CreateObject("Scripting.FileSystemObject")
	if fso.FolderExists(skinPath&"\"&url) then
		fso.deleteFolder skinPath&"\"&url
	end if
	Set fso=Nothing
	response.Redirect Request.ServerVariables("HTTP_REFERER")
End Sub
Sub editSkin()
dim id,url,skinName,txtStream,content,fileName,author
url=trim(Request("url"))
id=trim(Request("id"))
fileName=trim(Request("fileName"))
skinName=trim(Request("skinName"))
author=trim(Request("author"))
if fileName="" then
	fileName="skin.css"
end if
Set fso=Server.CreateObject("Scripting.FileSystemObject")
if not fso.folderExists(skinPath&"\"&url) then
	fso.CreateFolder(skinPath&"\"&url)
end if
set myfiles=fso.GetFolder(skinPath&"\"&url)
for each fileObj in myfiles.files
	fileType=mid(fileObj.name,instrRev(fileObj.name,".")+1)
	Select Case fileType
		Case "css","js"
		fileStr=fileStr&"<a href=""?action=editSkin&skinName="&skinName&"&url="&url&"&id="&id&"&fileName="&fileObj.name&"&author="&author&""">"&fileObj.name&"<font color=""#ff0000"">["&fileType&"]</font>"&"</a> &nbsp;"
	End Select
next
set txtStream=fso.OpenTextFile(skinPath&"\"&url&"\"&fileName,1,true,-2)
if not txtStream.AtEndOfStream then
	content=txtStream.ReadAll
end if
txtStream.close
%>
<table width="100%" border="0" cellpadding="4"  cellspacing="1" class="text table_border mainTable">
  <tr valign="middle"> 
    <td height="25" colspan="2" class="td_titleT">编辑样式</td>
  </tr>
  <tr class="td_bgcolor"> 
    <td width="110" height="22" align="right" valign="middle">文件操作：</td>
    <td width="*" valign="middle"><%=folderStr&" "&fileStr%></td>
  </tr>
  <form action="?action=saveSkin" name="form1" method="post">
  <tr class="td_bgcolor"> 
    <td height="22" align="right" valign="middle">样式名称：</td>
    <td valign="middle"><input type="text" name="skinName" value="<%=skinName%>" <%if lcase(fileName)<>lcase("skin.css") then response.write("disabled") end if%>><input type="hidden" value="<%=id%>" name="id"></td>
  </tr>
  <tr class="td_bgcolor"> 
    <td height="23" align="right" valign="middle">设计者：</td>
    <td valign="middle"><input type="text" name="author" value="<%=author%>"></td>
  </tr>
  <tr class="td_bgcolor"> 
    <td height="23" align="right" valign="middle">样式路径：</td>
    <td valign="middle"><input type="text" name="url" value="<%=url%>"></td>
  </tr>
  <tr class="td_bgcolor"> 
    <td height="23" align="right" valign="middle">文件名：</td>
    <td valign="middle"><input type="text" name="fileName" value="<%=fileName%>"> &nbsp;<font color="#ff0000">*要新建文件，重名命文件名即可！</font></td>
  </tr>
  <tr class="td_bgcolor"> 
    <td height="113" align="right" valign="middle">样式内容:</td>
    <td valign="top"><textarea name="content" style="width:100%" rows="20"><%=content%></textarea> <a href="javascript:edit_size(-5,'content')"><img src="images/minus.gif" align="bottom" border="0"></a>&nbsp;<a href="javascript:edit_size(5,'content')"><img src="images/plus.gif" align="bottom" border="0"></a></td>
  </tr>
  <tr class="td_titleB" align="center" valign="middle"> 
    <td height="23" colspan="2"> <input type="submit" name="Submit" value="保存修改"></td>
  </tr>
  </form>
</table>
<br/>
<table width="100%" border="0" cellpadding="4"  cellspacing="1" class="text table_border mainTable">
  <tr> 
    <td height="26" colspan="2" valign="middle" class="td_titleT" align="center"> 图标列表</td>
  </tr>
  <tr class="td_bgcolor"> 
    <td height="19" colspan="2" valign="middle"> 路径：<font color="#333333"><%="skins/"&url&"/"%></font>&nbsp;&nbsp;&nbsp;&nbsp;[<a href="javascript:window.location.reload();">刷新</a>]</td>
  </tr>
   <tr class="td_bgcolor">
   	<td colspan="2">
	<table align="center" cellpadding="4"><tr>
<%
dim i:i=1
for each fileObj in myfiles.files
fileType=mid(fileObj.name,instrRev(fileObj.name,".")+1)
	Select Case fileType
		Case "gif","jpg","jpge","bmp","png"
		response.write bbimg("<td style=""background:#ffffff;border:1px dotted #00648A;padding:5px;""><img src=""../skins/"&url&"/"&fileObj.name&""" align=""baseline""/><br>文件名："&fileObj.name&"</br>[<a href=""?action=delFile&fileName=../skins/"&url&"/"&fileObj.name&""">删除</a>]</td> ",130)
		if i=5 then
			response.write "</tr><tr>"
			i=0
		end if
		i=i+1
	End Select
next%>  
	</tr></table>
	</td>
  </tr>
  <tr class="td_bgcolor"> 
    <td height="26" width="60" valign="middle">图片上传：</td><td width="90%" valign="middle"><iframe src="../skins/upfile.asp?url=<%=url%>" height="24" width="100%" frameBorder="no" scrolling="no" marginHeight="0" marginWidth="0"></iframe></td>
  </tr>
</table>
<%Set fso=Nothing
End Sub
Sub saveSkin()
dim id,skinName,author,url,fileName,content,fso,txtStream,xml,skinObj
id=trim(Request("id"))
skinName=trim(Request("skinName"))
author=trim(Request("author"))
url=trim(Request("url"))
fileName=trim(Request("fileName"))
content=trim(Request("content"))
Set fso=Server.CreateObject("Scripting.FileSystemObject")
if not fso.folderExists(skinPath&"\"&url) then
	fso.createFolder(skinPath&"\"&url)
end if
set txtStream=fso.CreateTextFile(skinPath&"\"&url&"\"&fileName,true)
txtStream.write content
txtStream.close
Set fso=Nothing
if Lcase(fileName)=Lcase("skin.css") then
Set xml=Server.CreateObject("Microsoft.XMLDOM")
xml.async="false"
xml.load(xmlPath)
for each skinObj in xml.documentElement.childNodes
	if cint(skinObj.getAttributeNode("id").value)=cint(id) then
		skinObj.text=skinName
		skinObj.getAttributeNode("url").value=url
		skinObj.setAttribute "author",author
		'skinObj.getAttributeNode("author").value=author
	end if
next
xml.save(xmlPath)
set xml=nothing
end if
adminShowMsg "成功信息","恭喜恭喜，保存成功"
End Sub
Sub delFile()
dim fileName,filePath,fso
fileName=Request("fileName")
filePath=server.mappath(fileName)
set fso=Server.CreateObject("Scripting.FileSystemObject")
if fso.fileExists(filePath) then
	fso.DeleteFile filePath
end if
set fso=nothing
response.Redirect Request.ServerVariables("HTTP_REFERER")
End Sub
'========================================================
'MaoSin CMS 1.1      Power by maosin.com
'Email: maosin@163.com , maosin@maosin.com
'Web: http://www.maosin.com  http://www.maosin.net
'Copyright (C) 2006 maosin.com All Rights Reserved.
'========================================================
%>

⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -