gpio.cmd

DSP2812 GPIO口读数的工程文件

/*
//============================================================================
//File:  Linker command file for Boot to RAM for emulating FOR 2812.
//这个程序将2812所有的存储空间都写了出来，你可以根据自己的需要修改以下内容：
//1、程序存储区的位置与大小
//2、数据存储区的位置与大小
//3、程序的入口地址，你可以选择从ROM、PRAM、FLASH中启动程序，这时要相应地修改程序存储区的值
//编程作者：
//编写时间：
//============================================================================
*/
MEMORY
{
 PAGE 0:    	/* Program Memory */ 
    
    RAMM0       : origin = 0x000000, length = 0x000400     /* on-chip RAM block M0 */
   	RAMM1       : origin = 0x000400, length = 0x000400     /* on-chip RAM block M1 */ 
 	ZONE0       : origin = 0x002000, length = 0x002000     /* XINTF zone 0 */
   	ZONE1       : origin = 0x004000, length = 0x002000     /* XINTF zone 1 */
   	RAML0       : origin = 0x008000, length = 0x001000     /* on-chip RAM block L0 */  
   	RAML1       : origin = 0x009000, length = 0x001000     /* on-chip RAM block L1 */  
   	ZONE2       : origin = 0x080000, length = 0x080000     /* XINTF zone 2 */
   	ZONE6       : origin = 0x100000, length = 0x080000     /* XINTF zone 6 */
   	OTP         : origin = 0x3D7800, length = 0x000800     /* on-chip OTP */
   	FLASH_IJ    : origin = 0x3D8000, length = 0x004000     /* on-chip FLASH */
   	FLASH_GH    : origin = 0x3DC000, length = 0x008000     /* on-chip FLASH */
   	FLASH_EF    : origin = 0x3E4000, length = 0x008000     /* on-chip FLASH */
   	FLASH_CD    : origin = 0x3EC000, length = 0x008000     /* on-chip FLASH */
   	FLASH_AB    : origin = 0x3F4000, length = 0x003F80     /* on-chip FLASH */
   	CSM_RSVD    : origin = 0x3F7F80, length = 0x000076     /* Part of FLASHA.  Reserved when CSM is in use. */
   	BEGIN_FLASH : origin = 0x3F7FF6, length = 0x000002     /* Part of FLASHA.  Used for "boot to flash" bootloader mode. */
   	PASSWORDS   : origin = 0x3F7FF8, length = 0x000008     /* Part of FLASHA.  CSM password locations. */
   	BEGIN_H0    : origin = 0x3F8000, length = 0x000002     /* Part of H0.  Used for "boot to H0" bootloader mode. */
   	PRAMH0      : origin = 0x3F8002, length = 0x0017FE     /* H0 SARAM */
   	DRAMH0		: origin = 0x3F9800, length = 0x000800     /* DH0 SARAM */
/*   ZONE7       : origin = 0x3FC000, length = 0x003FC0     /* XINTF zone 7 available if MP/MCn=1 */ 
   	ROM         : origin = 0x3FF000, length = 0x000FC0     /* boot ROM available if MP/MCn=0 */
   	RESET       : origin = 0x3FFFC0, length = 0x000002     /* part of boot ROM (MP/MCn=0) or XINTF zone 7 (MP/MCn=1) */
   	VECTORS     : origin = 0x3FFFC2, length = 0x00003E     /* part of boot ROM (MP/MCn=0) or XINTF zone 7 (MP/MCn=1  */
   
 PAGE 1:      	/*system registers*/  
 
   	DEV_EMU     : origin = 0x000880, length = 0x000180     /* device emulation registers */
   	PIE_VECT    : origin = 0x000D00, length = 0x000100     /* PIE Vector Table */
   	FLASH_REGS  : origin = 0x000A80, length = 0x000060     /* FLASH registers */
   	CSM         : origin = 0x000AE0, length = 0x000010     /* code security module registers */
   	XINTF       : origin = 0x000B20, length = 0x000020     /* external interface registers */
   	CPU_TIMER0  : origin = 0x000C00, length = 0x000008     /* CPU Timer0 registers (CPU Timer1 and Timer2 are reserved for BIOS)*/
   	PIE_CTRL    : origin = 0x000CE0, length = 0x000020     /* PIE control registers */
   	ECANA       : origin = 0x006000, length = 0x000040     /* eCAN control and status registers */ 
   	ECANA_LAM   : origin = 0x006040, length = 0x000040     /* eCAN local acceptance masks */
   	ECANA_MOTS  : origin = 0x006080, length = 0x000040     /* eCAN message object time stamps */
   	ECANA_MOTO  : origin = 0x0060C0, length = 0x000040     /* eCAN object time-out registers */
   	ECANA_MBOX  : origin = 0x006100, length = 0x000100     /* eCAN mailboxes */
   	SYSTEM      : origin = 0x007010, length = 0x000020     /* System control registers */
   	SPIA        : origin = 0x007040, length = 0x000010     /* SPI registers */
   	SCIA        : origin = 0x007050, length = 0x000010     /* SCI-A registers */
   	XINTRUPT    : origin = 0x007070, length = 0x000010     /* external interrupt registers */
   	GPIOMUX     : origin = 0x0070C0, length = 0x000020     /* GPIO mux registers */
   	GPIODAT     : origin = 0x0070E0, length = 0x000020     /* GPIO data registers */
   	ADC         : origin = 0x007100, length = 0x000020     /* ADC registers */
   	EVA         : origin = 0x007400, length = 0x000040     /* Event Manager A registers */
   	EVB         : origin = 0x007500, length = 0x000040     /* Event Manager B registers */
   	SCIB        : origin = 0x007750, length = 0x000010     /* SCI-B registers */
   	MCBSPA      : origin = 0x007800, length = 0x000040     /* McBSP registers */ 
   	CSM_PWL     : origin = 0x3F7FF8, length = 0x000008     /* Part of FLASHA.  CSM password locations. */ 
  	
}

 
SECTIONS
{
   	
   /* Allocate program areas: */
   .reset           : > PRAMH0,      PAGE = 0
   .text            : > PRAMH0,      PAGE = 0
   .cinit           : > PRAMH0,      PAGE = 0

   /* Allocate data areas: */
   .stack           : > RAMM1,       PAGE = 0
   .bss             : > DRAMH0,      PAGE = 0
   .ebss            : > DRAMH0,      PAGE = 0
   .const           : > DRAMH0,      PAGE = 0
   .econst          : > DRAMH0,      PAGE = 0      
   .sysmem          : > DRAMH0,      PAGE = 0
   
/*** Peripheral Frame 0 Register Structures ***/
   	DevEmuRegsFile    : > DEV_EMU,     PAGE = 1
   	FlashRegsFile     : > FLASH_REGS,  PAGE = 1
   	CsmRegsFile       : > CSM,         PAGE = 1
   	XintfRegsFile     : > XINTF,       PAGE = 1
   	CpuTimer0RegsFile : > CPU_TIMER0,  PAGE = 1  
   	PieCtrlRegsFile   : > PIE_CTRL,    PAGE = 1      
    PieVectTableFile  : > PIE_VECT,    PAGE = 1
    
/*** Peripheral Frame 1 Register Structures ***/
   	SysCtrlRegsFile   : > SYSTEM,      PAGE = 1
   	SpiaRegsFile      : > SPIA,        PAGE = 1
   	SciaRegsFile      : > SCIA,        PAGE = 1
   	XIntruptRegsFile  : > XINTRUPT,    PAGE = 1
   	GpioMuxRegsFile   : > GPIOMUX,     PAGE = 1
   	GpioDataRegsFile  : > GPIODAT      PAGE = 1
   	AdcRegsFile       : > ADC,         PAGE = 1
   	EvaRegsFile       : > EVA,         PAGE = 1
   	EvbRegsFile       : > EVB,         PAGE = 1
   	ScibRegsFile      : > SCIB,        PAGE = 1
   	McbspaRegsFile    : > MCBSPA,      PAGE = 1

/*** Peripheral Frame 2 Register Structures ***/
   	ECanaRegsFile     : > ECANA,       PAGE = 1
   	ECanaLAMRegsFile  : > ECANA_LAM    PAGE = 1   
   	ECanaMboxesFile   : > ECANA_MBOX   PAGE = 1
   	ECanaMOTSRegsFile : > ECANA_MOTS   PAGE = 1
   	ECanaMOTORegsFile : > ECANA_MOTO   PAGE = 1

/*** Code Security Module Register Structures ***/  
   	CsmPwlFile        : > CSM_PWL,     PAGE = 1 
   	
/*** User Defined Sections ***/
   codestart         : > BEGIN_H0,     PAGE = 0                /* Used by file CodeStartBranch.asm */
   csm_rsvd          : > CSM_RSVD,     PAGE = 0                /* Used by file passwords.asm */
   passwords         : > PASSWORDS,    PAGE = 0                /* Used by file passwords.asm */
   pie_vect          : > PIE_VECT,     PAGE = 1
/*   secureRamFuncs    :   LOAD = FLASH_AB,  PAGE = 0                /* Used by InitFlash() in SysCtrl.c */ 
/*                         RUN = RAML0,      PAGE = 0 
                         LOAD_START(_secureRamFuncs_loadstart),
                         LOAD_END(_secureRamFuncs_loadend),
                         RUN_START(_secureRamFuncs_runstart) */         
}


/******************* end of file ************************/