petls.pas

Delphi写的PE查看器

{******************************************************************************}
{Copyright(C) 2007,Pefine Security Lab                                         }
{All rights reserved.                                                          }
{                                                                              }
{Abstract:View Win32 PE file information.                                      }
{                                                                              }
{Version:1.01                                                                  }
{Author:WindRand                                                               }
{Date:2007-01-20                                                               }
{******************************************************************************}
unit PeTls;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, JwaWinNT;

type
  TPeTlsFrm = class(TForm)
    GroupBox1: TGroupBox;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    Label5: TLabel;
    Label6: TLabel;
    DSEdit: TEdit;
    DEEdit: TEdit;
    IVEdit: TEdit;
    CTEdit: TEdit;
    SZEdit: TEdit;
    CharEdit: TEdit;
    Panel1: TPanel;
    Button1: TButton;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    procedure FreeHandle(hFile,mFile:Thandle);
    function GetSectionHeader(tRVA:DWORD;ImageNTHeaders:PImageNtHeaders):PImageSectionHeader;
  public
    { Public declarations }
  end;

var
  PeTlsFrm: TPeTlsFrm;

implementation

uses Main;

{$R *.dfm}

procedure TPeTlsFrm.FormShow(Sender: TObject);
begin
  With PeTlsFrm do
    begin
      Left:=(Screen.Width div 2)-(Width div 2);
      Top:=(Screen.Height div 2)-(Height div 2);
    end;
end;

procedure TPeTlsFrm.FreeHandle(hFile,mFile:Thandle);
begin
  CloseHandle(hFile);
  CloseHandle(mFile);
end;

function TPeTlsFrm.GetSectionHeader(tRVA:DWORD;ImageNTHeaders:PImageNtHeaders):PImageSectionHeader;
var
 ImageSection:PImageSectionHeader;
 i:integer;
begin
  ImageSection:=pImageSectionHeader(longword(ImageNTHeaders)+sizeof(TImageNtHeaders));
  for i:=0 to ImageNTHeaders.FileHeader.NumberOfSections-1 do
    begin
      if (tRVA>=LongWord(ImageSection.VirtualAddress)) and
         (tRVA<LongWord(ImageSection.VirtualAddress + ImageSection.Misc.VirtualSize)) then
        begin
          Result:=ImageSection;
          Exit;
        end;
      Inc(ImageSection);
    end;
  Result:=nil;
end;

procedure TPeTlsFrm.FormCreate(Sender: TObject);
var
  ImageDosHeader:PIMAGEDOSHEADER;
  ImageNTHeaders:PIMAGENTHEADERS;
  ImageSectionHeader:PIMAGESECTIONHEADER;
  ImageTLS:PImageTlsDirectory32;
  hFile,mFile:THandle;
  hView:Pointer;
  vBase,vTls:LongWord;
  tRVA:Integer;
begin
  hFile:=CreateFile(PChar(MainFrm.PublicFileNameStr),GENERIC_READ,FILE_SHARE_READ,nil,OPEN_EXISTING,FILE_ATTRIBUTE_NORMAL,0);
  if hFile=INVALID_HANDLE_VALUE then
    begin
      MessageBox(Handle,'Open file error！','Information',MB_OK+MB_ICONERROR);
      CloseHandle(hFile);
      Exit;
    end;
  mFile:=CreateFileMapping(hFile,nil,PAGE_READONLY,0,0,nil);
  if mFile=0 then
    begin
      MessageBox(Handle,'Cannot open the file for memory mapping！','Information',MB_OK+MB_ICONERROR);
      CloseHandle(hFile);
      Exit;
    end;
  hView:=MapViewOfFile(mFile,FILE_MAP_READ,0,0,0);
  if hView=nil then
    begin
      MessageBox(Handle,'Cannot map the file into memory！','Information',MB_OK+MB_ICONERROR);
      FreeHandle(hFile,mFile);
      Exit;
    end;
  ImageDosHeader:=PImageDosHeader(hView);
  if ImageDosHeader.e_magic<>IMAGE_DOS_SIGNATURE then
    begin
      MessageBox(Handle,'This file is not a valid PE！','Information',MB_OK+MB_ICONERROR);
      FreeHandle(hFile,mFile);
      Exit;
    end;
  vBase:=LongWord(ImageDosHeader);
  ImageNTHeaders:=PIMAGENTHEADERS(vBase+LongWord(ImageDosHeader.e_lfanew));
  if ImageNTHeaders.Signature<>IMAGE_NT_SIGNATURE then
    begin
      MessageBox(Handle,'This file is not a valid PE。','Information',MB_OK+MB_ICONINFORMATION);
      FreeHandle(hFile,mFile);
      Exit;
    end;
  vTls:=ImageNTHeaders.OptionalHeader.DataDirectory[IMAGE_DIRECTORY_ENTRY_TLS].VirtualAddress;
  if vTls=0 then
    begin
      FreeHandle(hFile,mFile);
      Exit;
    end;
  ImageSectionHeader:=GetSectionHeader(vTls,ImageNTHeaders);
  if ImageSectionHeader=nil then
    begin
      FreeHandle(hFile,mFile);
      Exit;
    end;
  tRVA:=Integer(ImageSectionHeader.VirtualAddress-ImageSectionHeader.PointerToRawData);
  ImageTls:=PImageTlsDirectory32(PChar(vTls)-tRVA+vBase);

  DSEdit.Text:=IntToHex(ImageTls.StartAddressOfRawData,8);
  DEEdit.Text:=IntToHex(ImageTls.EndAddressOfRawData,8);
  IVEdit.Text:=IntToHex(ImageTls.AddressOfIndex,8);
  CTEdit.Text:=IntToHex(ImageTls.AddressOfCallBacks,8);
  SZEdit.Text:=IntToHex(ImageTls.SizeOfZeroFill,8);
  CharEdit.Text:=IntToHex(ImageTls.Characteristics,8);

  UnmapViewOfFile(hView);
  FreeHandle(hFile,mFile);
end;

procedure TPeTlsFrm.Button1Click(Sender: TObject);
begin
  Close;
end;

end.