qtmail.pro

Qtopia下的邮件处理程序

qtopia_project(app)
TARGET=qtmail
CONFIG+=qtopia_main

include(qtmail.pri)

HEADERS += qtmailgui.h
SOURCES += qtmailgui.cpp \
          main.cpp

depends(libraries/qtopiamail)
depends(libraries/qtopiapim)
enable_mms:depends(libraries/qtopiasmil)
else:DEFINES+=QTOPIA_NO_MMS
phone:depends(libraries/qtopiawap)

pics.files=$$QTOPIA_DEPOT_PATH/pics/qtmail/*
pics.path=/pics/qtmail
pics.hint=pics
desktop.files=$$QTOPIA_DEPOT_PATH/apps/Applications/qtmail.desktop
desktop.path=/apps/Applications
desktop.hint=desktop
emailservice.files=$$QTOPIA_DEPOT_PATH/services/Email/qtmail
emailservice.path=/services/Email
help.source=$$QTOPIA_DEPOT_PATH/help
help.files=qtmail*
help.hint=help
INSTALLS+=pics desktop emailservice help

phone {
    smsservice.files=$$QTOPIA_DEPOT_PATH/services/SMS/qtmail
    smsservice.path=/services/SMS
    messageservice.files=$$QTOPIA_DEPOT_PATH/services/Messages/qtmail
    messageservice.path=/services/Messages
    mmsservice.files=$$QTOPIA_DEPOT_PATH/services/Push/application/vnd.wap.mms-message/qtmail
    mmsservice.path=/services/Push/application/vnd.wap.mms-message
    xmlrightsservice.files=$$QTOPIA_DEPOT_PATH/services/Push/application/vnd.oma.drm.rights+xml/qtmail
    xmlrightsservice.path=/services/Push/application/vnd.oma.drm.rights+xml
    wbxmlrightsservice.files=$$QTOPIA_DEPOT_PATH/services/Push/application/vnd.oma.drm.rights+wbxml/qtmail
    wbxmlrightsservice.path=/services/Push/application/vnd.oma.drm.rights+wbxml
    INSTALLS+=messageservice smsservice mmsservice xmlrightsservice wbxmlrightsservice
}
setvalueservice.files=$$QTOPIA_DEPOT_PATH/services/SetValue/v-card/qtmail
setvalueservice.path=/services/SetValue/v-card/
INSTALLS+=setvalueservice

enable_gcc4_target {
    QMAKE_CXXFLAGS+=-fvisibility=hidden
}

pkg.name=qpe-mail
pkg.desc=Messaging application for Qtopia.
pkg.domain=window,docapi,msg,phonecomm,cardreader,camera,pictures,alarm,mediarecorder,pim,screensaver,net