hdatabasecon.cls

即时通讯

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "HDatabaseCon"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
'**************************************
'*    模 块 名 称 :数据库联接类
'*    功 能 描 述 :完成数据库链路的连接测试，与数据库的相关操作
'*    程序员姓名  : 陈齐国
'*    最后修改人  : 陈齐国
'*    最后修改时间:2005/08/17
'**************************************
Option Explicit

Private m_connectionStr As String                       ' 数据库连接字符串
Private m_databaseUser  As String                       ' 数据库用户名
Private m_dUPassword    As String                       ' 用户密码
Public m_adoConnection As ADODB.Connection              '测试连接(为屏蔽提示信息)
'**************************************
'*    功 能 描 述 :类初始化函数
'*    输 入 参 数 :无
'*    输 出 能 数 :无
'**************************************
Private Sub Class_Initialize()
  Set m_adoConnection = New ADODB.Connection
End Sub
'**************************************
'*    功 能 描 述 :联接数据库函数
'*    输 入 参 数 :serverName     -  服务器名字符串
'*                 userName       -  用户名
'*                 password       -  用户密码
'*    输 出 能 数 :True           -  数据库连接成功
'*                 False          -  数据库连接失败
'**************************************
Public Function Connection(serverName As String, _
                               userName As String, _
                               password As String) As Boolean
    Connection = False
    
    m_databaseUser = userName
    m_dUPassword = password

    m_connectionStr = "Provider=SQLOLEDB.1;"
    
    m_connectionStr = m_connectionStr + "Persist Security Info=False;"
    
    m_connectionStr = m_connectionStr + "Data Source=" + Trim(serverName) + ";"
    
    m_connectionStr = m_connectionStr + " Initial Catalog=" + "SunDooErp" + ";"
    
    On Error GoTo Cwcl
    
    If m_adoConnection.State = 1 Then m_adoConnection.Close
    m_adoConnection.Open m_connectionStr, userName, password
    
    Connection = True
    
    Exit Function
    
Cwcl:
    Connection = False
    Exit Function
End Function
'**************************************
'*    功 能 描 述 :重新联接数据库函数
'*    输 入 参 数 :无
'*    输 出 能 数 :True           -  数据库连接成功
'*                 False          -  数据库连接失败
'**************************************
Public Function ReConnection() As Boolean
    ReConnection = False

    On Error GoTo Cwcl
    
    If m_adoConnection.State = 1 Then m_adoConnection.Close
    m_adoConnection.Open m_connectionStr, m_databaseUser, m_dUPassword
    
    ReConnection = True
    
    Exit Function
    
Cwcl:
    ReConnection = False
    Exit Function
End Function