configure.ac

手写输入

# Process this file with autoconf to produce a configure script.
AC_PREREQ(2.59)

m4_define([scim_tomoe_major_version], [0])
m4_define([scim_tomoe_minor_version], [6])
m4_define([scim_tomoe_micro_version], [0])
m4_define([scim_tomoe_version],
          [scim_tomoe_major_version.scim_tomoe_minor_version.scim_tomoe_micro_version])

AC_INIT(scim-tomoe, [scim_tomoe_version], [e-mail])
AC_CONFIG_SRCDIR([configure.ac])

# Save this value here, since automake will set cflags and cxxflags later
cflags_set=${CFLAGS+set}
cppflags_set=${CPPFLAGS+set}

SCIM_TOMOE_MAJOR_VERSION=scim_tomoe_major_version
SCIM_TOMOE_MINOR_VERSION=scim_tomoe_minor_version
SCIM_TOMOE_MICRO_VERSION=scim_tomoe_micro_version

SCIM_TOMOE_VERSION=scim_tomoe_version

AC_SUBST(SCIM_TOMOE_MAJOR_VERSION)
AC_SUBST(SCIM_TOMOE_MINOR_VERSION)
AC_SUBST(SCIM_TOMOE_MICRO_VERSION)
AC_SUBST(SCIM_TOMOE_VERSION)

# Init automake stuff
AM_INIT_AUTOMAKE(1.9)
AM_CONFIG_HEADER(config.h)

# Init UUID of scim-tomoe
SCIM_TOMOE_UUID=b1bfe2b4-6930-41b0-8c07-d05bce8c92e2
AC_SUBST(SCIM_TOMOE_UUID)
AC_DEFINE_UNQUOTED(SCIM_TOMOE_UUID, "$SCIM_TOMOE_UUID", [The UUID of scim-tomoe])

# Init gettext
IT_PROG_INTLTOOL([0.35.0])

AM_GLIB_GNU_GETTEXT
dnl should run after AM_GLIB_GNU_GETTEXT
AC_CONFIG_COMMANDS([modify-itlocaledir], [
sed \
  -i'' \
  -e "s/^itlocaledir = /itlocaledir = \$(datadir)\/locale\n#itlocaledir = /" \
  po/Makefile
])
GETTEXT_PACKAGE=scim-tomoe
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [The gettext domain])

# Init libtool
AC_LIBTOOL_DLOPEN
AC_PROG_LIBTOOL
AC_SUBST(LIBTOOL_DEPS)

# Checks for programs.
AC_PROG_CXX
AC_PROG_CC
AC_LANG(C++)

AC_C_CONST
AC_TYPE_SIZE_T

# Checks for libraries.

SCIM_VERSION=1.2.0

PKG_CHECK_MODULES(SCIM, [scim >= $SCIM_VERSION])

# Check gtk2
PKG_CHECK_MODULES(GTK2, [gtk+-2.0 >= 2.4.0])

# Check tomoe-gtk
PKG_CHECK_MODULES(TOMOE_GTK, [tomoe-gtk >= 0.4.0])

# Check tomoe
PKG_CHECK_MODULES(TOMOE, [tomoe >= 0.4.0])

AC_SUBST(SCIM_VERSION)

# Checks for header files.
AC_HEADER_STDC
AC_FUNC_ALLOCA
AC_CHECK_HEADERS([argz.h fcntl.h float.h inttypes.h langinfo.h libintl.h limits.h locale.h malloc.h stddef.h stdint.h stdio_ext.h stdlib.h string.h strings.h sys/param.h unistd.h wchar.h])

# Checks for library functions.
AC_SUBST(ac_aux_dir)

# Checks for tomoe
PKG_CHECK_MODULES(TOMOE, tomoe)
AC_SUBST(TOMOE_CFLAGS)
AC_SUBST(TOMOE_LIBS)

# libtool option to control which symbols are exported
# right now, symbols starting with _ are not exported
LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
AC_SUBST(LIBTOOL_EXPORT_OPTIONS)

# Extra args.
AC_ARG_ENABLE(debug,
	      [  --enable-debug     Turn on debugging],
	      [case "${enableval}" in
	       yes) debug=yes ;;
	       no)  debug=no ;;
	       *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
       	      esac],[debug=no])

if test "x$debug" = "xyes"; then
  test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
  test "$cppflags_set" = set || CPPFLAGS="$CXXFLAGS -g"
  SCIM_DEBUG_FLAGS="-DENABLE_DEBUG=1"
else
  SCIM_DEBUG_FLAGS=""
fi
AC_SUBST(SCIM_DEBUG_FLAGS)

SCIM_DATADIR=`$PKG_CONFIG --variable=scimdatadir scim`
SCIM_ICONDIR=`$PKG_CONFIG --variable=icondir scim`
SCIM_MODULEDIR=`$PKG_CONFIG --variable=moduledir scim`
SCIM_LIBEXECDIR=`$PKG_CONFIG --variable=libdir scim`/scim-1.0

if test "x$SCIM_DATADIR" = "x"; then
  SCIM_DATADIR=${datadir}/scim
fi

if test "x$SCIM_ICONDIR" = "x"; then
  SCIM_ICONDIR=${datadir}/scim/icons
fi

if test "x$SCIM_MODULEDIR" = "x"; then
  SCIM_MODULEDIR=${libdir}/scim-1.0
fi

if test "x$SCIM_LIBEXECDIR" = "x/scim-1.0"; then
  SCIM_LIBEXECDIR=${libdir}/scim-1.0
fi

SCIM_TOMOE_DATADIR=${SCIM_DATADIR}/tomoe

AC_SUBST(SCIM_DATADIR)
AC_SUBST(SCIM_ICONDIR)
AC_SUBST(SCIM_MODULEDIR)
AC_SUBST(SCIM_LIBEXECDIR)
AC_SUBST(SCIM_TOMOE_DATADIR)

AC_CONFIG_FILES([
Makefile
po/Makefile.in
src/Makefile
data/Makefile
src/scim-tomoe
])

AC_OUTPUT