main.bak

房租管理系统。有登记、到期提示、水电费管理等功能。

* 列出所有当前进程
*-----------------------------------------
CLOSE ALL
CLEAR ALL

DECLARE INTEGER GetActiveWindow  IN "user32"
DECLARE INTEGER GetWindow        IN "user32" INTEGER HWND, INTEGER wFlag
DECLARE INTEGER GetWindowText    IN "user32" INTEGER hand, STRING @ctitle, INTEGER ntitle

hCurrent   = GetActiveWindow()    && 从当前活动窗口开始
DO WHILE hCurrent > 0
	lcWinTitle = SPACE(255)
	lnlength   = getwindowtext(hCurrent, @lcWinTitle, LEN(lcWinTitle))
	lcWinTitle = IIF(lnlength>0, STRTRAN(TRIM(lcWinTitle),CHR(0),""), "")
	IF '房租管理'$lcWinTitle
		DECLARE INTEGER ShowWindow IN Win32api INTEGER ,INTEGER  &&区分大小写！
		DECLARE INTEGER SetForegroundWindow IN Win32api INTEGER
		=SHOWWINDOW(hCurrent,1)   &&0 隐藏，1还原，2最小化，3最大化
		=SetForegroundWindow(hCurrent)  &&使当前程序获得焦点
		QUIT
	ENDIF
	hCurrent   = GetWindow (hCurrent, 2)  && 得到下一个窗口句柄
ENDDO

SET CENTURY ON
SET DATE ANSI
SET HOURS TO 24
SET TALK OFF
SET ESCAPE OFF
SET DEBUG OFF
SET DELETED ON
SET MULTILOCKS ON
SET COMPATIBLE ON  &&使fsize()函数返回文件的大小。
SET REFRESH TO 1
SET DEFAULT TO (JUSTPATH(SYS(16)))
SET PATH TO ALLTRIM(STRTRAN(CURDIR(),'\','')),DATA,prg,FORM,PICT
ON ERROR DO errhand WITH ;
	ERROR( ), MESSAGE( ), MESSAGE(1), PROGRAM( ), LINENO( )


vpzwj=SYS(5)+CURDIR()+'\data\bh_pz.dbf'
IF !FILE(vpzwj)
	CREAT TABLE &vpzwj. (空闲颜色 n(10,0),已租颜色 n(10,0),到期颜色 n(10,0),;
		逾期颜色 n(10,0),维修颜色 n(10,0),自用颜色 n(10,0),提醒期限 N(3,0))
	INSE INTO bh_pz (空闲颜色,已租颜色,到期颜色,逾期颜色,维修颜色,自用颜色,提醒期限) ;
		VALUE (0,0,0,0,0,0,3)
ENDIF

DO FORM MAINFRM.scx
READ EVENTS
CLOSE ALL
CLEAR ALL
QUIT

PROCEDURE errhand
PARAMETER merror, mess0, mess1, mprog, mlineno
vxx=;
	'----- 系统遇到了如下错误 -----'+CHR(13)+CHR(13)+CHR(10)+;
	'  日期：' + TTOC(DATETIME())+CHR(13)+CHR(10)+;
	'  错误号：' + LTRIM(STR(merror))+;
	'  错误行号：' + LTRIM(STR(mlineno))+CHR(13)+CHR(10)+;
	'  错误信息：' + mess0+CHR(13)+CHR(10)+;
	'  错误代码行：' + mess1+CHR(13)+CHR(10)+;
	'  产生错误的程序：' + mprog+CHR(13)+CHR(10)

=MESSAGEBOX(vxx,0,'程序错误')
verrfile='err'+DTOS(DATE())+ALLTRIM(LEFT(SYS(0),ATC('#',SYS(0)) - 2))+'.txt'
=STRTOFILE(vxx,verrfile,.T.)   &&记载为文件
IF _SCREEN.FORMCOUNT>0
	_SCREEN.ACTIVEFORM.RELEASE
ELSE
	QUIT
ENDIF
ENDPROC