config.asp

是个不错的文件代码,希望大家好好用,

<%@language="vbscript" codepage="936"%>
<%
option explicit         '强制声明变量
response.buffer=true 	'开启缓冲页面功能
%>
<!-- #include file="common.asp" -->
<!-- #include file="common_other.asp" -->
<!-- #include file="jk_encrypt.asp" -->
<!-- #include file="jk_class.asp" -->
<!-- #include file="joekoe_skin.asp" -->
<%
'****************************************************
' 玫瑰情缘 2006v3.0      power by meigui8.cn
' email: [e-mail]  , [e-mail]
' web: http://www.meigui8.cn
' copyright (c) 2006 meigui8.cn all rights reserved.
'****************************************************
dim joekoe_cms,conn,rs,sql,page_power,i,tit,tit_fir,index_url,action,dim_user,dim_num
dim login_username,login_id,login_password,login_mode,login_popedom,login_emoney,login_integral,login_modep,login_faces,login_lentim,login_lentimt
dim ukong,redx,go_back,web_nologin,web_nopost,cms_skin,web_config,login_bbs_counter

set joekoe_cms=new class_joekoe_cms                                             '定义joekoe_cms为类变量
'-------------------数据库类型判断--“0”为access数据库，“1”为sql数据库-------------
joekoe_cms.web_vt=0
'---------------------------------数据库连接字符串----------------------------------
if joekoe_cms.web_vt=1 then
joekoe_cms.connstr="provider=sqloledb;" & _
		  "driver={sql server};" & _
		  "server=(local);" & _
		  "uid=sql_name;" & _
		  "pwd=sql_pass;" & _
		  "database=hpsy_cms_2004_sqldata;"
else 
joekoe_cms.connstr="dbq="&server.mappath("data/meigui8_cn_data.asp")&";driver={microsoft access driver (*.mdb)};"
end if
'----------------------------------网站初始化，定义相关网站变量-----------------------------------
'以下变量大部分取值于 common.asp 文件
'----------------------------------网站cookies名称----------------------------------
joekoe_cms.web_cookies=web_dim(5)                                               '即common.asp中web_dim(5)
'-----------------------------------常用变量设置--------------------------------------
joekoe_cms.web_name=web_dim(1)                                                  '网站名称
joekoe_cms.web_url=web_dim(2)                                                   '网站的网址
joekoe_cms.web_email=web_dim(4)
joekoe_cms.web_skin=web_dim(7)                                                  '网站的skin名称
joekoe_cms.web_upload=web_dim(13)                                               '网站上传路径
joekoe_cms.web_unit=web_dim(9)                                                  '网站虚拟货币
joekoe_cms.web_health=web_dim(18)                                               '网站健康信息(过滤字符)
joekoe_cms.web_dir_skin=web_dim(6)&"skin/"&web_dim(7)&"/"                       '网站skin的相对路径

if int(web_dim(0))<2 then joekoe_cms.js_tim=""
dim_user=split(web_dim(19),"|")                                                 '用户类别设置
dim_num=split(web_dim(12),"|")                                                  '页面显示设置
set cms_skin=new class_cms_skin                                                 '定义cms_skin为类变量
login_username=trim(request.cookies(joekoe_cms.web_cookies)("login_username"))  'cookies用户名
login_password=trim(request.cookies(joekoe_cms.web_cookies)("login_password"))  'cookies用户密码
login_id=0                                                                      '用户的id编号
login_mode=""                                                                   '用户登录模式
login_modep=0
login_popedom=""
login_emoney=0                                                                  '用户的虚拟货币数量
login_integral=0                                                                '用户的积分
login_bbs_counter=0
login_lentim=0
login_lentimt=0
action=trim(request.querystring("action"))                                      '处理返回的action
action=replace(action,"'","")                                                   '去掉action中的'
action=replace(action,"""","")                                                  '去掉action中的""
ukong=cms_skin.skukong
redx=cms_skin.skredx
go_back=cms_skin.skgo_back
web_nologin=cms_skin.sknologin
web_nopost=cms_skin.skpost

'================================================
'作    用：清除所有全局数组等，同时处理cookies，以及要清除的全局数组等为：dim_num,web_dim,rs,conn,joekoe_cms
'参    数：
'	   c_end : 为1时结束网页
'基础介绍：
'   如果不永久保存cookies，则设置cookies的时间为dim_num(2)的值（即web_dim(12)的第3个参数）
'   dateadd 函数：返回已添加指定时间间隔的日期－dateadd(interval, number, date)，其中：
'   interval：要添加的时间间隔单位，参数可为：yyyy 年,q 季度,m 月,d 日,ww 周,h 小时,n 分钟,s 秒
'   number：要添加的时间间隔长度，本例中为 20 分钟
'   date：要进行添加的时间，本例为 当前时间 
'   dateadd函数：此函数在本例中主要是设置cookies的过期时间为  20 分钟
'================================================
sub web_clear(c_end)
  response.cookies(joekoe_cms.web_cookies).path=joekoe_cms.web_dir                 '写入cookies的路径 
  if request.cookies(joekoe_cms.web_cookies)("iscookies")="yes" then     '如果永久保存cookies，则过期时间设置为10年
    if joekoe_cms.web_vt=1 then
      response.cookies(joekoe_cms.web_cookies).expires=date+365
	else 
      response.cookies(joekoe_cms.web_cookies).expires=date+3650
	end if
  else
    response.cookies(joekoe_cms.web_cookies).expires=dateadd("n",dim_num(2),joekoe_cms.now_time)
  end if
  erase dim_num                                                    '清除 dim_num 用户数组
  erase web_dim                                                    '清除 web_dim 全局数组，已在common.asp中定义
  if isobject(rs) then set rs=nothing                              '如果rs是连接数据库变量，则清除
  if joekoe_cms.isconn then                               '如果数据库仍保持连接，则关闭数据库，同时清除conn变量
    conn.close
    set conn=nothing
  end if
  if isarray(web_config) then erase web_config
  set joekoe_cms=nothing                                         '清除类变量edxsky_2in1
  set cms_skin=nothing
  if c_end=1 then response.end                                   'c_end=1时结束网页（c_end为参数）
end sub

'================================================
'作  用：将变量置为空字符－－防止出现null
'================================================
function var_null(ub)
  var_null=trim(ub)
  if var_null="" or isnull(var_null) then var_null=""
end function

'================================================
'作    用：判断变量是否为整数即 int 
'基础介绍：
'    instr 函数：返回string1在string2中首次出现的位置。instr(string1, string2)string1,string2 为 null 返回       null,string1 为"" 返回 0 ,string2 为"" 返回 1,在 string1 中找到 string2 ,则返回找到匹配字符串的位置 
'    instr 函数：本例中查找  .  小数点，用于判断变量是否为小数，如果是则返回值＞0
'================================================
function int_true(nvar)
  int_true=true
  if var_null(nvar)="" or not(isnumeric(nvar)) or instr(nvar,".")>0 then int_true=false
end function

'================================================
'作  用：判断变量是否为数值即 numeric 
'================================================
function num_true(nvar)
  num_true=true
  if var_null(nvar)="" or not(isnumeric(nvar)) then num_true=false
end function

'================================================
'作    用：从web_dim(11)变量取值－在common.asp中定义，用于设置注册用户信息(共50个参数)
'基础介绍：
'      mid 函数：从string中返回指定数目的字符。mid(string, start[, length])，string 字符串,如果 string 为 null，则返回 null。start 开始位置,如果start 超过了 string 中字符的数目,是返回 ""length 要返回的字符数。如果省略或 length 超过文本的字符数,则返回从 start 到结束的所有字符
'================================================
function format_mid_num(nnum)
  if nnum>len(web_dim(11)) then
    format_mid_num=0
    exit function
  end if
  format_mid_num=int(mid(web_dim(11),nnum,1))
end function

'================================================
'作  用：从ndata表中查找指定id，该id为ndata表中的最新数据
'================================================
function first_id(ndata,id)
  dim rsf
  set rsf=joekoe_cms.exec("select top 1 "&id&" from "&ndata&" order by "&id&" desc",1)
  first_id=rsf(id)
  rsf.close
  set rsf=nothing
end function

function code_admin(strers,at,acut)
  dim strer
  strer=trim(strers)
  select case int(at)
  case 1
    strer=trim(request.form(strer))
  case 2
    strer=trim(request.querystring(strer))
  end select
  if isnull(strer) or strer="" then
    code_admin=""
    exit function
  end if
 ' strer=replace(strer,"'","""")
  if int(acut)>0 then strer=left(strer,acut)
  code_admin=strer
end function

'================================================
'作    用：根据用户的登录模式，取得用户所属类别的设置。format_power(login_mode,2)
'参    数：
'     pvar：即login_mode，用户登录模式。pt:有3个取值:1,2,3
'     pt=1：取得用户登录模式的中文名称
'     pt=2：如果把web_(19)(即dim_user())分为5类,则pt=2查找用户属于第几类