maindao.cls

即时通讯

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "MainDAO"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
'**************************************
'*    模 块 名 称 :主模块中的数据据库操作
'*    功 能 描 述 :完成数据库操作
'*    程序员姓名  : 陈齐国
'*    最后修改人  : 陈齐国
'*    最后修改时间:2005/08/18
'**************************************
Option Explicit


'**************************************
'*    功 能 描 述 :登陆函数
'*    输 入 参 数 :无
'*    输 出 能 数 :True           -  数据库连接成功
'*                 False          -  数据库连接失败
'**************************************
Public Function Login(recSet As ADODB.Recordset, _
                      loginUser As String, _
                      password As String) As Boolean
    
    Dim cmdProc As ADODB.Command          ' 执行存储过程的命令
    
    Login = False
    Set cmdProc = New ADODB.Command
    Set cmdProc.ActiveConnection = MainForm.g_application.m_databaseCon.m_adoConnection
    
    ' 执行存储过程的命令的设置
    cmdProc.CommandText = "main_login"     ' 指定存储过程的名子
    cmdProc.CommandType = adCmdStoredProc
    cmdProc.Parameters.Refresh
    cmdProc.Parameters(1) = loginUser      ' 参数
    cmdProc.Parameters(2) = password       ' 参数
    
    On Error GoTo Cwcl
    
    ' 执行命令 把查询到的结果放在recSet中
    With recSet
        .CursorLocation = adUseClient
        .CursorType = adOpenDynamic
        .LockType = adLockOptimistic
        .Open cmdProc
    End With
    
    With recSet
        If Not .EOF Then
            Login = True
        Else
            Login = False
        End If
    End With
    
    Exit Function
    
Cwcl:
    Login = False
    Exit Function
End Function
'**************************************
'*    功 能 描 述 :取得一个新的ID编号
'*    输 入 参 数 :无
'*    输 出 能 数 :
'**************************************
Public Function NewId() As String
    
    Dim cmdProc As ADODB.Command          ' 执行存储过程的命令
    
    NewId = ""
    Set cmdProc = New ADODB.Command
    Set cmdProc.ActiveConnection = MainForm.g_application.m_databaseCon.m_adoConnection
    
    ' 执行存储过程的命令的设置
    cmdProc.CommandText = "main_newId"          ' 指定存储过程的名子
    cmdProc.CommandType = adCmdStoredProc
    cmdProc.Parameters.Refresh
    cmdProc.Parameters(1) = "000"             ' 参数
    
    ' 执行命令 把查询到的结果放在recSet中
    On Error GoTo Cwcl
    
    cmdProc.Execute
    NewId = cmdProc.Parameters(1)

    Exit Function
    
Cwcl:
    NewId = ""
End Function