sz_ram.lcf

来自「FreeScale DragonBall SZ LCD driver sampl」· LCF 代码 · 共 84 行

/*	Sample Linker Command File for M68SZ328ADS ver 1.0 */

/* location to reconfig on new board */

MEMORY {
	TEXT (RX) : ORIGIN = 0x00000400				/* 1. beginning of application RAM, leaving room 
													  for exception vector table in RAM, we may wish 
													  to use it, need to avoid monitor footprint as well
												*/
	DATA (RWX): ORIGIN = AFTER(TEXT)
	
	IMAGE (RWX): ORIGIN = 0x01000000
	
}

SECTIONS {
	
	/* code and read only data in ROM */
	.main_application :
	{
		.= ALIGN(0x8);
		*(.text)
		.= ALIGN(0x8);
		*(.rodata)
	} > TEXT

	/* initialized data and C++ code will be copy to RAM by runtime function */
    .cpp_code :
	{
		. = ALIGN(0x8);
		*(.exception)
		. = ALIGN(0x8);
		__exception_table_start__ = .;
		EXCEPTION
		__exception_table_end__ = .;
		. = ALIGN(0x8);
		___sinit__ = .;
	    STATICINIT
	} > DATA   
	
	.data :
	{  
		. = ALIGN(0x8);
		__START_DATA = .;
		*(.data)
		__END_DATA = .;

		__START_SDATA = .;
		*(.sdata)
		__END_SDATA = .;
		
		__SDA_BASE = .;				/* A5 set to  middle of data and bss ... */
	} >> DATA

	/* uninitialized data in RAM */
	.uninitialized_data :
	{
		__START_SBSS = .;
		*(.sbss)
		*(SCOMMON)
		__END_SBSS = .;

		__START_BSS = .;
		*(.bss)
		*(COMMON)
		__END_BSS = .;	
	} >> DATA
	
	.image_lcd:
	{
		INCLUDE Talk.bin
	} > IMAGE
	
	__S_romp = 0;							/* RAM target need to have a null for ROM table */
	
	_stack_address = __END_BSS;
	_stack_address = ((_stack_address + (8)-1)&(~((8)-1)));		/* align top of stack by 8 after end of bss */
	__SP_INIT = _stack_address + 0x00004000;	/* set stack to 0x4000 bytes (16KB) */
												
	___heap_addr = __SP_INIT;		/* heap grows in opposite direction of stack */
	___heap_size = 0x50000;			/* heap size set to 0x50000 bytes (500KB) */

}