📄 cesysgen.bat
字号:
REM ==============================================================================================
REM
REM Optional Security Components (CAPI, SSPI, NTLM, Kerberos)
REM
REM ==============================================================================================
REM PPP Server uses NTLMSSP support for auth
if "%SYSGEN_PPP_SERVER%"=="1" set SYSGEN_AUTH_NTLM=1
REM // SSPI
if "%SYSGEN_AUTH_NTLM%"=="1" set SYSGEN_AUTH=1
if "%SYSGEN_AUTH_KERBEROS%"=="1" set SYSGEN_AUTH=1
if "%SYSGEN_AUTH_SCHANNEL%"=="1" set SYSGEN_AUTH=1
REM Required for credential manager
if "%SYSGEN_REDIR%"=="1" set SYSGEN_AUTH=1
if "%SYSGEN_REDIR%"=="1" if "%SYSGEN_AUTH_NTLM%"=="1" set __SYSGEN_AUTH_SPNEGO=1
if not "%SYSGEN_AUTH%"=="1" goto skipauth
if not "%SYSGEN_CORELOC%"=="1" set SYSGEN_LOCUSA=1
set CE_MODULES=%CE_MODULES% secur32
set __SYSGEN_FILESYS=1
REM // Secure components: SSPI, ntlm SSP, kerberos SSP;
if "%SYSGEN_AUTH_NTLM%"=="1" set CE_MODULES=%CE_MODULES% ntlmssp
if "%SYSGEN_AUTH_KERBEROS%"=="1" set __SYSGEN_AUTH_SPNEGO=1
if "%SYSGEN_AUTH_KERBEROS%"=="1" set __SYSGEN_MSASN1=1
if "%SYSGEN_AUTH_KERBEROS%"=="1" set CE_MODULES=%CE_MODULES% kerberos cryptdll
if "%__SYSGEN_AUTH_SPNEGO%" == "1" set __SYSGEN_MSASN1=1
if "%__SYSGEN_AUTH_SPNEGO%" == "1" set CE_MODULES=%CE_MODULES% spnego
if "%SYSGEN_AUTH_KERBEROS%"=="1" set SYSGEN_TCPIP=1
if "%SYSGEN_AUTH_KERBEROS%"=="1" set SYSGEN_FULL_CRT=1
if not "%SYSGEN_AUTH_SCHANNEL%"=="1" goto skipschannel
REM // Secure channel SSL provider (now depends on crypt32)
set CE_MODULES=%CE_MODULES% schannel
set SYSGEN_CRYPTO=1
set SYSGEN_CERTS=1
set SYSGEN_TCPIP=1
set WINSOCK_COMPONENTS=sslsock
:skipschannel
:skipauth
REM // CAPI
if "%SYSGEN_CERTS%" == "1" set SYSGEN_CRYPTO=1
if "%SYSGEN_WIFI_AP%"=="1" set SYSGEN_CRYPTO=1
if "%SYSGEN_CRYPTO_SCWCSP%" == "1" set SYSGEN_CRYPTO=1
if "%SYSGEN_CRYPTO_DSSDH%" == "1" set SYSGEN_CRYPTO=1
if not "%SYSGEN_CRYPTO%"=="1" goto skipcrypto
set COREDLL_COMPONENTS=%COREDLL_COMPONENTS% cryptapi
set __SYSGEN_FILESYS=1
REM // RSAENH crypto service provider is included by default
set CE_MODULES=%CE_MODULES% rsaenh
if "%SYSGEN_SMARTCARD%" == "1" if "%SYSGEN_CRYPTO_SCWCSP%" == "1" set CE_MODULES=%CE_MODULES% scwapi scwcsp
REM // Diffie-Hellman CSP
if "%SYSGEN_CRYPTO_DSSDH%" == "1" set CE_MODULES=%CE_MODULES% dssdh
REM // CAPI2
if "%SYSGEN_CERTS%" == "1" set __SYSGEN_MSASN1=1
if "%SYSGEN_CERTS%" == "1" set CE_MODULES=%CE_MODULES% crypt32
if "%SYSGEN_CERTS%" == "1" set SYSGEN_CORESTRA=1
:skipcrypto
REM //ASN.1 dll used by crypto/auth modules
if "%__SYSGEN_MSASN1%"=="1" set CE_MODULES=%CE_MODULES% msasn1
REM // USB dependencies
if "%SYSGEN_USB_HID_CLIENTS%"=="1" set SYSGEN_USB_HID_KEYBOARD=1
if "%SYSGEN_USB_HID_CLIENTS%"=="1" set SYSGEN_USB_HID_MOUSE=1
if "%SYSGEN_USB_HID_KEYBOARD%"=="1" set SYSGEN_USB_HID=1
if "%SYSGEN_USB_HID_KEYBOARD%"=="1" set __SYSGEN_HID_KEYBOARD=1
if "%SYSGEN_USB_HID_MOUSE%"=="1" set SYSGEN_USB_HID=1
if "%SYSGEN_USB_HID_MOUSE%"=="1" set __SYSGEN_HID_MOUSE=1
if "%SYSGEN_USB_HID%"=="1" set SYSGEN_USB=1
if "%SYSGEN_USB_HID%"=="1" set __SYSGEN_HID_PARSER=1
if "%SYSGEN_USB_HID%"=="1" set SYSGEN_MININPUT=1
if "%SYSGEN_USB_PRINTER%"=="1" set SYSGEN_USB=1
if "%SYSGEN_USB_STORAGE%"=="1" set SYSGEN_USB=1
if "%SYSGEN_USB_STORAGE%"=="1" set SYSGEN_STOREMGR=1
if "%SYSGEN_USB_STORAGE%"=="1" set SYSGEN_CORESTRA=1
if "%SYSGEN_ETH_USB_HOST%"=="1" set SYSGEN_USB=1
if "%SYSGEN_ETH_USB_HOST%"=="1" set SYSGEN_ETHERNET=1
if "%SYSGEN_USB_SMARTCARD%"=="1" set SYSGEN_USB=1
if "%SYSGEN_USB_SMARTCARD%"=="1" set SYSGEN_SMARTCARD=1
REM // HID dependencies
if "%__SYSGEN_HID_KEYBOARD%"=="1" set __SYSGEN_HID_PARSER=1
if "%__SYSGEN_HID_KEYBOARD%"=="1" set SYSGEN_MININPUT=1
if "%__SYSGEN_HID_MOUSE%"=="1" set __SYSGEN_HID_PARSER=1
if "%__SYSGEN_HID_MOUSE%"=="1" set SYSGEN_MININPUT=1
if "%__SYSGEN_HID_PARSER%"=="1" set SYSGEN_CORESTRA=1
REM ==============================================================================================
REM
REM Optional Networking Components
REM
REM ==============================================================================================
REM // LDAP
if "%SYSGEN_LDAP%"=="1" set SYSGEN_WINSOCK=1
if "%SYSGEN_LDAP%"=="1" set CE_MODULES=%CE_MODULES% wldap32
REM // HTTP Lite
if "%__SYSGEN_HTTPLITE_FTP%"=="1" set __SYSGEN_HTTPLITE=1
if "%__SYSGEN_HTTPLITE%"=="1" set CE_MODULES=%CE_MODULES% httplite
if "%__SYSGEN_HTTPLITE%"=="1" set SYSGEN_CORESTRA=1
if "%__SYSGEN_HTTPLITE%"=="1" set SYSGEN_FULL_CRT=1
if "%__SYSGEN_HTTPLITE%"=="1" set SYSGEN_TCPIP=1
if "%__SYSGEN_HTTPLITE%"=="1" set SYSGEN_WINSOCK=1
if "%__SYSGEN_HTTPLITE%"=="1" if not "%SYSGEN_CORELOC%"=="1" set SYSGEN_LOCUSA=1
if "%__SYSGEN_HTTPLITE_FTP%"=="1" set HTTPLITE_COMPONENTS=httpftp
if "%SYSGEN_ETH_XIRCOM%"=="1" set SYSGEN_ETHERNET=1
if "%SYSGEN_ETH_CISCO%"=="1" set SYSGEN_ETH_80211=1
if "%SYSGEN_ETH_80211%"=="1" set SYSGEN_ETHERNET=1
if "%SYSGEN_WIFI_AP%"=="1" set SYSGEN_ETHERNET=1
if "%SYSGEN_NETUTILS%"=="1" set SYSGEN_IPHLPAPI=1
if "%SYSGEN_SNMP%"=="1" set SYSGEN_IPHLPAPI=1
if "%SYSGEN_ETH_80211%"=="1" set SYSGEN_IPHLPAPI=1
if "%SYSGEN_TCPIP6%"=="1" set SYSGEN_IPHLPAPI=1
if "%SYSGEN_PPTP%"=="1" set SYSGEN_IPHLPAPI=1
if "%SYSGEN_PPTP%"=="1" set SYSGEN_PPP=1
if "%SYSGEN_PPPOE%"=="1" set SYSGEN_PPP=1
if "%SYSGEN_MODEM%"=="1" set SYSGEN_PPP=1
if "%SYSGEN_PPP_SERVER%"=="1" set SYSGEN_PPP=1
if "%SYSGEN_PPP%"=="1" set SYSGEN_IPHLPAPI=1
REM Most net components require TCP/IP, winsock, NDIS
if "%SYSGEN_ETHERNET%"=="1" set SYSGEN_TCPIP=1
if "%SYSGEN_ETH_OTHER%"=="1" set SYSGEN_TCPIP=1
if "%SYSGEN_GATEWAY%"=="1" set SYSGEN_TCPIP=1
if "%SYSGEN_BRIDGE%"=="1" set SYSGEN_TCPIP=1
if "%SYSGEN_PPP%"=="1" set SYSGEN_TCPIP=1
if "%SYSGEN_SNMP%"=="1" set SYSGEN_TCPIP=1
if "%SYSGEN_REDIR%"=="1" set SYSGEN_TCPIP=1
if "%SYSGEN_LDAP%"=="1" set SYSGEN_TCPIP=1
if "%__SYSGEN_BTH%"=="1" set SYSGEN_TCPIP=1
if "%SYSGEN_NETUTILS%"=="1" set SYSGEN_TCPIP=1
if "%SYSGEN_IPHLPAPI%"=="1" set SYSGEN_TCPIP=1
REM Base TCP/IP support
if "%SYSGEN_TCPIP%"=="1" set CE_MODULES=%CE_MODULES% tcpstk
if "%SYSGEN_TCPIP%"=="1" set SYSGEN_NDIS=1
if "%SYSGEN_TCPIP%"=="1" set SYSGEN_WINSOCK=1
if "%SYSGEN_TCPIP%"=="1" set __SYSGEN_CXPORT=1
if "%SYSGEN_TCPIP%"=="1" set SYSGEN_FMTMSG=1
if "%SYSGEN_TCPIP%"=="1" set SYSGEN_FULL_CRT=1
REM IPv6 support
if "%SYSGEN_TCPIP6%"=="1" set CE_MODULES=%CE_MODULES% tcpip6 ipv6hlp
if "%SYSGEN_TCPIP6%"=="1" set SYSGEN_NDIS=1
if "%SYSGEN_TCPIP6%"=="1" set SYSGEN_WINSOCK=1
if "%SYSGEN_TCPIP6%"=="1" set __SYSGEN_CXPORT=1
if "%SYSGEN_TCPIP6%"=="1" set SYSGEN_FMTMSG=1
if "%SYSGEN_TCPIP6%"=="1" set SYSGEN_FULL_CRT=1
REM IPv6 firewall
if "%SYSGEN_FIREWALL%"=="1" set CE_MODULES=%CE_MODULES% fw6 fwapi
if "%SYSGEN_FIREWALL%"=="1" set SYSGEN_IPHLPAPI=1
if "%SYSGEN_FIREWALL%"=="1" set SYSGEN_WINSOCK=1
REM Infrared (IrDA) support
if "%SYSGEN_IRDA%"=="1" set SYSGEN_NDIS=1
if "%SYSGEN_IRDA%"=="1" set SYSGEN_WINSOCK=1
if "%SYSGEN_IRDA%"=="1" set __SYSGEN_CXPORT=1
if "%SYSGEN_IRDA%"=="1" set CE_MODULES=%CE_MODULES% irdastk
REM NDIS driver support
if "%SYSGEN_NDIS%"=="1" set SYSGEN_DEVICE=1
if "%SYSGEN_NDIS%"=="1" set SYSGEN_MSGQUEUE=1
if "%SYSGEN_NDIS%"=="1" set SYSGEN_CORESTRA=1
if "%SYSGEN_NDIS%"=="1" set CE_MODULES=%CE_MODULES% ndis
REM Winsock API support. Winsock1.1 is now a stub that calls into WS2.
if "%SYSGEN_WINSOCK%"=="1" set CE_MODULES=%CE_MODULES% winsock afd
if "%SYSGEN_WINSOCK%"=="1" set CE_MODULES=%CE_MODULES% ws2 ws2instl wspm nspm
REM SSL winsock layered service provider
if "%SYSGEN_WINSOCK%"=="1" if "%SYSGEN_AUTH_SCHANNEL%"=="1" set CE_MODULES=%CE_MODULES% ssllsp
if "%SYSGEN_WINSOCK%"=="1" set SYSGEN_DEVICE=1
if "%SYSGEN_WINSOCK%"=="1" set __SYSGEN_CXPORT=1
if "%SYSGEN_WINSOCK%"=="1" set SYSGEN_CORESTRA=1
if "%SYSGEN_WINSOCK%"=="1" if not "%SYSGEN_CORELOC%"=="1" set SYSGEN_LOCUSA=1
REM Ethernet specific settings
if "%SYSGEN_ETHERNET%"=="1" set CE_MODULES=%CE_MODULES% dhcp
REM Built in (e.g. PCI only) NIC drivers. Include these always, will be filtered out by BSP_NIC_xxx settings
if "%SYSGEN_ETHERNET%"=="1" set CE_MODULES=%CE_MODULES% rtl8139 smsc100fd dp83815 dc21x4
REM USB RNDIS function driver, filtered by BSP_RNDISMINI_NET2890
if "%SYSGEN_ETHERNET%"=="1" set CE_MODULES=%CE_MODULES% rndismini net2890
REM NE2000 can be either installable (PCMCIA) or built in. Include by default.
if "%SYSGEN_ETHERNET%"=="1" set CE_MODULES=%CE_MODULES% ne2000
if "%SYSGEN_ETH_80211%"=="1" set CE_MODULES=%CE_MODULES% wzcsvc wzcsapi eapol
if "%SYSGEN_ETH_80211%"=="1" set __SYSGEN_NDISUIO=1
if "%SYSGEN_ETH_80211%"=="1" set __SYSGEN_ETH_INTERSIL=1
REM Too late for new sysgen, intersil is added permanently with SYSGEN_ETH_80211.
REM Addition to the image controlled by BSP_NIC_ISLP2NDS
if "%__SYSGEN_ETH_INTERSIL%"=="1" set CE_MODULES=%CE_MODULES% islp2nds
REM TEMP - retain following settings until all configs are updated to select a driver
if "%SYSGEN_ETH_80211%"=="1" set SYSGEN_ETH_CISCO=1
REM 802.11 Access Point
IF "%SYSGEN_WIFI_AP%"=="1" set __SYSGEN_WIFI=1
IF "%__SYSGEN_WIFI%"=="1" set CE_MODULES=%CE_MODULES% wlclient wlsvc oneex nwifi dot11emu
REM PCMCIA NDIS miniport drivers
if "%SYSGEN_ETH_XIRCOM%"=="1" set CE_MODULES=%CE_MODULES% xircce2
if "%SYSGEN_ETH_CISCO%"=="1" set CE_MODULES=%CE_MODULES% pcx500
if "%SYSGEN_ETHERNET%"=="1" set CE_MODULES=%CE_MODULES% netmui
REM NDIS interface module
if "%__SYSGEN_NDISUIO%"=="1" set CE_MODULES=%CE_MODULES% ndisuio
REM Internet Connection Sharing
if "%SYSGEN_GATEWAY%"=="1" set CE_MODULES=%CE_MODULES% ipnat
REM MAC Bridge
if "%SYSGEN_BRIDGE%"=="1" set CE_MODULES=%CE_MODULES% mbridge
if not "%SYSGEN_PPP%" == "1" goto no_ppp
REM PPP (Point-to-Point Protocol)
set SYSGEN_MSGQUEUE=1
set CE_MODULES=%CE_MODULES% ppp
REM Optional features that are only interesting when PPP is present
if "%SYSGEN_GATEWAY%"=="1" set CE_MODULES=%CE_MODULES% autodial
if "%SYSGEN_IRDA%"=="1" set CE_MODULES=%CE_MODULES% ircomm
:no_ppp
REM Minimal configs with built in modem can remove these
REM and write a replacement asyncmac that does dialing directly.
if "%SYSGEN_MODEM%"=="1" set CE_MODULES=%CE_MODULES% asyncmac unimodem
if "%SYSGEN_MODEM%"=="1" set SYSGEN_TAPI=1
REM TAPI dialing support.
if "%SYSGEN_TAPI%" == "1" set COREDLL_COMPONENTS=%COREDLL_COMPONENTS% tapilib
if "%SYSGEN_TAPI%" == "1" set CE_MODULES=%CE_MODULES% tapi
if "%SYSGEN_TAPI%" == "1" set __SYSGEN_FILESYS=1
if "%SYSGEN_TAPI%" == "1" set SYSGEN_MINGWES=1
if "%SYSGEN_TAPI%" == "1" set SYSGEN_DEVICE=1
if "%SYSGEN_PPTP%"=="1" set CE_MODULES=%CE_MODULES% pptp
if "%SYSGEN_L2TP%"=="1" set CE_MODULES=%CE_MODULES% l2tp
if "%SYSGEN_PPPOE%"=="1" set CE_MODULES=%CE_MODULES% pppoe
if "%__SYSGEN_IPSEC%"=="1" set CE_MODULES=%CE_MODULES% ipsec ipsecsvc
if "%SYSGEN_SNMP%"=="1" set CE_MODULES=%CE_MODULES% snmp snmp_mibii snmp_hostmib
REM HostMIB requires toolhelp
if "%SYSGEN_SNMP%"=="1" set SYSGEN_TOOLHELP=1
REM // Redirector
if "%SYSGEN_REDIR%"=="1" set __SYSGEN_NETBIOS=1
if "%SYSGEN_REDIR%"=="1" set CE_MODULES=%CE_MODULES% redir
if "%__SYSGEN_NETBIOS%"=="1" set CE_MODULES=%CE_MODULES% netbios
REM Gateway Config UI support
if not "%SYSGEN_GATEWAY_UI%"=="1" goto endgatewayconfig
REM Required Gateway Config pieces
set GATEWAY_CONFIG_COMPONENTS=Admin2 AdminBackupSettings AdminCore AdminPassword AdminReset AdminTime AdminWanLan AdminDMZ RLMClient RLMService
REM Optional Gateway Config pieces
if "%SYSGEN_FTPD%"=="1" set GATEWAY_CONFIG_COMPONENTS=%GATEWAY_CONFIG_COMPONENTS% AdminFTP
if "%SYSGEN_FIREWALL%"=="1" set GATEWAY_CONFIG_COMPONENTS=%GATEWAY_CONFIG_COMPONENTS% AdminServices AdminPC AdminProxyFilter FRMService
if "%SYSGEN_WIFI_AP%"=="1" set GATEWAY_CONFIG_COMPONENTS=%GATEWAY_CONFIG_COMPONENTS% AdminWireless
if "%__SYSGEN_GATEWAY_UI_INTRUSION%"=="1" if "%SYSGEN_FIREWALL%"=="1" set GATEWAY_CONFIG_COMPONENTS=%GATEWAY_CONFIG_COMPONENTS% AdminFWHook
set SERVERS_MODULES=%SERVERS_MODULES% gatewayconfig %GATEWAY_CONFIG_COMPONENTS%
:endgatewayconfig
REM Bluetooth support
REM // Bluetooth
if not "%__SYSGEN_BTH%"=="1" goto endbluetooth
if "%SYSGEN_BTH_GATEWAY%"=="1" set CE_MODULES=%CE_MODULES% btgw btdun
if "%SYSGEN_BTH_GATEWAY%"=="1" if "%SYSGEN_HTTPD%"=="1" set SERVERS_MODULES=%SERVERS_MODULES% btconfig
if "%SYSGEN_BTH_GATEWAY%"=="1" set SERVERS_MODULES=%SERVERS_MODULES% routenbtd
if "%SYSGEN_BTH_MODEM%"=="1" set CE_MODULES=%CE_MODULES% btmodem
set CE_MODULES=%CE_MODULES% btd btdrt btloader
set BTD_COMPONENTS=hci l2cap sdp rfcomm portemu tdi sys
set BTDRT_COMPONENTS=sdpuser bthns
REM Delivered PCMCIA driver samples do not notify the stack
REM of the insertion events. They are best used with universal
REM driver only.
if "%SYSGEN_BTH_UART_ONLY%"=="1" goto :bth_uart_only
if "%SYSGEN_BTH_USB_ONLY%"=="1" goto :bth_usb_only
if "%SYSGEN_BTH_CSR_ONLY%"=="1" goto :bth_csr_only
REM Include all of the BTH Drivers.
set BTD_COMPONENTS=%BTD_COMPONENTS% univ
set BTD_DRIVERS=bthuart bthamb bthsc bthcsr bthuniv wendyser wcestreambt sio950
if "%SYSGEN_USB%"=="1" set BTD_DRIVERS=%BTD_DRIVERS% bthusb
set CE_MODULES=%CE_MODULES% %BTD_DRIVERS%
goto endbluetooth
:bth_uart_only
set BTD_COMPONENTS=%BTD_COMPONENTS% uart
goto endbluetooth
:bth_csr_only
set BTD_COMPONENTS=%BTD_COMPONENTS% csr
goto endbluetooth
:bth_usb_only
set BTD_COMPONENTS=%BTD_COMPONENTS% usb
set BTD_DRIVERS=bthusb
set CE_MODULES=%CE_MODULES% %BTD_DRIVERS%
goto endbluetooth
:endbluetooth
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -