msp430x20x3_usi_08.s43

MSP430F20xx系列单片机汇编源代码

;******************************************************************************
;  MSP430F20xx Demo - I2C Slave Receiver, single byte
;
;  Description: I2C Slave communicates with I2C Master using
;  the USI. Master data should increment from 0x00 with each transmitted byte
;  which is verified by the slave.
;  LED off for address or data Ack; LED on for address or data NAck.d by the slave.
;  ACLK = n/a, MCLK = SMCLK = Calibrated 1MHz
;
;  ***THIS IS THE SLAVE CODE***
;
;                  Slave                      Master
;                                      (msp430x20x3_usi_07.s43)
;               MSP430F20x2/3              MSP430F20x2/3
;             -----------------          -----------------
;         /|\|              XIN|-    /|\|              XIN|-
;          | |                 |      | |                 |
;          --|RST          XOUT|-     --|RST          XOUT|-
;            |                 |        |                 |
;      LED <-|P1.0             |        |                 |
;            |                 |        |             P1.0|-> LED
;            |         SDA/P1.7|<-------|P1.7/SDA         |
;            |         SCL/P1.6|<-------|P1.6/SCL         |
;
;  Note: internal pull-ups are used in this example for SDA & SCL
;
;  P. Thanigai
;  Texas Instruments Inc.
;  May 2007
;  Built with IAR Embedded Workbench Version: 3.42A
;******************************************************************************
#include  "msp430x20x2.h"

#define    I2CState  R4
#define    MST_data  R5
#define    slav_add  R6          
;-------------------------------------------------------------------------------
            RSEG    CSTACK                  ; Define stack segment
;-------------------------------------------------------------------------------
            RSEG    CODE                    ; Assemble to Flash memory
            EVEN
;-------------------------------------------------------------------------------    
RESET       mov.w   #SFE(CSTACK),SP         ; Initialize stackpointer
StopWDT     mov.w   #WDTPW+WDTHOLD,&WDTCTL  ; Stop watchdog timer
SetupDCO    mov.b   &CALBC1_1MHZ,&BCSCTL1   ; Set DCO 
            mov.b   &CALDCO_1MHZ,&DCOCTL
SetupP1     mov.b   #0xC0,&P1OUT            ; P1.6 & P1.7 pullups      
            bis.b   #0xC0,&P1REN
            mov.b   #0xFF,&P1DIR            ; unused pins in output direction
SetupP2     clr.b   &P2OUT                  
            mov.b   #0xFF,&P2DIR            
SetupUSI    mov.b   #USIPE6+USIPE7+USISWRST,&USICTL0; Port, USI mode setup
            mov.b   #USIIE+USII2C+USISTTIE,&USICTL1 ; Enable I2C mode,interrupts
            mov.b   #USICKPL,&USICKCTL      ; Setup clock polarity
            bis.b   #USIIFGCC,&USICNT       ; Disable automatic clear control
            bic.b   #USISWRST,&USICTL0      ; Enable USI
            bic.b   #USIIFG,&USICTL1        ; Clear pending flag
            clr.w   I2CState
            clr.b   MST_data
            mov.b   #0x90,slav_add                                           
Mainloop         
            bis.w   #LPM0+GIE,SR            ; Enter LPM0, enable interrupts
            nop                             ; Set breakpoint here
            jmp     Mainloop                ; Again                                           
;-------------------------------------------------------------------------------
USI_ISR  ;
;-------------------------------------------------------------------------------
            bit.b   #USISTTIFG,&USICTL1     ; Start entry?
            jnc     Check_State
            bis.b   #0x01,&P1OUT            ; turn on LED, sequence start
            mov.w   #2,I2CState             ; First I2C state, Rx address
Check_State add.w   I2CState,PC             ; I2C State Machine
            jmp     STATE0                  
            jmp     STATE2
            jmp     STATE4
            jmp     STATE6
            jmp     STATE8
            jmp     STATE10
     
STATE0      nop                             ; Idle, should not get here
            bic.b   #USIIFG,&USICTL1
            reti 
STATE2                                      ; Rx address           
            mov.b   &USICNT,R8              ; Bit counter = 8, Rx address
            and.b   #0xE0,R8
            add.b   #0x8,R8
            mov.b   R8,&USICNT
            bic.b   #USISTTIFG,&USICTL1     ; Clear Start flag
            mov.w   #4,I2CState             ; Go to next state, chk address
            bic.b   #USIIFG,&USICTL1
            reti           
STATE4                                      ; Process address and send (N)Ack
            bit.b   #0X01,&USISRL           ; If read
            jnc     Chk_Add
            inc.b   slav_add                ; Save R/W bit
Chk_Add     bis.b   #USIOE,&USICTL0         ; SDA = output
            cmp.b   slav_add,&USISRL        ; Address match?
            jnz     Add_NACK                ; Send Nack
            clr.b   &USISRL
            bic.b   #0x01,&P1OUT            ; LED off
            mov.w   #8,I2CState             ; Go to next state: Rx data
            bis.b   #0x01,&USICNT           ; Bit counter = 1, Send Ack
            bic.b   #USIIFG,&USICTL1
            reti
Add_NACK
            mov.b   #0xFF,&USISRL           ; Send NACK
            bis.b   #0x1,&P1OUT             ; LED on:error
            mov.w   #6,I2CState             ; Go to nxt state,prep for nxt start
            bis.b   #0x01,&USICNT
            bic.b   #USIIFG,&USICTL1 
            reti                      
STATE6                                      ; Prep for Re-start condition
            bic.b   #USIOE,&USICTL0         ; SDA = input
            mov.b   #0x90,slav_add          ; Reset Slave address
            clr.w   I2CState                ; Reset state machine
            bic.b   #USIIFG,&USICTL1
            reti
STATE8                                      ; Rx data byte
            bic.b   #USIOE,&USICTL0         ; SDA =input
            bis.b   #0x8,&USICNT            ; Bit counter = 8, Rx data
            mov.w   #10,I2CState            ; go to next state,Test data,(N)Ack
            bic.b   #USIIFG,&USICTL1 
            reti          
STATE10  
            bis.b   #USIOE,&USICTL0         ; SDA = output
            cmp.b   MST_data,&USISRL        ; if data valid...
            jne     Data_NACK
            clr.b   &USISRL                 ; send Ack
            inc.b   MST_data                ; Increment Master data
            bic.b   #0x1,&P1OUT             ; LED off
            jmp     STATE10_Exit                     
Data_NACK          
            mov.b    #0xFF,&USISRL          ; Send Nack
            bis.b    #0x1,&P1OUT            ; LED on : error
STATE10_Exit            
            bis.b    #0x1,&USICNT           ; Bit counter= 1
            mov.w    #6,I2CState            ; Prep for next start
            bic.b    #USIIFG,&USICTL1 
            reti       
;-------------------------------------------------------------------------------
;           Interrupt Vectors Used MSP430x2013
;-------------------------------------------------------------------------------
            COMMON  INTVEC
            ORG     RESET_VECTOR            ; MSP430 RESET Vector
            DW      RESET                   ;
            ORG     USI_VECTOR              ; USICNT
            DW      USI_ISR                 ;
            END