form06.frm

VB＋MO的GIS开发代码

VERSION 5.00
Object = "{9BD6A640-CE75-11D1-AF04-204C4F4F5020}#2.0#0"; "Mo20.ocx"
Begin VB.Form Form06 
   Caption         =   "根据面积分区显示"
   ClientHeight    =   5445
   ClientLeft      =   60
   ClientTop       =   345
   ClientWidth     =   6765
   LinkTopic       =   "Form1"
   ScaleHeight     =   5445
   ScaleWidth      =   6765
   StartUpPosition =   2  'CenterScreen
   Begin VB.CommandButton Command1 
      Caption         =   "显示"
      Height          =   495
      Left            =   2640
      TabIndex        =   1
      Top             =   4800
      Width           =   1335
   End
   Begin MapObjects2.Map Map1 
      Height          =   4575
      Left            =   0
      TabIndex        =   0
      Top             =   0
      Width           =   6735
      _Version        =   131072
      _ExtentX        =   11880
      _ExtentY        =   8070
      _StockProps     =   225
      BackColor       =   16777215
      BorderStyle     =   1
      Contents        =   "Form06.frx":0000
   End
End
Attribute VB_Name = "Form06"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
'Xuewei,2003/6/7
'ClassBreaksRenderer示例；
'

Option Explicit

Private Sub Command1_Click()
  Dim i As Integer
  Dim oMapLayer As MapObjects2.MapLayer
  Dim oStats As MapObjects2.Statistics
  Dim oClassRend As New MapObjects2.ClassBreaksRenderer
  Dim fBreakVal As Double

  Set oMapLayer = Map1.Layers("States")
  Set oMapLayer.Renderer = oClassRend
  With oClassRend
    .SymbolType = moFillSymbol
    .Field = "AREA"
    Set oStats = oMapLayer.Records.CalculateStatistics("AREA")
    
    fBreakVal = oStats.Mean - (oStats.StdDev * 3)
    MsgBox oStats.Mean & ",stddev=" & oStats.StdDev & _
    ",min=" & oStats.Min & ",max=" & oStats.Max & ",break=" & fBreakVal
    For i = 0 To 6
      If fBreakVal >= oStats.Min And fBreakVal <= oStats.Max Then
        .BreakCount = .BreakCount + 1
        .Break(.BreakCount - 1) = fBreakVal
      End If
      fBreakVal = fBreakVal + oStats.StdDev
    Next
    .RampColors moPaleYellow, moRed
  End With
  Map1.Refresh
End Sub

Private Sub Form_Load()
  DrawLayer   '添加一个States图层；
End Sub

Private Sub DrawLayer()
  Dim dc As New DataConnection
  Dim layer As MapLayer
  dc.Database = App.Path + "\..\" + "Mexico"
  If Not dc.Connect Then
    MsgBox "在指定的文件夹下没找到图层数据文件！"
    End
  End If
    
  Set layer = New MapLayer
  Set layer.GeoDataset = dc.FindGeoDataset("States")
  layer.Symbol.Color = moPaleYellow
  layer.Symbol.Size = 1
  layer.Symbol.OutlineColor = moBrown
  Map1.Layers.Add layer
  
  Map1.Refresh
End Sub