arale.bat

用java写的网络爬虫

@echo off
rem ---------------------------------------------------------------------------
rem arale.bat - Start script for Arale web spider
rem
rem Required Environment Variables:
rem
rem   JAVA_HOME     Must point at your Java Development Kit installation.
rem   ARALE_HOME     Must point at your Arale installation directory.
rem   ARALE_OPTS    (Optional) Java runtime options.
rem
rem ---------------------------------------------------------------------------


rem ----- Save Environment Variables That May Change --------------------------

set _CLASSPATH=%CLASSPATH%

rem ----- Verify and Set Required Environment Variables -----------------------

if not "%JAVA_HOME%" == "" goto gotJavaHome
echo You must set JAVA_HOME to point at your Java Development Kit installation
goto cleanup
:gotJavaHome

if not "%ARALE_HOME%" == "" goto gotAraleHome
echo ARALE_HOME is not set. Setting ARALE_HOME to current directory
set ARALE_HOME=.
:gotAraleHome

rem ----- Set Up The Runtime Classpath ----------------------------------------

set CLASSPATH=%JAVA_HOME%\jre\lib\rt.jar;%JAVA_HOME%\lib\tools.jar

echo Using CLASSPATH: %CLASSPATH%
echo Using JAVA_HOME: %JAVA_HOME%
echo Using ARALE_HOME: %ARALE_HOME%

%JAVA_HOME%\bin\java -jar %ARALE_OPTS% %ARALE_HOME%/arale.jar %1 %2 %3 %4 %5 %6 %7 %8 %9

rem ----- Restore Environment Variables ---------------------------------------

:cleanup
set CLASSPATH=%_CLASSPATH%
set _CLASSPATH=