area.cls

vb做的数据库 客户管理系统

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "Area"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False

Public AreaId As Long
Public AreaName As String
Public AreaType As Integer
Public UpperId As Long

Public Sub Init()  '初始化成员变量
  AreaId = 0
  AreaName = ""
  AreaType = 0
  UpperId = 0
End Sub

'删除指定的地域记录，TmpId表示要删除的记录编号
Public Sub Delete(TmpId As Long)
  SqlStmt = "DELETE FROM Area WHERE AreaId=" + Trim(Str(TmpId))
  SQLExt (SqlStmt)
End Sub

'读取指定的地域记录，TmpId表示要选取的记录编号
Public Sub GetInfo(TmpId As Long)
  Dim rs As New ADODB.Recordset
  AreaId = TmpId
  If TmpId = 0 Then
    AreaName = ""
    AreaType = 0
    UpperId = -1
    Exit Sub
  End If
  
  SqlStmt = "SELECT * FROM Area WHERE AreaId=" + Trim(Str(TmpId))
  Set rs = QueryExt(SqlStmt)
  If Not rs.EOF Then
    If IsNull(rs.Fields(1)) Then
      AreaName = ""
    Else
      AreaName = Trim(rs.Fields(1))
    End If
    
    If IsNull(rs.Fields(2)) Then
      AreaType = 0
    Else
      AreaType = rs.Fields(2)
    End If
    If IsNull(rs.Fields(3)) Then
      UpperId = 0
    Else
      UpperId = rs.Fields(3)
    End If
  Else
    Init
  End If
End Sub

'根据指定的记录编号读取地域名称，TmpId表示指定的记录编号
Public Function GetName(TmpId As Long) As String
  Dim rs As New ADODB.Recordset
  
  SqlStmt = "SELECT AreaName FROM Area WHERE AreaId=" + Trim(Str(TmpId))
  Set rs = QueryExt(SqlStmt)
  If Not rs.EOF Then
    GetName = Trim(rs.Fields(0))
  Else
    GetName = ""
  End If
End Function

'返回新增记录的编号，在添加新记录时调用此函数
Public Function GetNewId() As Long
  Dim TmpId As Long
  Dim rs As New ADODB.Recordset
  
  SqlStmt = "SELECT AreaId FROM Area ORDER BY AreaId"
  Set rs = QueryExt(SqlStmt)
  i = 1
  Do While Not rs.EOF
    TmpId = rs.Fields(0)
    If TmpId = i Then
      i = i + 1
    Else
      GetNewId = i
      Exit Function
    End If
    rs.MoveNext
  Loop
  GetNewId = i
End Function

'判断指定的地域是否包含下级地域，TmpUpperId表示指定的地域编号
Public Function HaveSon(ByVal TmpUpperId As Long) As Boolean
  Dim rs As New ADODB.Recordset
  SqlStmt = "SELECT AreaId FROM Area WHERE UpperId=" _
          + Trim(Str(TmpUpperId))
  Set rs = QueryExt(SqlStmt)
  If rs.EOF Then
    HaveSon = False
  Else
    HaveSon = True
  End If
End Function

'判断指定的地域是否已经在数据库中，TmpAreaName表示指定的地域名称
'TmpAreaUpper表示指定的上级地域编号

Public Function In_DB(ByVal TmpAreaName As String, _
                      ByVal TmpAreaUpper As Long) As Boolean
  Dim rs As New ADODB.Recordset
  
  SqlStmt = "SELECT AreaId FROM Area WHERE AreaName='" + Trim(TmpAreaName) _
             + "' and UpperId=" + Trim(Str(TmpAreaUpper))
  Set rs = QueryExt(SqlStmt)
  If Not rs.EOF Then
    In_DB = True
  Else
    In_DB = False
  End If
End Function

Public Function Insert() As Long  '插入新的地域记录
  AreaId = GetNewId
  
  SqlStmt = "INSERT INTO Area VALUES(" + Trim(Str(AreaId)) + ",'" _
            + Trim(AreaName) + "'," + Trim(Str(AreaType)) _
            + "," + Trim(Str(UpperId)) + ")"
  SQLExt (SqlStmt)
  Insert = AreaId
End Function

Public Sub Load_Area()  '读取所有的地域信息到数组中
  '初始化数组
  Erase Arr_AreaName
  Erase Arr_AreaId
  Erase Arr_AreaType
  Erase Arr_AreaUpper
  ReDim Arr_AreaName(0)
  ReDim Arr_AreaId(0)
  ReDim Arr_AreaType(0)
  ReDim Arr_AreaUpper(0)
  '读取数据到记录集
  Dim rs As New ADODB.Recordset
  SqlStmt = "SELECT * FROM Area ORDER BY AreaType"
  Set rs = QueryExt(SqlStmt)
  i = 0
  Do Until rs.EOF
    '地域编号
    ReDim Preserve Arr_AreaId(i + 1)
    Arr_AreaId(i) = rs.Fields(0)
    '地域名称
    ReDim Preserve Arr_AreaName(i + 1)
    Arr_AreaName(i) = Trim(rs.Fields(1))
    '地域类型
    ReDim Preserve Arr_AreaType(i + 1)
    Arr_AreaType(i) = rs.Fields(2)
    '上级地域
    ReDim Preserve Arr_AreaUpper(i + 1)
    Arr_AreaUpper(i) = rs.Fields(3)
    rs.MoveNext
    i = i + 1
  Loop
End Sub

'更新地域数据，TmpId为要修改的记录编号
Public Sub Update(ByVal TmpId As Long)
  SqlStmt = "UPDATE Area SET AreaName='" + Trim(AreaName) _
          + "' WHERE AreaId=" + Trim(Str(TmpId))
  SQLExt (SqlStmt)
End Sub