customdatagrid.vb

数据网格数据Custom_Data_Grid_src_demo

Namespace CustomControls

    Public Class CustomDataGrid
        Inherits System.Windows.Forms.UserControl

#Region " Windows Form Designer generated code "

        Public Sub New()
            MyBase.New()

            'This call is required by the Windows Form Designer.
            InitializeComponent()
            'Add any initialization after the InitializeComponent() call
            LoadProperties()
        End Sub

        'UserControl1 overrides dispose to clean up the component list.
        Protected Overloads Overrides Sub Dispose(ByVal disposing As Boolean)
            If disposing Then
                If Not (components Is Nothing) Then
                    components.Dispose()
                End If
            End If
            MyBase.Dispose(disposing)
        End Sub

        'Required by the Windows Form Designer
        Private components As System.ComponentModel.IContainer

        'NOTE: The following procedure is required by the Windows Form Designer
        'It can be modified using the Windows Form Designer.  
        'Do not modify it using the code editor.
        <System.Diagnostics.DebuggerStepThrough()> Private Sub InitializeComponent()
            '
            'CustomDataGrid
            '
            Me.Name = "CustomDataGrid"
            Me.Size = New System.Drawing.Size(192, 232)

        End Sub

#End Region

        Private WithEvents _dgrid As DataGrid

#Region "Control code"

        Public Sub LoadProperties()
            'create objects
            _dgrid = New DataGrid()
            _dgrid.Dock = DockStyle.Fill

            'Me.Controls.Add(_tbar)
            Me.Controls.Add(_dgrid)
            'add events
            AddHandler _dgrid.MouseDown, AddressOf DataGridMouseDownEventHandler

        End Sub

        Public Property DataGrid() As DataGrid
            Get
                Return _dgrid
            End Get
            Set(ByVal Value As DataGrid)
                _dgrid = Value
            End Set
        End Property

        Public Property PreferedColumnWidth() As Integer
            Get
                Return _dgrid.PreferredColumnWidth
            End Get
            Set(ByVal Value As Integer)
                _dgrid.PreferredColumnWidth = Value
            End Set
        End Property

        Public Property GridBackgrundColor() As Color
            Get
                Return _dgrid.BackgroundColor
            End Get
            Set(ByVal Value As Color)
                _dgrid.BackgroundColor = Value
            End Set
        End Property

        Public Property RowHeaderWidth() As Integer
            Get
                If _dgrid.TableStyles.Count < 1 Then
                    Return _dgrid.RowHeaderWidth
                Else
                    Return _dgrid.TableStyles(0).RowHeaderWidth
                End If
            End Get
            Set(ByVal Value As Integer)
                If _dgrid.TableStyles.Count < 1 Then
                    _dgrid.RowHeaderWidth = Value
                Else
                    _dgrid.TableStyles(0).RowHeaderWidth = Value
                End If
            End Set
        End Property

        Public Sub SetColumnBackColor(ByVal colName As String, ByVal colBackColor As Color)

            If _dgrid.TableStyles.Count < 1 Then
                'no table styles defined
                Exit Sub
            End If

            Dim tstyle As DataGridTableStyle = _dgrid.TableStyles(0)
            If tstyle.GridColumnStyles.Count < 1 Then
                'no cols' defined
                Exit Sub
            End If

            If tstyle.GridColumnStyles.Contains(colName) Then
                Dim cstyle As DataGridColoredTextBoxColumn = tstyle.GridColumnStyles(colName)
                cstyle.BackColor = colBackColor
                _dgrid.Refresh()
            End If
        End Sub

        Public Sub SetColumnForeColor(ByVal colName As String, ByVal colForeColor As Color)

            If _dgrid.TableStyles.Count < 1 Then
                'no table styles defined
                Exit Sub
            End If

            Dim tstyle As DataGridTableStyle = _dgrid.TableStyles(0)
            If tstyle.GridColumnStyles.Count < 1 Then
                'no cols' defined
                Exit Sub
            End If

            If tstyle.GridColumnStyles.Contains(colName) Then
                Dim cstyle As DataGridColoredTextBoxColumn = tstyle.GridColumnStyles(colName)
                cstyle.ForeColor = colForeColor
                _dgrid.Refresh()
            End If
        End Sub
#End Region

#Region "Event Handlers"

        '--------------- Display context menu ----------------
        'Catch mouse down event and on right click
        'display the context menu 
        Private Sub DataGridMouseDownEventHandler(ByVal sender As System.Object, ByVal e As System.Windows.Forms.MouseEventArgs)

            If Not e.Button = MouseButtons.Right Then
                Exit Sub
            End If

            Dim myGrid As DataGrid = CType(sender, DataGrid)
            Dim hti As System.Windows.Forms.DataGrid.HitTestInfo
            hti = myGrid.HitTest(e.X, e.Y)
            If hti.Type = Windows.Forms.DataGrid.HitTestType.ColumnHeader Then
                Dim mItem As New MenuItem()
                mItem.Text = "Field Chooser"

                AddHandler mItem.Click, AddressOf MenuItem_EventHandler

                Dim _cMenu As New ContextMenu()
                _cMenu.MenuItems.Add(mItem)

                _cMenu.Show(Me, New Point(e.X, e.Y))

            End If
        End Sub

        Public Sub MenuItem_EventHandler( _
                   ByVal sender As Object, _
                   ByVal e As EventArgs)
            Call SelectColumns()
        End Sub

#End Region

        Private Sub SelectColumns()

            'get datagrid columns
            Dim alistCols As ArrayList = GetDataGridColumns()

            If alistCols.Count < 1 Then
                Exit Sub
            End If

            Dim frmSlt As New frmColumns()
            Dim col As String

            If _dgrid.TableStyles.Count < 1 Then
                'no styles defined.
                'Exit Sub
                _dgrid.TableStyles.Add(GetDataGridTableStyle(alistCols))
            End If

            Dim tblStyle As DataGridTableStyle = _dgrid.TableStyles(0)

            Dim colStyle As DataGridColumnStyle
            Dim colStyles As GridColumnStylesCollection = tblStyle.GridColumnStyles

            If colStyles.Count < 1 Then
                Exit Sub
            End If

            'set Mappingname property to colname property 
            'to display a column.

            Dim lItem As Object

            'load the listboxes
            For Each colStyle In colStyles
                If colStyle.MappingName = colStyle.HeaderText Then
                    'col. is visible
                    frmSlt.lboxSelected.Items.Add(colStyle.HeaderText)
                Else
                    'col is not visible
                    frmSlt.lboxNSelected.Items.Add(colStyle.HeaderText)
                End If
            Next

            Dim i As Integer

            'show the form
            Dim res As DialogResult = frmSlt.ShowDialog
            Dim tcol As DataGridColumnStyle
            Dim cols As New ArrayList()


            If res = DialogResult.OK Then

                'loop through the col headers
                'and change the mapping as selected
                For Each colStyle In colStyles
                    If frmSlt.lboxNSelected.Items.Contains(colStyle.HeaderText) Then
                        colStyle.MappingName = ""
                    Else
                        colStyle.MappingName = colStyle.HeaderText
                    End If
                Next

                For Each lItem In frmSlt.lboxSelected.Items
                    For Each colStyle In colStyles
                        If colStyle.HeaderText = lItem Then
                            cols.Add(colStyle)
                        End If
                    Next
                Next

                For Each lItem In frmSlt.lboxNSelected.Items
                    For Each colStyle In colStyles
                        If colStyle.HeaderText = lItem Then
                            cols.Add(colStyle)
                        End If
                    Next
                Next
                colStyles.Clear()
                colStyles.AddRange(cols.ToArray(GetType(DataGridColumnStyle)))
            End If

            frmSlt.Close()
            frmSlt = Nothing
        End Sub

        Public Function GetDataGridTableStyle(ByVal alistCols As ArrayList) As DataGridTableStyle
            Dim aList As New ArrayList()
            Dim col As String
            Dim dtblStyle As New DataGridTableStyle()
            Dim dtblCol As DataGridColoredTextBoxColumn
            For Each col In alistCols
                dtblCol = New DataGridColoredTextBoxColumn()
                dtblCol.HeaderText = col
                dtblCol.MappingName = col
                dtblStyle.GridColumnStyles.Add(dtblCol)
                dtblCol.Width = PreferedColumnWidth
            Next
            If _dgrid.DataSource.GetType Is GetType(DataTable) Then
                dtblStyle.MappingName = CType(_dgrid.DataSource, DataTable).TableName
            End If

            'set the row width
            dtblStyle.RowHeaderWidth = RowHeaderWidth
            Return dtblStyle
        End Function

        Private Function GetDataGridColumns() As ArrayList
            'get the datatable 
            Dim htblCols As New Hashtable()
            Dim alistCols As New ArrayList()


            If Not _dgrid.DataSource Is Nothing Then
                If _dgrid.DataSource.GetType Is GetType(DataTable) Then

                    Dim dtbl As DataTable = _dgrid.DataSource
                    Dim dcol As DataColumn

                    For Each dcol In dtbl.Columns
                        alistCols.Add(dcol.ColumnName)
                    Next
                End If
            End If
            Return alistCols
        End Function

        Private Sub DataGrid_DataSourceChanged(ByVal sender As Object, ByVal e As System.EventArgs) _
                Handles _dgrid.DataSourceChanged
            'datasource changed
            'load the default table styles
            RefreshTableStyles()
        End Sub

        Private Sub RefreshTableStyles()
            'get datagrid columns
            Dim alistCols As ArrayList = GetDataGridColumns()

            If alistCols.Count < 1 Then
                Exit Sub
            End If

            _dgrid.TableStyles.Clear()
            _dgrid.TableStyles.Add(GetDataGridTableStyle(alistCols))

        End Sub
    End Class
End Namespace