cesysgen.bat

edb9315 wince4.2最新的bsp代码

REM Network utilities
if "%SYSGEN_NETUTILS%"=="1" set CE_MODULES=%CE_MODULES% ping ipconfig tracert route netstat
if "%SYSGEN_NETUTILS%"=="1" if "%SYSGEN_TCPIP6%"=="1" set CE_MODULES=%CE_MODULES% ipv6 ipv6tun
REM IPv6.exe requires stdio
if "%SYSGEN_NETUTILS%"=="1" if "%SYSGEN_TCPIP6%"=="1" set SYSGEN_STDIOA=1


if "%SYSGEN_IPHLPAPI%"=="1" set CE_MODULES=%CE_MODULES% iphlpapi

REM ==============================================================================================
REM
REM Optional components from GWES.  Certain components require basic window message handling
REM
REM ==============================================================================================
if "%SYSGEN_MINNOTIFY%"=="1" set SYSGEN_MINGWES=1
if "%SYSGEN_MINGDI%"=="1"    set SYSGEN_MINGWES=1
if "%SYSGEN_MININPUT%"=="1"  set SYSGEN_MINGWES=1
if "%SYSGEN_MINWMGR%"=="1"   set SYSGEN_MINGWES=1
if "%SYSGEN_DISPLAY%"=="1"   set SYSGEN_MINGWES=1


if not "%SYSGEN_MINGWES%"=="1" goto noMinGWES
   REM // Minimal message only gwe + required client libraries for coredll
   set __SYSGEN_FILESYS=1
   set SYSGEN_DEVICE=1
   set CE_MODULES=%CE_MODULES% gwes
   set GWE1_COMPONENTS=wmbase gweshare gwesmain immthunk msgque GSetWinLong CePtr
   set GWES_COMPONENTS=gwe1
   set GWE4_COMPONENTS=
   set COREDLL_COMPONENTS=%COREDLL_COMPONENTS% rectapi wmgr_c

   if not "%SYSGEN_PM%"=="1" set SYSGEN_PMSTUBS=1

   if "%SYSGEN_MINNOTIFY%"=="1" set GWE1_COMPONENTS=%GWE1_COMPONENTS% notify notifmin
   if "%SYSGEN_MINNOTIFY%"=="1" set SYSGEN_FSDBASE=1

   if "%SYSGEN_MINGDI%"=="1"    set SYSGEN_MININPUT=1
   if "%SYSGEN_MINWMGR%"=="1"   set SYSGEN_MININPUT=1
   if not "%SYSGEN_MININPUT%"=="1" goto noMinInput
      set CE_MODULES=%CE_MODULES% keybd pointer
      set GWE1_COMPONENTS=%GWE1_COMPONENTS% foregnd idle kbdui nled uibase
      set SYSGEN_FSPASSWORD=1
   :noMinInput

   if "%SYSGEN_MINWMGR%"=="1" set SYSGEN_MINGDI=1
   if not "%SYSGEN_MINGDI%"=="1" goto noMinGDI
      set GWE1_COMPONENTS=%GWE1_COMPONENTS% msgbeep
      set GWE2_COMPONENTS=mgbase mgbitmap mgblt mgblt2 mgdc mgdibsec mgdraw mgrgn mgwinmgr
      REM // Can also have calibration UI now that we have a display
      set GWE2_COMPONENTS=%GWE2_COMPONENTS% tchui calibrui
      set COREDLL_COMPONENTS=%COREDLL_COMPONENTS% mgdi_c
      REM Include TrueType engine
      set GWE2_COMPONENTS=%GWE2_COMPONENTS% mgtt
      REM Include DrawText API
      set GWE2_COMPONENTS=%GWE2_COMPONENTS% mgdrwtxt
      REM Include a font as well
      set FONTS_COMPONENTS=tahoma_1_07
      REM Include palette support
      set GWE2_COMPONENTS=%GWE2_COMPONENTS% mgpal mgpalnat
      set GWES_COMPONENTS=%GWES_COMPONENTS% gwe2
      REM Add the display driver support as well
      set CE_MODULES=%CE_MODULES% display fonts
      if not "%SYSGEN_CORELOC%"=="1" set SYSGEN_LOCUSA=1
   :noMinGDI

   if not "%SYSGEN_MINWMGR%"=="1" goto noMinWMgr
      set GWE3_COMPONENTS=accel audio btnctl caret cascade cdlctl clipbd cmbctl TouchCursorOnly cursor cursor2 defwndproc dlgmgr dlgmgr_hpc dlgmnem edctl EditControlOs gcache gwectrl icon iconcmn imgctl lbctl loadbmp loadimg menu menu_hpc menuscrl
      set GWE4_COMPONENTS=mnoover msgbox msgbox_hpc mtapui nclient oom oomui sbcmn scbctl startui startup stcctl winmgr sbcmnview nclientview gcacheview btnctlview stcctlview cmbctlview lbctlview
      set GWES_COMPONENTS=%GWES_COMPONENTS% gwe3

      set COREDLL_COMPONENTS=%COREDLL_COMPONENTS% accel_c
      set SYSGEN_AUDIO=1
      set __SYSGEN_GWE_TIMER=1
   :noMinWMgr

   if not "%__SYSGEN_GWE_TIMER%"=="1" goto noGweTimer
      set GWE4_COMPONENTS=%GWE4_COMPONENTS% timer
      set GWES_COMPONENTS=%GWES_COMPONENTS% gwe4
   :noGweTimer

:noMinGWES

REM If no GWES components then add the stubs
if "%GWES_COMPONENTS%"=="" set COREDLL_COMPONENTS=%COREDLL_COMPONENTS% coregwestub

REM // GPE components.
if "%__SYSGEN_GPE_NOEMUL%" == "1" set GPE_MODULES=emulstub_lib
if not "%__SYSGEN_GPE_NOEMUL%" == "1" set GPE_MODULES=emul_lib

if "%__SYSGEN_GPE_CLEARTYPE%" == "1" set GPE_MODULES=%GPE_MODULES% ctblt_lib
if not "%__SYSGEN_GPE_CLEARTYPE%" == "1" set GPE_MODULES=%GPE_MODULES% ctbltstub_lib

if "%__SYSGEN_GPE_GRADFILL%" == "1" set GPE_MODULES=%GPE_MODULES% drvgradfill_lib
if not "%__SYSGEN_GPE_GRADFILL%" == "1" set GPE_MODULES=%GPE_MODULES% drvgradfillstub_lib

if "%__SYSGEN_GPE_NOEMUL%" == "1" set GPEROTATE_MODULES=emulrotatestub_lib
if not "%__SYSGEN_GPE_NOEMUL%" == "1" set GPEROTATE_MODULES=emulrotate_lib

if "%__SYSGEN_GPE_CLEARTYPE%" == "1" set GPEROTATE_MODULES=%GPEROTATE_MODULES% rctblt_lib
if not "%__SYSGEN_GPE_CLEARTYPE%" == "1" set GPEROTATE_MODULES=%GPEROTATE_MODULES% rctbltstub_lib

if "%__SYSGEN_GPE_GRADFILL%" == "1" set GPEROTATE_MODULES=%GPEROTATE_MODULES% rdrvgradfill_lib
if not "%__SYSGEN_GPE_GRADFILL%" == "1" set GPEROTATE_MODULES=%GPEROTATE_MODULES% rdrvgradfillstub_lib

REM ==============================================================================================
REM
REM Optional audio components
REM
REM ==============================================================================================

REM // WaveAPI - Waveform Audio, Hardware Mixer and Audio Compression Manager
set WAVEAPI_COMPONENTS=

REM // ACM Codecs/GSM610 - handy for wireless
if not "%SYSGEN_ACM_GSM610%"=="1" goto nogsm610
	set CE_MODULES=%CE_MODULES% gsm610
	set SYSGEN_AUDIO_ACM=1
:nogsm610

REM // ACM (Audio Compression Manager)
if not "%SYSGEN_AUDIO_ACM%"=="1" goto noacm
	set WAVEAPI_COMPONENTS=%WAVEAPI_COMPONENTS% wapiacm
	set COREDLL_COMPONENTS=%COREDLL_COMPONENTS% mmacm
	set SYSGEN_AUDIO=1
:noacm

if not "%SYSGEN_AUDIO%"=="1" goto noaudio
	set CE_MODULES=%CE_MODULES% waveapi audiodrv
	set CE_MODULES=%CE_MODULES% wavesamples
	set WAVEAPI_COMPONENTS=%WAVEAPI_COMPONENTS% wapiwave wapimap
	set COREDLL_COMPONENTS=%COREDLL_COMPONENTS% mmwave mmsnd mmmix
	REM Audio stack needs DeviceIoControl, MsgQueues & Registry
	set __SYSGEN_FILESYS=1
	set SYSGEN_MSGQUEUE=1
	REM Also used GetDeviceKey - serdev.
	set SYSGEN_DEVICE=1
	set SYSGEN_SERDEV=1
    if not "%SYSGEN_CORELOC%"=="1" set SYSGEN_LOCUSA=1
:noaudio

REM ==============================================================================================
REM
REM Optional Driver Components
REM
REM ==============================================================================================
if "%SYSGEN_ATADISK%"=="1"   set SYSGEN_FATFS=1
if "%SYSGEN_ATAPI%"=="1"     set SYSGEN_FATFS=1
if "%SYSGEN_SDMMC%"=="1"     set SYSGEN_FATFS=1

if "%SYSGEN_ATADISK%"=="1"   set SYSGEN_DEVICE=1
if "%SYSGEN_ATAPI%"=="1"     set SYSGEN_DEVICE=1
if "%SYSGEN_SDMMC%"=="1"     set SYSGEN_DEVICE=1

if "%SYSGEN_UDFS%"=="1"      set SYSGEN_STOREMGR=1
if "%SYSGEN_FATFS%"=="1"     set SYSGEN_STOREMGR=1
if "%SYSGEN_TFAT%"=="1"      set SYSGEN_STOREMGR=1
if "%SYSGEN_BINFS%"=="1" 	 set SYSGEN_STOREMGR=1

if "%SYSGEN_SMARTCARD%"=="1" set SYSGEN_DEVICE=1
if "%SYSGEN_USB%"=="1"       set SYSGEN_DEVICE=1
if "%SYSGEN_PARALLEL%"=="1"  set SYSGEN_DEVICE=1

REM // IEEE-1394
if "%SYSGEN_1394_SBP2_SCSI%"=="1" set SYSGEN_1394_SBP2=1
if "%SYSGEN_1394_SBP2%"=="1" set SYSGEN_1394=1
if "%SYSGEN_1394_AVC_VCR_VIRTUAL%"=="1" set SYSGEN_1394_AVC_VIRTUAL=1
if "%SYSGEN_1394_AVC_VIRTUAL%"=="1" set SYSGEN_1394_AVC_STREAMING=1
if "%SYSGEN_1394_AVC_VCR%"=="1" set SYSGEN_1394_AVC_STREAMING=1
if "%SYSGEN_1394_AVC_STREAMING%"=="1" set SYSGEN_1394_AVC=1
if "%SYSGEN_1394_AVC%"=="1" set SYSGEN_1394=1
if "%SYSGEN_1394_DCAM_VIRTUAL%"=="1" set SYSGEN_1394=1
if "%SYSGEN_1394_DCAM%"=="1" set SYSGEN_1394=1
if "%SYSGEN_1394_DIAG%"=="1" set SYSGEN_1394=1
if "%SYSGEN_1394_DIAG_VIRTUAL%"=="1" set SYSGEN_1394=1
if "%SYSGEN_1394%"=="1" set SYSGEN_DEVICE=1
if "%SYSGEN_1394%"=="1" set SYSGEN_CORESTRA=1
if "%SYSGEN_1394%"=="1" set __SYSGEN_CXPORT=1

REM Helper library for TCP/IP, winsock, and 1394
if "%__SYSGEN_CXPORT%"=="1"   set CE_MODULES=%CE_MODULES% cxport
if "%__SYSGEN_CXPORT%"=="1"   set __SYSGEN_FILESYS=1

REM // battery driver
if not "%SYSGEN_BATTERY%"=="1" goto no_battery
   set SYSGEN_DEVICE=1
   set COREDLL_COMPONENTS=%COREDLL_COMPONENTS% battery
   set CE_MODULES=%CE_MODULES% battdrvr
:no_battery

REM Bring in the device manager if power management is selected
if "%SYSGEN_PM%"=="1" set SYSGEN_DEVICE=1
if "%SYSGEN_PMSTUBS%"=="1" set SYSGEN_DEVICE=1

if not "%SYSGEN_DEVICE%"=="1" goto no_device
   REM Compression is not technically needed at this point but if your image
   REM includes device.exe then it starts to be large enough that compression is useful
   set SYSGEN_NKCOMPR=1

   set SYSGEN_FULL_CRT=1
   set __SYSGEN_FILESYS=1
   set SYSGEN_MSGQUEUE=1
   set CE_MODULES=%CE_MODULES% device regenum
   set DEVICE_COMPONENTS=%DEVICE_COMPONENTS% devmain

   REM Select power manager components
   if not "%SYSGEN_PM%"=="1" goto not_full_PM
      set CE_MODULES=%CE_MODULES% pm
      set PM_COMPONENTS=%PM_COMPONENTS% pm_mdd pm_battery pm_default_pdd
      set DEVICE_COMPONENTS=%DEVICE_COMPONENTS% pmif
      goto pm_done
   :not_full_PM
   if not "%SYSGEN_PMSTUBS%"=="1" goto no_PM
      set CE_MODULES=%CE_MODULES% pm
      set PM_COMPONENTS=%PM_COMPONENTS% pmstubs
      set DEVICE_COMPONENTS=%DEVICE_COMPONENTS% pmif
      goto pm_done
   :no_PM
      set DEVICE_COMPONENTS=%DEVICE_COMPONENTS% nopmif
      goto pm_done
   :pm_done

   set SYSGEN_SERDEV=1
   set SYSGEN_STDIO=1
   set COREDLL_COMPONENTS=%COREDLL_COMPONENTS% devload

   REM // Driver DLLs compiled for all platforms.  Some of these are aliases for groups
   REM // of drivers that are linked at SYSGEN time -- see
   REM // public\common\oak\cesysgen\makefile for a list.
   set CE_MODULES=%CE_MODULES% ceddk giisr mmtimer pci
   set CE_MODULES=%CE_MODULES% pcmcia pcmconv serial

   REM // Chip Support Package drivers.  The "csp" alias includes a number of sample drivers
   REM // that are linked at SYSGEN time -- see public\common\oak\cesysgen\makefile for a list.
   set CE_MODULES=%CE_MODULES% csp


   REM // FatFS support
   if "%SYSGEN_FATFS%"=="1"  set CE_MODULES=%CE_MODULES% fatfsd mspart fatutil
   if "%SYSGEN_TFAT%"=="1"   set CE_MODULES=%CE_MODULES% tfat mspart fatutil
   if "%SYSGEN_FATFS%"=="1"  if not "%SYSGEN_CORELOC%"=="1" set SYSGEN_LOCUSA=1
   if "%SYSGEN_TFAT%"=="1"   if not "%SYSGEN_CORELOC%"=="1" set SYSGEN_LOCUSA=1
   if "%SYSGEN_FATFS%"=="1"  set FATUTIL_COMPONENTS=fatutil_main fatutil_noui
   if "%SYSGEN_TFAT%"=="1"   set FATUTIL_COMPONENTS=fatutil_main fatutil_noui

   if "%SYSGEN_ATADISK%"=="1"      set CE_MODULES=%CE_MODULES% atadisk

   REM //=== FSD ===
   if "%SYSGEN_ATAPI%"=="1"  set CE_MODULES=%CE_MODULES% atapi
   if "%SYSGEN_UDFS%"=="1"   set CE_MODULES=%CE_MODULES% udfs
   if "%SYSGEN_SDMMC%"=="1"  set CE_MODULES=%CE_MODULES% sdmmc
   if "%SYSGEN_MSFLASH%"=="1" set CE_MODULES=%CE_MODULES% sdnpcid stratad 

   if "%SYSGEN_BINFS%"=="1"  set CE_MODULES=%CE_MODULES% binfs

   REM // USB modules
   if "%SYSGEN_USB%"=="1"           set CE_MODULES=%CE_MODULES% usbhost usbd
   if "%SYSGEN_USB_HID%"=="1"       set CE_MODULES=%CE_MODULES% usbhid
   if "%SYSGEN_USB_PRINTER%"=="1"   set CE_MODULES=%CE_MODULES% usbprn
   if "%SYSGEN_USB_STORAGE%"=="1"   set CE_MODULES=%CE_MODULES% usbmsc usbdisk6
   if "%SYSGEN_ETH_USB_HOST%"=="1"  set CE_MODULES=%CE_MODULES% rndismp usb8023
   if "%SYSGEN_USB_SMARTCARD%"=="1" set CE_MODULES=%CE_MODULES% stcusb

   REM // HID modules
   if "%__SYSGEN_HID_PARSER%"=="1"     set CE_MODULES=%CE_MODULES% hidparse
   if "%__SYSGEN_HID_KEYBOARD%"=="1"   set CE_MODULES=%CE_MODULES% kbdhid conshid
   if "%__SYSGEN_HID_MOUSE%"=="1"      set CE_MODULES=%CE_MODULES% mouhid

   REM -- TBD make netui load FormatMessage dynamically
   if "%SYSGEN_USB%"=="1" set SYSGEN_FMTMSG=1

   REM // Parallel support
   if "%SYSGEN_PARALLEL%"=="1" set CE_MODULES=%CE_MODULES% parallel

   REM // IEEE-1394 Components
   if "%SYSGEN_1394_DIAG%"=="1" set CE_MODULES=%CE_MODULES% 1394diag
   if "%SYSGEN_1394_DIAG_VIRTUAL%"=="1" set CE_MODULES=%CE_MODULES% 1394vdev
   if "%SYSGEN_1394_DCAM%"=="1" set CE_MODULES=%CE_MODULES% 1394dcam
   if "%SYSGEN_1394_DCAM_VIRTUAL%"=="1" set CE_MODULES=%CE_MODULES% virtdcam
   if "%SYSGEN_1394_AVC_VCR_VIRTUAL%"=="1" set CE_MODULES=%CE_MODULES% avc_vvcr
   if "%SYSGEN_1394_AVC_VIRTUAL%"=="1" set CE_MODULES=%CE_MODULES% avc_unit
   if "%SYSGEN_1394_AVC_VCR%"=="1" set CE_MODULES=%CE_MODULES% avc_vcr
   if "%SYSGEN_1394_AVC_STREAMING%"=="1" set CE_MODULES=%CE_MODULES% avc_stream
   if "%SYSGEN_1394_AVC%"=="1" set CE_MODULES=%CE_MODULES% avc 61883
   if "%SYSGEN_1394_SBP2_SCSI%"=="1" set CE_MODULES=%CE_MODULES% scsiblk
   if "%SYSGEN_1394_SBP2%"=="1" set CE_MODULES=%CE_MODULES% sbp2
   if "%SYSGEN_1394%"=="1" set CE_MODULES=%CE_MODULES% setupapi wdmlib cewdmmgr 1394bus 1394ohcd


:no_device

REM ==============================================================================================
REM FSDMGR
REM ==============================================================================================

   if "%SYSGEN_STOREMGR%"=="1"  set CE_MODULES=%CE_MODULES% fsdmgr
   if "%SYSGEN_STOREMGR%"=="1"  set SYSGEN_MSGQUEUE=1
   if "%SYSGEN_STOREMGR%"=="1"  set __SYSGEN_FILESYS=1
   if "%SYSGEN_STOREMGR%"=="1"  set SYSGEN_STDIO=1


REM ==============================================================================================
REM
REM Optional components from core OS
REM
REM ==============================================================================================

if "%SYSGEN_FIBER%"=="1" set COREDLL_COMPONENTS=%COREDLL_COMPONENTS% fiber

if "%SYSGEN_FMTMSG%"=="1"     set COREDLL_COMPONENTS=%COREDLL_COMPONENTS% fmtmsg
if "%SYSGEN_FMTRES%"=="1"     set COREDLL_COMPONENTS=%COREDLL_COMPONENTS% fmtres
if "%SYSGEN_CORESTRA%"=="1"   set COREDLL_COMPONENTS=%COREDLL_COMPONENTS% corestra
if "%SYSGEN_STDIO%"=="1"      set COREDLL_COMPONENTS=%COREDLL_COMPONENTS% coresiow
if "%SYSGEN_STDIOA%"=="1"     set COREDLL_COMPONENTS=%COREDLL_COMPONENTS% coresioa
if "%SYSGEN_STDIO%"=="1"      set SYSGEN_SERDEV=1
if "%SYSGEN_STDIOA%"=="1"     set SYSGEN_SERDEV=1
if "%SYSGEN_SERDEV%"=="1"  set COREDLL_COMPONENTS=%COREDLL