frmclass.frm

所在类别： 随书资源/T 工业技术/TP 自动化技术、计算机技术/TP31 计算机软件 其他题名： 作者： 夏邦贵, 刘凡馨等编著 出版者： 机械工业出版社 出版年： 2006 I

        .CursorType = adOpenStatic              '指定使用静态游标
        .LockType = adLockOptimistic
        .Open "SELECT * FROM 课程信息"          '获取课程信息记录
    End With
    '建立教师姓名列表
    cmbTeacher.AddItem ""                        '添加一个空的列表项
    With objTeacher
        If .RecordCount > 0 Then
            .MoveFirst
            While Not .EOF
                cmbTeacher.AddItem .Fields("姓名")
                .MoveNext
            Wend
        End If
    End With
    '触发按钮单击事件，显示第一个记录
    cmdMove(0).Value = True
End Sub

Private Sub cmdMove_Click(Index As Integer)
    With objClass
        Select Case Index           '切换当前记录
            Case 0                  '使第一个记录成为当前记录
                If .RecordCount > 0 And Not .BOF Then .MoveFirst
            Case 1                  '使上一个记录成为当前记录
                If .RecordCount > 0 And Not .BOF Then
                    .MovePrevious
                    If .BOF Then .MoveFirst
                End If
            Case 2                  '使下一个记录成为当前记录
                If .RecordCount > 0 And Not .EOF Then
                    .MoveNext
                    If .EOF Then .MoveLast
                End If
            Case 3                  '使最后一个记录成为当前记录
                If .RecordCount > 0 And Not .EOF Then .MoveLast
        End Select
        If .RecordCount < 1 Then
            txtNews = "记录：无"    '显示无记录提示
            txtNum = ""
            txtName = ""
            txtScore = ""
            cmbTeacher.ListIndex = 0
        Else
            '显示当前记录数据
            ShowData
        End If
    End With
    If isAdding Then isAdding = False '改变当前记录则退出当前添加记录状态
End Sub

Private Sub cmdAdd_Click()
    txtNews = "添加新记录"
    txtNum = ""
    txtName = ""
    txtScore = ""
    cmbTeacher.ListIndex = 1     '设置默认任课教师姓名
    isAdding = True
End Sub

Private Sub cmdDelete_Click()
    '根据是否处于添加记录状态执行不同的操作
    If isAdding Then
        '退出添加记录状态，显示当前记录
        isAdding = False
        If objClass.RecordCount < 1 Then
            txtNews = "记录：无"    '显示无记录提示
            '清空各个控件
            txtNum = ""
            txtName = ""
            txtScore = ""
            cmbTeacher.ListIndex = 0
        Else
            '显示当前记录数据
            ShowData
        End If
    Else
        If objClass.RecordCount > 0 Then
            '检查在课程编号是否被《选课记录》表引用
            '如果被使用，则不执行删除操作
            Dim objTemp As New Recordset
            With objTemp
                Set .ActiveConnection = objCn           '设置数据库联接
                .CursorLocation = adUseClient           '指定使用客户端游标
                .CursorType = adOpenStatic              '指定使用静态游标
                '检查课程编号是否被《选课记录》表引用
                .Open "SELECT TOP 1 * FROM 选课记录 WHERE 课编号='" & Trim(txtNum) & "'"
                If .RecordCount > 0 Then
                    MsgBox "编号被《选课记录》表使用，不能删除当前记录！", vbInformation, "课程信息管理"
                    .Close                  '关闭对象
                    Set objTemp = Nothing   '释放对象
                    Exit Sub
                End If
                .Close                      '关闭对象
            End With
            Set objTemp = Nothing           '释放对象
            '可以删除，请求确认执行删除操作
            If MsgBox("是否删除当前记录？", vbYesNo + vbQuestion, "课程信息管理") = vbYes Then
                '执行删除当前记录操作
                objClass.Delete
                '显示下一记录数据
                cmdMove(2).Value = True
            Else
                '显示当前记录数据
                ShowData
            End If
        End If
    End If
End Sub
Private Sub cmdSave_Click()
    '在当前表中无数据和不是添加记录时，不执行保存操作
    If Not isAdding And objClass.RecordCount < 1 Then Exit Sub
    '获得当前记录数据
    Dim strNum$, strName$, strScore$, strTeacher$
    strNum = Trim(txtNum)
    strName = Trim(txtName)
    strScore = Trim(txtScore)
    '根据教师姓名获得教师编号
    If cmbTeacher <> "" Then
        objTeacher.MoveFirst
        objTeacher.Find "姓名='" & cmbTeacher & "'"
        strTeacher = objTeacher.Fields("编号")
    End If
    '检验是否输入课程名称
    If strName = "" Then
        MsgBox "课程名称不能为空！", vbCritical, "课程信息管理"
        txtName.SetFocus
        txtName = ""
        Exit Sub
    End If
    '检验是否输入课程编号
    If Len(strNum) <> 8 Then
        MsgBox "课程编号必须为8位数字！", vbCritical, "课程信息管理"
        txtNum.SetFocus
        txtNum.SelStart = 0
        txtNum.SelLength = Len(txtNum)
        Exit Sub
    End If
    '检验是否输入学分
    If strScore = "" Then
        MsgBox "课程学分不能为空！", vbCritical, "课程信息管理"
        txtScore.SetFocus
        txtScore.SelStart = 0
        txtScore.SelLength = Len(txtScore)
        Exit Sub
    End If
    '检验选择了任课教师
    If cmbTeacher = "" Then
        MsgBox "必须指定任课教师！", vbCritical, "课程信息管理"
        cmbTeacher.SetFocus
        Exit Sub
    End If
    '检查是否修改了当前记录
    If objClass.RecordCount > 0 Then
        If Not isAdding And objClass.Fields("编号") = strNum _
            And objClass.Fields("名称") = strName _
            And objClass.Fields("教师") = strTeacher _
            And objClass.Fields("学分") = strScore Then
            '没有修改当前记录，不需执行保存操作，直接退出
            Exit Sub
        End If
    End If
    '在进一步保存添加的新记录或修改的当前记录之前，检查课程编号是否重复
    Dim objCopy As New Recordset
    Set objCopy = objClass.Clone
    If objClass.RecordCount > 0 Then
        objCopy.MoveFirst
        objCopy.Find "编号='" & strNum & "'"
        If (isAdding And Not objCopy.EOF) Or (Not isAdding And Not objCopy.EOF And _
            objCopy.AbsolutePosition <> objClass.AbsolutePosition) Then
            MsgBox "课程编号：" & strNum & "已被使用，请使用其他编号！", _
            vbCritical, "课程信息管理"
            txtNum.SetFocus
            txtNum.SelStart = 0
            txtNum.SelLength = Len(txtNum)
            Exit Sub        '课程编号重复，直接退出
        End If
    End If
    '课程编号不重复，执行下一步保存操作
    With objClass
        If isAdding Then
            '添加新记录
            .AddNew
        Else
            '保存被修改的当前记录
            If .Fields("编号") <> strNum Then
                If MsgBox("修改编号将影响《课程信息》表中的相关记录，是否继续？", _
                   vbYesNo + vbQuestion, "课程信息管理") = vbNo Then
                    '取消修改，还原当前记录
                    ShowData
                    Exit Sub
                End If
            End If
        End If
        '修改记录
        .Fields("编号") = strNum
        .Fields("名称") = strName
        .Fields("教师") = strTeacher
        .Fields("学分") = strScore
        '执行更新操作
        .Update
        MsgBox "数据保存成功！", vbInformation, "课程信息管理"
        isAdding = False
        '显示当前记录编号和记录总数
        txtNews = "记录：" & .AbsolutePosition & "/" & .RecordCount
    End With
End Sub

Private Sub Form_Unload(Cancel As Integer)
    objCn.Close                     '关闭数据联接
    Set objCn = Nothing             '释放数据库联接
    Set objTeacher = Nothing        '释放记录集对象
    Set objClass = Nothing          '释放记录集对象
End Sub

'限制编号输入
Private Sub txtNum_KeyPress(KeyAscii As Integer)
    If Not (Chr(KeyAscii) Like "[0-9]" Or KeyAscii = vbKeyBack) Then
        KeyAscii = 0    '输入不是数字或退格键，取消输入
    End If
End Sub

'限制学分输入
Private Sub txtScore_KeyPress(KeyAscii As Integer)
    If Not (Chr(KeyAscii) Like "[1-5]" Or KeyAscii = vbKeyBack) Then
        KeyAscii = 0    '输入不是数字或退格键，取消输入
    End If
End Sub

'显示objClass当前记录信息
Private Sub ShowData()
    With objClass
        '显示当前记录数据
        txtName = .Fields("名称")
        txtNum = .Fields("编号")
        txtScore = .Fields("学分")
        '根据教师编号显示教师名称
        objTeacher.MoveFirst
        objTeacher.Find "编号='" & .Fields("教师") & "'"
        cmbTeacher.ListIndex = objTeacher.AbsolutePosition
        '显示当前记录编号和记录总数
        txtNews = "记录：" & .AbsolutePosition & "/" & .RecordCount
    End With
End Sub