bomsupplierrelationdao.cls

即时通讯

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "BomSupplierRelationDAO"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
'**************************************
'*    模 块 名 称 :BOM与供应商关系模块中的数据据库操作
'*    功 能 描 述 :完成数据库操作
'*    程序员姓名  : 陈齐国
'*    最后修改人  : 陈齐国
'*    最后修改时间:2005/09/21
'**************************************
Option Explicit

'**************************************
'*    功 能 描 述 :新增一条BOM的关联供应商记录
'*    输 入 参 数 :无
'*    输 出 能 数 :""           -  失败
'*                 "..."          -  成功
'**************************************
Public Function NewBomSupplierRelation(recSet As ADODB.Recordset, _
                        bomId As String, _
                        supplierId As String, _
                        quote As Double, _
                        firstSelect As Integer, _
                        creditbrow As Double, _
                        memo As String) As String
    
    Dim cmdProc As ADODB.Command          ' 执行存储过程的命令
    
    NewBomSupplierRelation = ""
    Set cmdProc = New ADODB.Command
    Set cmdProc.ActiveConnection = MainForm.g_application.m_databaseCon.m_adoConnection
    
    ' 执行存储过程的命令的设置
    cmdProc.CommandText = "bomSupplierRelation_new"          ' 指定存储过程的名子
    cmdProc.CommandType = adCmdStoredProc
    cmdProc.Parameters.Refresh
    cmdProc.Parameters(1) = bomId             ' 参数
    cmdProc.Parameters(2) = supplierId      ' 参数
    cmdProc.Parameters(3) = quote              ' 参数
    cmdProc.Parameters(4) = firstSelect      ' 参数
    cmdProc.Parameters(5) = "OOOOO"          ' 参数
    cmdProc.Parameters(6) = creditbrow          ' 参数
    cmdProc.Parameters(7) = memo          ' 参数
    
    ' 执行命令 把查询到的结果放在recSet中
    MainForm.g_application.m_databaseCon.m_adoConnection.BeginTrans    ' 开始事务
    
    On Error GoTo Cwcl
    
    cmdProc.Execute
    NewBomSupplierRelation = cmdProc.Parameters(5)

    MainForm.g_application.m_databaseCon.m_adoConnection.CommitTrans   ' 结束事务
    Exit Function
    
Cwcl:
    MainForm.g_application.m_databaseCon.m_adoConnection.RollbackTrans   ' 回滚事务
    NewBomSupplierRelation = ""
End Function

'**************************************
'*    功 能 描 述 :修改一条BOM的关联供应商记录
'*    输 入 参 数 :无
'*    输 出 能 数 :True           -  新增成功
'*                 False          -  新增失败
'**************************************
Public Function ModifyBomSupplierRelation(recSet As ADODB.Recordset, _
                        bomId As String, _
                        supplierId As String, _
                        quote As Double, _
                        firstSelect As Integer, _
                        bomSupplierId As String, _
                        creditbrow As Double, _
                        memo As String) As Boolean
    
    Dim cmdProc As ADODB.Command          ' 执行存储过程的命令
    
    ModifyBomSupplierRelation = True
    Set cmdProc = New ADODB.Command
    Set cmdProc.ActiveConnection = MainForm.g_application.m_databaseCon.m_adoConnection
    
    ' 执行存储过程的命令的设置
    cmdProc.CommandText = "bomSupplierRelation_modify"          ' 指定存储过程的名子
    cmdProc.CommandType = adCmdStoredProc
    cmdProc.Parameters.Refresh
    cmdProc.Parameters(1) = bomId             ' 参数
    cmdProc.Parameters(2) = supplierId      ' 参数
    cmdProc.Parameters(3) = quote              ' 参数
    cmdProc.Parameters(4) = firstSelect      ' 参数
    cmdProc.Parameters(5) = bomSupplierId          ' 参数
    cmdProc.Parameters(6) = creditbrow          ' 参数
    cmdProc.Parameters(7) = memo          ' 参数
    
    ' 执行命令 把查询到的结果放在recSet中
'    MainForm.g_application.m_databaseCon.m_adoConnection.BeginTrans    ' 开始事务
    
    On Error GoTo Cwcl
    
    cmdProc.Execute
    ModifyBomSupplierRelation = True

'    MainForm.g_application.m_databaseCon.m_adoConnection.CommitTrans   ' 结束事务
    Exit Function
    
Cwcl:
'    MainForm.g_application.m_databaseCon.m_adoConnection.RollbackTrans   ' 回滚事务
    ModifyBomSupplierRelation = False
End Function
'**************************************
'*    功 能 描 述 :删除一条BOM的关联供应商记录
'*    输 入 参 数 :无
'*    输 出 能 数 :True           -  成功
'*                 False          -  失败
'**************************************
Public Function DeleteBomSupplierRelation(recSet As ADODB.Recordset, _
                        bomSupplierId As String) As Boolean
    
    Dim cmdProc As ADODB.Command          ' 执行存储过程的命令
    
    DeleteBomSupplierRelation = True
    Set cmdProc = New ADODB.Command
    Set cmdProc.ActiveConnection = MainForm.g_application.m_databaseCon.m_adoConnection
    
    ' 执行存储过程的命令的设置
    cmdProc.CommandText = "bomSupplierRelation_delete"          ' 指定存储过程的名子
    cmdProc.CommandType = adCmdStoredProc
    cmdProc.Parameters.Refresh
    cmdProc.Parameters(1) = bomSupplierId          ' 参数
    
    ' 执行命令 把查询到的结果放在recSet中
    MainForm.g_application.m_databaseCon.m_adoConnection.BeginTrans    ' 开始事务
    
    On Error GoTo Cwcl
    
    cmdProc.Execute
    DeleteBomSupplierRelation = True

    MainForm.g_application.m_databaseCon.m_adoConnection.CommitTrans   ' 结束事务
    Exit Function
    
Cwcl:
    MainForm.g_application.m_databaseCon.m_adoConnection.RollbackTrans   ' 回滚事务
    DeleteBomSupplierRelation = False
End Function
'**************************************
'*    功 能 描 述 :找到一个物料BOM的所有供应商列表
'*    输 入 参 数 :无
'*    输 出 能 数 :True           -  成功
'*                 False          -  失败
'**************************************
Public Function FindBomSupplierByBomId(recSet As ADODB.Recordset, _
                             bomId As String) As Boolean
    Dim cmdProc As ADODB.Command          ' 执行存储过程的命令
    
    FindBomSupplierByBomId = False
    Set cmdProc = New ADODB.Command
    Set cmdProc.ActiveConnection = MainForm.g_application.m_databaseCon.m_adoConnection
    
    ' 执行存储过程的命令的设置
    cmdProc.CommandText = "bomSupplierRelation_findByBomId"    ' 指定存储过程的名子
    cmdProc.CommandType = adCmdStoredProc
    cmdProc.Parameters.Refresh
    cmdProc.Parameters(1) = bomId            ' 参数
    
    On Error GoTo Cwcl
    
    ' 执行命令 把查询到的结果放在recSet中
    With recSet
        .CursorLocation = adUseClient
        .CursorType = adOpenDynamic
        .LockType = adLockOptimistic
        .Open cmdProc
    End With
    
    With recSet
        If Not .EOF Then
            FindBomSupplierByBomId = True
        Else
            FindBomSupplierByBomId = False
        End If
    End With
    
    Exit Function
    
Cwcl:
    FindBomSupplierByBomId = False
    Exit Function
End Function
'**************************************
'*    功 能 描 述 :找到一个供应商供应的物料
'*    输 入 参 数 :supplierId   -  供应商的ID编号
'*                 opType      0- 原料
'*                             1- 零件
'*                             2- 产品
'*                             3- 所有物料
'*    输 出 能 数 :True           -  成功
'*                 False          -  失败
'**************************************
Public Function FindMaterialBySupplier(recSet As ADODB.Recordset, _
                             supplierId As String, _
                             opType As String) As Boolean
    Dim cmdProc As ADODB.Command          ' 执行存储过程的命令
    
    FindMaterialBySupplier = False
    Set cmdProc = New ADODB.Command
    Set cmdProc.ActiveConnection = MainForm.g_application.m_databaseCon.m_adoConnection
    
    ' 执行存储过程的命令的设置
    cmdProc.CommandText = "bomSupplierRelation_findMaterial_bySupplier"    ' 指定存储过程的名子
    cmdProc.CommandType = adCmdStoredProc
    cmdProc.Parameters.Refresh
    cmdProc.Parameters(1) = supplierId            ' 参数
    cmdProc.Parameters(2) = opType                ' 参数
    
    On Error GoTo Cwcl
    
    ' 执行命令 把查询到的结果放在recSet中
    With recSet
        .CursorLocation = adUseClient
        .CursorType = adOpenDynamic
        .LockType = adLockOptimistic
        .Open cmdProc
    End With
    
    With recSet
        If Not .EOF Then
            FindMaterialBySupplier = True
        Else
            FindMaterialBySupplier = False
        End If
    End With
    
    Exit Function
    
Cwcl:
    FindMaterialBySupplier = False
    Exit Function
End Function
'**************************************