config.asp

是个不错的文件代码,希望大家好好用,

'     pt=3：取得登录用户的级别代码，用数值表示
'基础介绍：
'  ubound 函数：返回指定数组最大可用下标。用“:”将dim_user(i)分割成数据，查找用户所属的用户级别
'================================================
function format_power(pvar,pt)
  dim pi,pdim,temp1
  select case pt
  case 2
    temp1=1
  case 3
    temp1=0
  case else
    temp1=""
  end select
  if pvar="" then                              '如果用户为游客，则返回
    format_power=temp1
    exit function
  end if
  for pi=0 to ubound(dim_user)
    pdim=split(dim_user(pi),":")
    if pvar=pdim(0) then                       '找到该用户类别，对其进行pt处理
      select case pt
      case 1
        temp1=pdim(1)                          '取得用户登录模式的中文名称
      case 2
        temp1=pi+1                             '查找用户属于第几类
      case 3
        temp1=pdim(2)                          '取得登录用户的类别代码，用数值表示
      case else
        temp1=pvar                             '对pvar即login_mode不进行转换
      end select
    end if
    erase pdim                                 '削除临时数据
  next
  format_power=temp1
end function

'================================================
'作    用：如果把web_(19)(即dim_user())分为5类，则该函数取得各类中以“:”隔开的部分的值。format_power2(1,3)
'参    数：
'     pnn：须为数值,指定用户类别
'     pt ：须为数值,取值可以为1,2,3
'该函数与format_power()的区别主要在于：本函数已经明确所要处理的用户类型，而format_power()为用户类别的通用设置,调用简单。
'================================================
function format_power2(pnn,pt)	
  dim pdim
  format_power2=""
  pdim=split(dim_user(pnn-1),":")
  format_power2=pdim(pt-1)
  erase pdim
end function


function format_emoney_power(n_emoney,n_usert,n_pt)
  dim temp1,ddim,nj,nk,upnum
  upnum=ubound(dim_user)        
  ddim=split(n_usert,".")
  for nj=0 to ubound(ddim)
    nk=ddim(nj)
    if int(upnum+1)>=int(nk) then
      if int(nk)=0 then
        temp1=temp1&img_skin("icon_other")
      else
        temp1=temp1&img_skin("icon_"&format_power2(nk,1))
      end if
    end if
  next
  if isarray(ddim) then erase ddim
  if n_pt=1 then temp1=temp1&"&nbsp;<font class=red2>"&n_emoney&"</font>&nbsp;"&joekoe_cms.web_unit
  format_emoney_power=temp1
end function

'================================================
'作    用：处理网站运行时产生的任何错误的显示
'参    数：
'    rror_type：为产生错误的代码
'    error_len：显示表格的宽度
'基础介绍：
'   replace 函数：将find全部替换为replace。replace(expression, find, replace)本例中用于将 + 替换为错误显示的图片，以使页面更加美观
'================================================
function found_error(error_type,error_len)
  dim temp1
  temp1=replace(error_type,"+","<img src='images/small/jt_err.gif' border=0 align=absmiddle>&nbsp;")
  temp1=vbcrlf&"<table border=0 width=" & error_len & ">" & _
	vbcrlf&"<tr><td align=center height=50><font class=red>系统发现你输入的数据有以下错误：</font></td></tr>" & _
	vbcrlf&"<tr><td class=htd>" & temp1& "</td></tr>" & _
	vbcrlf&"<tr><td align=center height=50><a href='javascript:history.back(1)'>返回上一页</a></td></tr>" & _
	vbcrlf&"</table>"
  found_error=temp1
end function

'================================================
'作    用：判断sn_var 用户名、代号和密码是否合法
'参    数：
'  如果sn_var为：空字符 | : ' "" chr(9)-chr(13),chr(32)(系统过滤字符)以及长度大于20，则返回false
'================================================
function symbol_name(sn_var)
  symbol_name=false
  if sn_var="" or len(sn_var)>20 or instr(sn_var,"|")>0 or instr(sn_var,":")>0 or instr(sn_var,"'")>0 or instr(sn_var,"""")>0 or instr(sn_var,chr(9))>0 or instr(sn_var,chr(10))>0 or instr(sn_var,chr(13))>0 or instr(sn_var,chr(32))>0 then
    exit function
  end if
  for i=1 to len(sn_var)
    if instr(web_dim(15),mid(sn_var,i,1))>0 then exit function      '以web_dim(15)定义的过滤字符来检验sn_var
  next
  symbol_name=true
end function

'================================================
'作    用：判断symbol_var 密码是否合法
'参    数：
'  如果symbol_var为：空字符 | : ' "" chr(9)-chr(13),chr(32)(系统过滤字符)以及长度大于20，则返回false
'================================================
function symbol_ok(symbol_var)
  symbol_ok=false
  symbol_var=symbol_var
  if symbol_var="" or len(symbol_var)>20 then exit function               '密码为空字符以及长度>20，返回false
  for i=1 to len(symbol_var)
    if instr(web_dim(16),mid(symbol_var,i,1))=0 then exit function    '以web_dim(16)定义的密码字符来检验symbol_var
  next
  symbol_ok=true
end function

'================================================
'作    用：过滤掉不健康的字符以及保留的注册用户名
'================================================
function health_name(hnn)
  dim ti,tnum,tdim,hn
  health_name=false
  hn=hnn
  tdim=split(web_dim(17)&":"&web_dim(18),":")      'web_dim(17)保留的注册用户名，web_dim(18)为用于过滤的不健康字符
  tnum=ubound(tdim)
  for ti=0 to tnum
    if instr(hn,tdim(ti))>0 then                   '如果找到了不健康字符，则返回false
      erase tdim
      exit function
    end if
  next
  erase tdim
  health_name=true
end function

'================================================
'作    用：过滤掉不健康的字符以及保留的注册用户名
'参    数：
'  vt为保留参数
'================================================
function health_var(hnn,vt)
  if not joekoe_cms.ishealth then                   '如果不过滤不健康字符，则返回 
    health_var=hnn
    exit function
  end if
  dim ti,tj,tdim,ht,hn
  hn=hnn
  if format_mid_num(5)=1 then                       '如果后台设置过滤不健康字符(web_dim(11)的第6个参数)
    tdim=split(web_dim(18),":")
    for ti=0 to ubound(tdim)
      ht=""
      for tj=1 to len(tdim(ti))                         
        ht=ht&"*"                                   '不健康字符将显示为“*”
      next
      hn=replace(hn,tdim(ti),ht)                    '替换掉不健康的字符
    next
    erase tdim
  end if
  health_var=hn
end function

sub textarea_resize(textareaname)
%>
<p>
<a href="javascript:textarea_resize('<%response.write textareaname%>','-');"><img src='images/admin/resize_minus.gif' border=0></a>
<br>
<a href='javascript:;' onclick="javascript:textarea_resize('<%response.write textareaname%>','+');"><img src='images/admin/resize_plus.gif' border=0></a>
</p>
<%
end sub
'****************************************************
' 玫瑰情缘 2006v3.0      power by meigui8.cn
' email: [e-mail]  , [e-mail]
' web: http://www.meigui8.cn
' copyright (c) 2006 meigui8.cn all rights reserved.
'****************************************************
%>