📄 bookssaleview.asp

📁 所在类别：随书资源/T　工业技术/TP 自动化技术、计算机技术/TP31 计算机软件其他题名：作者：夏邦贵, 刘凡馨等编著出版者：机械工业出版社出版年： 2006 I

💻 ASP

字号:

<%@ LANGUAGE="VBScript"  %><% Response.Buffer=true %>
<HTML>
<HEAD>
    <TITLE>在线图书销售管理系统</TITLE>
    <META content="text/html; charset=gb2312" http-equiv="Content-Type">
    <LINK href="adminstyle.css" rel="stylesheet" type="text/css"> 
</HEAD>
<BODY>
<!--   显示图书订单 -->
<% 
'建立数据库连接
Set cn=Server.CreateObject("ADODB.Connection") 
cn.connectionstring="Provider=SQLOLEDB;UID=sa;pwd=123;" & _
              "DataBase=图书销售;Data Source=(local)"
cn.Open 
'访问数据库获得图书订单数据
Set rsbooks=Server.CreateObject("ADODB.Recordset")
querystr = "select sale_Date,user_name,订购记录.user_id from 订购记录,注册用户 " _ 
          & "where 订购记录.user_id=注册用户.user_id " _ 
          & "group by sale_date,user_name,订购记录.user_id order by sale_Date desc,user_name"
Set rsbooks.ActiveConnection = cn
rsbooks.CursorType =3
rsbooks.LockType = 1
rsbooks.PageSize=10   '设置记录集分页大小
rsbooks.Open querystr
%>
<CENTER>
<H3>在线图书销售系统--查看图书订单</H3>
<HR>
<TABLE CELLPADDING="3" BORDER="0">
	<TR>
    <TD CLASS="header"></TD>
		<TD CLASS="header" Align="Center">用户名</TD>
    <TD CLASS="header" Align="Center">订购日期</TD>
	</TR>
<% '以表格形式输出图书订单
  n=1
  if request("rspageindex")<>"" then
     rsbooks.AbsolutePage=request("rspageindex")
     n=(rsbooks.AbsolutePage-1)*rsbooks.PageSize+1 
  end if
  thispageindex=rsbooks.AbsolutePage 
	m=1
  while m<=rsbooks.PageSize and not rsbooks.eof
		   Response.Write "<TR>"
		   Response.Write "<TD ALIGN=CENTER>"
  %>
	<FORM ACTION="BooksSaleDetail.asp?UserID=<%=rsbooks.Fields(2)%>&SaleDate=<%=rsbooks.Fields(0)%>" METHOD="POST"> 
  		<INPUT TYPE="submit" NAME="Edit" VALUE="详细内容">
	</FORM>
<%  Response.Write "</TD><TD>"
		Response.Write rsbooks.Fields(1).Value
    Response.Write "</TD><TD>"
    Response.Write year(rsbooks.Fields(0).Value)
    Response.Write "年"
    Response.Write month(rsbooks.Fields(0).Value)
    Response.Write "月"
    Response.Write day(rsbooks.Fields(0).Value)
    Response.Write "日"
    Response.Write "</TD>"    
		Response.Write "</TR>"
		rsbooks.MoveNext
    m=m+1
	Wend
%>
</TABLE>
<% 
  if rsbooks.pagecount>1 then   '显示记录集分页链接
      response.write "<p><div align=center>共"
      response.write rsbooks.pagecount
      response.write "页:&nbsp;"
      for i=1 to rsbooks.pagecount
        if i <> thispageindex then 
           response.write "<a href=BooksSaleView.asp?rspageindex="
           response.write i           
           response.write ">"
           response.write i        
           response.write "</a>&nbsp;"
        else
           response.write i
           response.write "&nbsp;"
        end if
      next 
      response.write "</div>"
   end if
	rsbooks.Close
  cn.Close
  set rsbooks=nothing
  set cn=nothing
%>
</CENTER>
</BODY>
</HTML>

⌨️ 快捷键说明

复制代码 Ctrl + C

搜索代码 Ctrl + F

全屏模式 F11

切换主题 Ctrl + Shift + D

显示快捷键 ?

增大字号 Ctrl + =

减小字号 Ctrl + -