module1.vb

P2P 之 UDP穿透NAT的原理与实现（附源代码） 原创：shootingstars 参考：http://midcom-p2p.sourceforge.net/draft-ford-midcom

Imports System.Net
Imports System.Net.Sockets
Imports System.Text
Imports System.Threading


Module Module1

#Region "参数"

    '以下是客户端到服务器端的消息开头 
    Const LOGININ As String = "10" '请求登陆的消息|||消息形式:10+自己的用户名 
    Const LOGINOUT As String = "11" '请求登出的消息|||消息形式:11+自己的用户名 
    Const GETULIST As String = "12" '请求获得在线用户列表|||消息形式:12+自己的用户名 
    Const P2PCONN As String = "13" '请求P2P连接的消息|||消息形式:13+自己的用户名+对方的用户名 
    Const HOLDLINE As String = "14" '保持连接.|||消息开式:14+自己的用户名 

    '以下是服务器到客户端的消息开头 
    Const HVUSER As String = "20" '用户名已存在 
    Const GETUSER As String = "21" '在线用户列表|||消息格式:21+用户名+EP 
    Const MAKHOLD As String = "22" '打洞命令|||消息格式:22+IP 
    Const LOGINOK As String = "23" '登陆成功 
    Const SERVCLS As String = "24" '服务器关闭 
    Const MSGEND As String = "25" '消息结束 

    '以下是客户端到客户端的消息开头 
    Const HOLDOK As String = "30" '打洞成功 
    Const CHATMSG As String = "31" '聊天消息 
    Const CHTMSGEND As String = "32" '聊天消息发送成功 

    '以下是客户端的命名 
    Const EXITPRO As String = "EXIT" '退出命令 
    Const SHOWULIST As String = "SHOWUSER" '显示在线用户 
    Const HELP As String = "HELP" '显示帮助 
    Const SEND As String = "SEND" '发送消息 

#End Region

#Region "全局全量"

    Delegate Sub myMethodDelegate(ByRef myInData As Byte()) '登陆时用的事件 

    'Dim MaxTry As Integer = 5 
    Dim msgSendEnd As Boolean = False '消息是否发送成功,若发送成功,则会返回结束消息 
    Dim ThListen As New Thread(AddressOf listen) '监听的线程 
    Dim ClientSocket As New Socket(AddressFamily.InterNetwork, SocketType.Dgram, ProtocolType.Udp) '客户端套节字的定义 

    Dim username As String '当前用户名 
    Dim ServerEP As IPEndPoint '服务器的IPEP 
    Dim holdBytes As [Byte]() = Encoding.Unicode.GetBytes(HOLDLINE & username) '和服务器保持连接连接时用到的byte数组 

    Dim OLUserName() As String
    Dim OLUserEP() As IPEndPoint
    Dim getUrecCount As Integer
    Dim testHold As Boolean = False
    Dim testChat As Boolean = False

    Private receiveDone As ManualResetEvent '在登陆时用来阻塞线程,等待收到数据 
    Private sendDone As ManualResetEvent '用来阴塞发送消息的线程.等待收到回送的确认消息 
    Private getUDone As ManualResetEvent '用来阻塞请求好友名单的线程,等待接收好友名单 
    Private holdDone As ManualResetEvent '用来阻塞打洞时的线程 
    Private chatDone As ManualResetEvent '用来阻塞发送聊天消息时的线程 

    Dim timerDelegate As New TimerCallback(AddressOf holdonline) '为保持在线状态弄得 

#End Region

#Region "方法"

    '主函数,程序入口 
    Sub Main()
        Dim InputIP As String
        Dim InputOK As Boolean = False


        '判断输入的IP,并且保存服务器的IPEP 
        While InputOK <> True
            Console.Write("请输入服务器IP:")
            InputIP = Console.ReadLine()
            Try
                ServerEP = New IPEndPoint(IPAddress.Parse(InputIP), 11000)
                InputOK = True
            Catch
                Console.WriteLine("你输入的服务器IP不正确,请重新输入.")
                InputOK = False
            End Try
        End While

        Dim bool As Boolean = False

        '判断用户是否登陆成功 
        While bool <> True

            Dim LoginOK As Boolean = Login()
            If LoginOK = True Then
                bool = True
            Else
                Console.Write("是否重试:输入Y重试,输入任意值退出程序:")
                Dim tempYN As String = Console.ReadLine.ToUpper
                If tempYN = "Y" Then
                    bool = False
                Else
                    Exit Sub
                End If
            End If

        End While

        Console.WriteLine("用户名:" & username)
        holdBytes = Encoding.Unicode.GetBytes(HOLDLINE & username)
        '登陆成功后.用一个timer,每隔50秒向服务器发送消息,保持在线状态跟在主机注册的端口 
        Dim timer As New Timer(timerDelegate, Nothing, 10000, 50000)

        '请求在线名单 
        Console.WriteLine("正在获取在线名单,请稍后....")
        Dim getUbool As Boolean = False
        While getUbool <> True
            getUbool = getU()
            If getUbool = False Then
                Console.Write("是否重试:输入Y重试,输入任意值退出程序:")
                Dim tempYN As String = Console.ReadLine.ToUpper
                If tempYN = "Y" Then
                    bool = False
                Else
                    Exit Sub
                End If
            End If
        End While

        ThListen.Start()

        '用来处理客户端的一些命令 
        Dim SVInput As String
        While True
            Console.Write("Client>")
            SVInput = Console.ReadLine().ToUpper
            Select Case SVInput
                Case EXITPRO
                    exitApp()
                    ThListen.Abort()
                    ClientSocket.Close()
                    Exit Sub
                Case SHOWULIST
                    Console.WriteLine("*********************************")
                    showUserList()
                    Console.WriteLine("*********************************")
                Case HELP
                    Console.Write("*********************************" & Chr(10) & Chr(13) & "exit:输出当前程序" & Chr(10) & Chr(13) & "showuser:显示当前在线用户例表" & Chr(10) & Chr(13) & "send:发送消息.格式:send 用户名 消息" & Chr(10) & Chr(13) & "help:显示帮助" & Chr(10) & Chr(13) & "*********************************" & Chr(10) & Chr(13))
                Case Else
                    If SVInput.Substring(0, 4) = "SEND" Then
                        Dim split() As String = SVInput.Split(" ")
                        If split.Length = 3 Then
                            sendChatMsg(split(1), split(2))
                        Else
                            Console.WriteLine("*********************************" & Chr(10) & Chr(13) & "你输入的命令格式不正确.send命令格式为:send 用户名 你的消息" & Chr(10) & Chr(13) & "*********************************")
                        End If
                    Else
                        Console.WriteLine("*********************************" & Chr(10) & Chr(13) & "笨瓜,你输入的不是有效的命令." & Chr(10) & Chr(13) & "*********************************")
                    End If
            End Select
        End While

    End Sub

    '登陆函数 
    Private Function Login() As Boolean

        receiveDone = New ManualResetEvent(False)
        Dim userBytes As [Byte]()

        Dim userOK As Boolean = False

        Console.Write("请输入你的用户名:")

        '判断用户名是否符合格式 
        While (userOK <> True)
            username = Console.ReadLine.ToUpper
            userBytes = Encoding.Unicode.GetBytes(LOGININ & username)

            If userBytes.Length > 24 Or userBytes.Length < 10 Then
                Console.WriteLine("用户名不得小于6个字节,且不得大于20个字节.")
                Console.Write("请重新输入你的用户名:")
            Else
                userOK = True
            End If
        End While

        '向服务器发送客户消息 
        ClientSocket.SendTo(userBytes, ServerEP)

        Dim data As [Byte]() = New Byte(1024) {}

        Dim comStr As String = Encoding.Unicode.GetString(data, 0, 4)

        '异面的接收服务器回送的消息 
        Dim DGrecv As New myMethodDelegate(AddressOf recvLogin)
        DGrecv.BeginInvoke(data, Nothing, Nothing)

        '等待服务器回送消息的时长为10秒,否则为服务器超时 
        receiveDone.WaitOne(30000, True)

        Dim recvStr As String = Encoding.Unicode.GetString(data, 0, 4)

        If recvStr = comStr Then
            Console.WriteLine("服务器超时.登陆失败!!")
            Return False
        End If

        If Encoding.Unicode.GetString(data, 0, 4) = LOGINOK Then
            Console.WriteLine("登陆成功!!")
            Return True
        ElseIf Encoding.Unicode.GetString(data, 0, 4) = HVUSER Then
            Console.WriteLine("用户名重复.登陆失败!!")
            Return False
        Else
            Console.WriteLine("服务器未知错误,登陆失败!!")
            Return False
        End If

    End Function

    '登出函数 
    Private Sub exitApp()

        Dim loginOutStr As String = LOGINOUT & username
        Dim sendBytes As [Byte]() = Encoding.Unicode.GetBytes(loginOutStr)
        ClientSocket.SendTo(sendBytes, ServerEP)

    End Sub

    '请求好友列表的函数 
    Private Function getU() As Boolean

        getUDone = New ManualResetEvent(False)
        Dim getUbytes As Byte() = Encoding.Unicode.GetBytes(GETULIST)
        ClientSocket.SendTo(getUbytes, ServerEP)

        Dim data As [Byte]() = New Byte(4056) {}
        Dim comStr As String = Encoding.Unicode.GetString(data, 0, 4)

        Dim GUrecv As New myMethodDelegate(AddressOf recvGetU)
        GUrecv.BeginInvoke(data, Nothing, Nothing)

        getUDone.WaitOne(30000, True)

        Dim recvStr As String = Encoding.Unicode.GetString(data, 0, 4)

        If recvStr = comStr Then
            Console.WriteLine("服务器超时.或取好友名单失败!!")
            Return False
        End If

        If Encoding.Unicode.GetString(data, 0, 4) = GETUSER Then
            getUserList(data, getUrecCount)
            Console.WriteLine("获取在线名单成功!!")
            showUserList()
            Return True
        Else
            Console.WriteLine("服务器未知错误,获取在线名单失败!!")
            Return False
        End If

    End Function

    '登陆时用来异步的接收服务器发送的消息 
    Sub recvLogin(ByRef inData As Byte())

        ClientSocket.Receive(inData)
        receiveDone.Set()

    End Sub

    '请求好友名单时用来异步接收服务器发送的消息 
    Sub recvGetU(ByRef inData As Byte())

        getUrecCount = ClientSocket.Receive(inData)
        getUDone.Set()

    End Sub

    '处理收到的在线用户信息 
    Private Sub getUserList(ByVal userInfobytes() As Byte, ByVal reccount As Integer)

        Dim ustr As String = Encoding.Unicode.GetString(userInfobytes, 4, reccount - 4)