checkright.asp

来自「投资管理系统, asp+ mssql server」· ASP 代码 · 共 1,233 行 · 第 1/4 页

ASP
1,233 行
字号
1234
<%
'*******************************************************************************************************
'                                      公共函数库
'版 本 号：	3.0
'设计人员：	黄先强  李文俊
'设计日期：	2001.2	至   2001.9
'
'适用范围：
'			基于B/S的软件开发均可使用，其中公用的函数和过程对于其它的项目也同样实用；
'遵循原则：
'			函数和过程应分开，公用函数和过程应与特定系统使用的函数和过程分开；
'
'*******************************************************************************************************


'*******************************************************************************************************
'                                           公用   函数
'*******************************************************************************************************

FUNCTION GetSpeStr(DispStr,RepStr,DispLens,RepType)
	corpvar=""
	varlen=len(DispStr)
	for i=1 to DispLens-varlen
		corpvar=corpvar&RepStr
	next

	select case UCase(RepType)
	case "L"	'在左边循环
		corpvar=corpvar & DispStr
	case "R"	'在右边循环
		corpvar=DispStr & corpvar
	case else	'在左边循环
		corpvar=corpvar & DispStr
	end select

	GetSpeStr=corpvar
END FUNCTION

FUNCTION SetPages(PPageSize,SqlStr,StrConn,CurPage)
	dim SPrs,SPageSize

	set SPrs=server.createobject("ADODB.RecordSet")
	SPrs.open SqlStr,StrConn,1,1
	SPageSize=PPageSize
	if SPageSize="" then
		SPageSize=20	'如果系统中可设置每页默认显示记录数，则此处用SESSION变量代替“20”
	end if

	SPrs.pagesize=SPageSize
	PageSize=SPageSize
	PageCount=SPrs.pagecount
	RecordCount=SPrs.recordcount

	if CurPage<>"" and isnumeric(CurPage) then
		CurrentPage=cint(CurPage)

		if CurrentPage>PageCount then
			CurrentPage=PageCount
		elseif CurrentPage<1 then
			CurrentPage=1
		end if
	else
		if SPrs.RecordCount>0 then
			CurrentPage=1
		else
			CurrentPage=0
		end if
	end if	

	if not SPrs.eof and not SPrs.bof then
		SPrs.absolutepage=CurrentPage
		ResArr=SPrs.getrows(SPageSize)
		SetPages=TRUE
	else
		SetPages=FALSE
	end if
	SPrs.close
	set SPrs=nothing
END FUNCTION

FUNCTION GetPages(DispStr)
	dim BRecNum,ERecNum,ResultValue
	BRecNum=(CurrentPage-1) * PageSize + 1
	if BRecNum<0 then
		BRecNum=0
	end if
	if CurrentPage>=PageCount then
		ERecNum=RecordCount
	else
		ERecNum=CurrentPage * PageSize
	end if
	ResultValue="第<b><font color='#FF0000'> " & BRecNum & "</font></b>～<b><font color='#FF0000'>" & ERecNum & "</font></b> " & DispStr
	ResultValue=ResultValue & "/共<font color='#FF0000'><b> " & RecordCount & " </b></font>" & DispSTR
	ResultValue=ResultValue & "，第 <b><font color='#FF0000'> " & CurrentPage & " </font></b>页/共 <font color='#FF0000'><b> " & PageCount & " </b></font>页"
	GetPages=ResultValue
END FUNCTION

'=============================================================================================
'     f
'=============================================================================================
FUNCTION get_chinese(dispnums)
	dim resultarr(9)
	dim resultstr
	resultarr(0)="Ο"
	resultarr(1)="一"
	resultarr(2)="二"
	resultarr(3)="三"
	resultarr(4)="四"
	resultarr(5)="五"
	resultarr(6)="六"
	resultarr(7)="七"
	resultarr(8)="八"
	resultarr(9)="九"
	resultstr123=""
	for ii=1 to len(dispnums)
		resultstr123=resultstr123 & resultarr(cint(mid(cstr(dispnums),ii,1)))
	next
	get_chinese=resultstr123
END FUNCTION

'=============================================================================================

'=============================================================================================
FUNCTION GetSafeStr(OldStr)
	dim sTmpStr
	sTmpStr=OldStr
	sTmpStr=trim(sTmpStr)
	sTmpStr=replace(sTmpStr,"'","''")
	sTmpStr=replace(sTmpStr,"""","&quot;")
	sTmpStr=replace(sTmpStr,"<","&lt;")
	sTmpStr=replace(sTmpStr,">","&gt;")
	GetSafeStr=sTmpStr
END FUNCTION

'*******************************************************************************************************
'                                           公用   过程
'*******************************************************************************************************


'========================================================================================

'=======================================================================================================
SUB ConfirmSubmit(FormName,ObjAction,DispStr,VarHid1,Hid1Value,VarHid2,Hid2Value,VarHid3,Hid3Value)
	response.write "<script language=""JavaScript"">"  & chr(13)
	response.write "function ConfirmSubmit()" & chr(13)
	response.write "{" & chr(13)
	response.write "     var isconfirm=window.confirm('" & DispStr & "');" & chr(13)
	response.write "     if(isconfirm==1)" & chr(13)
	response.write "     {" & chr(13)
	if trim(VarHid1)<>"" then
		response.write "           " & FormName & "." & trim(VarHid1) & ".value='" & Hid1Value & "';" & chr(13)
	end if
	if trim(VarHid2)<>"" then
		response.write "           " & FormName & "." & trim(VarHid2) & ".value='" & Hid2Value & "';" & chr(13)
	end if
	if trim(VarHid3)<>"" then
		response.write "           " & FormName & "." & trim(VarHid3) & ".value='" & Hid3Value & "';" & chr(13)
	end if
	if trim(ObjAction)<>"" then
		response.write "           " & FormName & ".Action=" & ObjAction & chr(13)
	end if
	response.write "           " & FormName & ".submit();" & chr(13)
	response.write "           return true;" & chr(13)
	response.write "     }" & chr(13)

	response.write "     else" & chr(13)
	response.write "           return false;" & chr(13)
	response.write "}" & chr(13)
	response.write "</script>" & chr(13)
END SUB

'========================================================================================

'=======================================================================================================
SUB PutPageUpDown(FormName,VarHid1,Hid1Value,VarHid2,Hid2Value,VarHid3,Hid3Value)
if RecordCount>0 then
   response.write "<script language=""JavaScript"">" & chr(13)
   response.write "	function pageupdown(updnpg)" & chr(13)
   response.write "	{" & chr(13)

   response.write "		" & FormName & ".page.value=updnpg;" & chr(13)
   if trim(VarHid1)<>"" then
	   response.write "		" & FormName & "." & trim(VarHid1) & ".value='" & Hid1Value & "';" & chr(13)
   end if
   if trim(VarHid2)<>"" then
	   response.write "		" & FormName & "." & trim(VarHid2) & ".value='" & Hid2Value & "';" & chr(13)
   end if
   if trim(VarHid3)<>"" then
	   response.write "		" & FormName & "." & trim(VarHid3) & ".value='" & Hid3Value & "';" & chr(13)
   end if

   response.write "		" & FormName & ".submit();" & chr(13)
   response.write " }" & chr(13)
   response.write "</script>" & chr(13)

   if CurrentPage>1 then
      response.write "【<a href=""JavaScript:pageupdown(1)"">首页</a>】"
      response.write "【<a href=""JavaScript:pageupdown(" & CurrentPage-1 & ")"">上一页</a>】"
   else
      response.write "<font color=""#666666"">【首页】</font>"
      response.write "<font color=""#666666"">【上一页】</font>"
   end if
   if CurrentPage<PageCount then
      response.write "【<a href=""JavaScript:pageupdown(" & CurrentPage+1 & ")"">下一页</a>】"
      response.write "【<a href=""JavaScript:pageupdown(" & PageCount & ")"">尾页</a>】"
   else
      response.write "<font color=""#666666"">【下一页】</font>"
      response.write "<font color=""#666666"">【尾页】</font>"
   end if
   response.write "　　跳到第<input type=""text"" size=""4"" name=""page"" value=""" & GetSpeStr(CurrentPage," ",4,"L") &""">页<a href='JavaScript:"& FormName &".submit()'><img src=""../images/menu/searchgo.gif"" border=""0""></a>"
   '<input class=buttoncss type=""button"" name=""go"" value=""==>"" OnClick=""this.form.submit()
end if
END SUB

'==================================================================================

'=======================================================================================================
SUB PutSelectObject(SelObjName,PutTypeStr,CompValue,EventStr,SqlStr,ConnStr)
	dim PSrs
	set PSrs=ConnStr.Execute(SqlStr)
	response.write "<select name=""" & SelObjName & """" & chr(13)

	if trim(EventStr)<>"" then
		response.write " " & EventStr
	end if

	response.write ">"
	if trim(PutTypeStr)<>"" then
		response.write "<option value="""">" & PutTypeStr & "</option>" & chr(13)
	end if

	while not PSrs.eof
		response.write "     <option value=""" & PSrs(0) & """"
		if cstr(PSrs(0))=cstr(CompValue) then
			response.write " selected"
		end if
		response.write ">" & PSrs(1) & "</option>" & chr(13)
		PSrs.MoveNext
	wend
	response.write "</select>"
	PSrs.close
	set PSrs=nothing
END SUB

'==================================================================================

'=======================================================================================================
SUB PutPromptInfo(DispStr)
	response.write "<script language='JavaScript'>" & chr(13)
	response.write "  alert('" & replace(DispStr,"'","\'") & "');"
	response.write "</script>" & chr(13)
END SUB

'=====================================================================================
'		s
'=====================================================================================
SUB PutErrorInfo(DispStr)
	response.write "<script language='JavaScript'>" & chr(13)
	response.write "  alert('" & replace(DispStr,"'","\'") & "');"
	response.write "window.history.back();"
	response.write "</script>" & chr(13)
END SUB

'==========================================================================

'=======================================================================================================
SUB PutDate(SelObjName,BeginDate,EndDate,CurrDate,DateType)
	dim i,CurrDateValue
	response.write "<select name=""" & trim(SelObjName) & """>" & chr(13)
	if trim(cstr(CurrDate))="" then
		select case ucase(trim(DateType))
		case "YEAR"
			CurrDateValue=year(now)
		case "MONTH"
			CurrDateValue=month(now)
		case "DAY"
			CurrDateValue=day(now)
		case else	'其它情况默认为当前年份；
			CurrDateValue=year(now)
		end select
	else
		CurrDateValue=CurrDate
	end if

	for i=BeginDate to EndDate
		response.write "<option value=""" & i & """"
		if i=CurrDateValue then
			response.write " selected"
		end if
		response.write ">" & i & "</option>" & chr(13)
	next
	response.write "</select>" & chr(13)
END SUB

'=============================================================================================

'=============================================================================================
sub  InsertData(strSql,strConn,strSuccessInfo)
	on error resume next
	strConn.execute(strSql)
	if strConn.Errors.Count>0 then
		PutInsertErrInf ()
	else
		call PutPromptInfo(strSuccessInfo)
	end if
end sub

'=============================================================================================
1234

checkright.asp - 源码说明

本页面展示了「投资管理系统, asp+ mssql server」中的 checkright.asp 源码文件，采用 ASP 编程语言编写，共 1,233 行代码。您可以在线阅读完整代码内容，也可以返回资源详情页下载完整源码包进行本地学习和开发。

虫虫开发者社区收录了大量与投资管理相关的技术资源，包括源代码、技术文档、电路图等，是电子工程师和嵌入式开发者的专业学习平台。

⌨️ 快捷键说明

复制代码Ctrl + C
搜索代码Ctrl + F
全屏模式F11
增大字号Ctrl + =
减小字号Ctrl + -
显示快捷键?