qtmail.pri

Qtopia下的邮件处理程序

VPATH+=$$PWD

phone:contains(PROJECTS,libraries/qtopiasmil):CONFIG+=enable_mms
PHONE_FORMS_MMS = mmseditaccountbase.ui
PHONE_FORMS = editaccountbasephone.ui searchviewbasephone.ui
enable_mms:PHONE_FORMS += $$PHONE_FORMS_MMS
PDA_FORMS   = editaccountbase.ui searchviewbase.ui writemailbase.ui

phone {
    FORMS += $$PHONE_FORMS
} else {
    FORMS += $$PDA_FORMS
}

HEADERS		+= emailclient.h \
		  emailhandler.h \
		  emaillistitem.h \
		  emailfolderlist.h \
		  popclient.h \
		  readmail.h \
		  smtpclient.h \
		  writemail.h \
		  viewatt.h \
		  addatt.h \
		  editaccount.h \
		  maillist.h \
		  addresslist.h \
		  searchview.h \
		  search.h \
		  maillistview.h \
		  email.h \
		  account.h \
		  imapclient.h \
		  folder.h \
		  folderlistview.h \
		  accountlist.h \
		  imapprotocol.h \
		  qtmailwindow.h \
		  common.h \
		  client.h

SOURCES		+= emailclient.cpp \
		  emailhandler.cpp \
		  emaillistitem.cpp \
		  emailfolderlist.cpp \
		  popclient.cpp \
		  readmail.cpp \
		  smtpclient.cpp \
		  writemail.cpp \
		  viewatt.cpp \
		  addatt.cpp \
		  editaccount.cpp \
		  maillist.cpp \
		  addresslist.cpp \
		  searchview.cpp \
		  search.cpp \
		  maillistview.cpp \
		  email.cpp \
		  account.cpp \
		  imapclient.cpp \
		  folder.cpp \
		  folderlistview.cpp \
		  accountlist.cpp \
		  imapprotocol.cpp \
		  qtmailwindow.cpp \
		  client.cpp
		  

PHONE_SOURCES   = smsclient.cpp \
		    audiosource.cpp \
		    smsdecoder.cpp \
		    accountsettings.cpp \
		    genericcomposer.cpp \
		    detailspage.cpp \
		    composer.cpp \
		    emailcomposer.cpp \
		    templatetext.cpp \
		    selectfolder.cpp \
		    rightsnotification.cpp

MMS_SOURCES += mmsclient.cpp \
		    mmscomms.cpp \
		    mmscomposer.cpp \
                    mmseditaccount.cpp \
		    drmattachmentlink.cpp
                    
enable_mms:PHONE_SOURCES += $$MMS_SOURCES

PHONE_HEADERS   = smsclient.h \
		    audiosource.h \
		    smsdecoder.h \
		    accountsettings.h \
		    addattdialogphone.h \
		    genericcomposer.h \
		    detailspage.h \
		    composer.h \
		    emailcomposer.h \
		    templatetext.h \
		    selectfolder.h \
		    rightsnotification.h

MMS_HEADERS = mmsclient.h \
		    mmscomms.h \
		    mmscomposer.h \
                    mmseditaccount.h \
		    drmattachmentlink.h

enable_mms:PHONE_HEADERS += $$MMS_HEADERS

#PHONE_SOURCES   += emscomposer.cpp
#PHONE_HEADERS   += emscomposer.h
    
!enable_singleexec {
    PHONE_HEADERS += ../addressbook/imagesource.h \
		../addressbook/imagesourcedialog.h
    PHONE_SOURCES +=	../addressbook/imagesource.cpp \
		../addressbook/imagesourcedialog.cpp
}
enable_singleexec:!contains(PROJECTS,applications/addressbook) {
    PHONE_HEADERS += ../addressbook/imagesource.h \
		../addressbook/imagesourcedialog.h
    PHONE_SOURCES +=	../addressbook/imagesource.cpp \
		../addressbook/imagesourcedialog.cpp
}

PDA_SOURCES = pdacomposer.cpp
PDA_HEADERS = addattdialogpda.h \
 	      pdacomposer.h

phone {
    SOURCES+=$$PHONE_SOURCES
    HEADERS+=$$PHONE_HEADERS
} else {
    SOURCES += $$PDA_SOURCES
    HEADERS += $$PDA_HEADERS
}

# To enable HTTP MMS comms:
MMSCOMMS_HEADERS = mmscomms_http.cpp
MMSCOMMS_SOURCES = mmscomms_http.h

enable_mms {
    SOURCES+=$$MMSCOMMS_HEADERS
    HEADERS+=$$MMSCOMMS_SOURCES

    DEFINES+=MMSCOMMS_HTTP
}

TRANSLATABLES +=    $$PHONE_HEADERS \
                    $$PHONE_SOURCES \
                    $$PDA_HEADERS \
                    $$PDA_SOURCES \
                    $$MMS_HEADERS \
                    $$MMS_SOURCES \
                    $$PHONE_FORMS \
                    $$PDA_FORMS \
                    $$PHONE_FORMS_MMS \
                    $$MMSCOMMS_HEADERS \
                    $$MMSCOMMS_SOURCES \
                    
qtmail_ssl {
    depends(3rdparty/libraries/openssl/ssl)
    DEFINES+=SMTPAUTH
    HEADERS += qtsslsocket.h \
               ssllibrary.h
    SOURCES += qtsslsocket.cpp \
               ssllibrary.cpp
}