configure.in

网络爬虫程序

		if eval "test x$PCRE_CONFIG = xyes"; then
			pcre_cflags=`pcre-config --cflags`
			pcre_libs=`pcre-config --libs`
			x_cflags="$x_cflags $pcre_cflags"
			AC_DEFINE_UNQUOTED(HAVE_REGEX, 1, [REs support])
			AC_DEFINE_UNQUOTED(HAVE_PCRE_REGEX, 1, [PCRE REs])
			x_libs="$x_libs $pcre_libs"
			want_regex_impl=no
		else
			AC_CHECK_LIB(pcre, pcre_compile, [
				AC_DEFINE_UNQUOTED(HAVE_REGEX, 1, [REs support])
				AC_DEFINE_UNQUOTED(HAVE_PCRE_REGEX, 1,
					[PCRE REs])
				x_libs="$x_libs -lpcre";want_regex_impl="no"])
		fi
	fi
fi	

dnl ********************
dnl test for GNU regex
dnl ********************

if eval "test x$want_regex_impl = xyes"; then
	if eval "test x$WITH_REGEX = xauto -o x$WITH_REGEX = xgnu"; then
		AC_MSG_CHECKING([for GNU regular expressions])
		ac_gnu_re="no"
		AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
			re_compile_pattern();
		]])],[ac_gnu_re="yes"],[])
		AC_MSG_RESULT($ac_gnu_re)
		if eval "test x$ac_gnu_re = xyes"; then
			AC_DEFINE_UNQUOTED(HAVE_REGEX, 1, [REs support])
			AC_DEFINE_UNQUOTED(HAVE_GNU_REGEX, 1, [GNU REs])
			want_regex_impl=no
		fi
	fi
fi

dnl ********************
dnl test for Bell V8 regex
dnl ********************

if eval "test x$want_regex_impl = xyes"; then
	if eval "test x$WITH_REGEX = xauto -o x$WITH_REGEX = xv8"; then
		AC_MSG_CHECKING([for Bell V8 regcomp()])
		ac_v8regcomp="no" 
		AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <regexp.h>]], [[
			regexp *pr;
			pr = regcomp("");
		]])],[ac_v8regcomp="yes"],[])
		AC_MSG_RESULT($ac_v8regcomp)
		if eval "test x$ac_v8regcomp = xyes"; then
			AC_DEFINE_UNQUOTED(HAVE_REGEX, 1, [REs support])
			AC_DEFINE_UNQUOTED(HAVE_V8_REGEX, 1, [SYSV 8 REs])
			AC_CHECK_FUNC(regsub, 
				AC_DEFINE_UNQUOTED(HAVE_V8_REGSUB, 1,
					[SYSV 8 RE exports regsub]))
			want_regex_impl=no
		fi
	fi
fi

dnl ********************
dnl test for BSD regex
dnl ********************

if eval "test x$want_regex_impl = xyes"; then
	if eval "test x$WITH_REGEX = xauto -o x$WITH_REGEX = xbsd"; then
		AC_MSG_CHECKING([for BSD regular expressions])
		ac_bsd_re="no"
		AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
			re_comp(".*");
			re_exec(".*");
		]])],[ac_bsd_re="yes"],[])
		AC_MSG_RESULT($ac_bsd_re)
		if eval "test x$ac_bsd_re = xyes"; then
			AC_DEFINE_UNQUOTED(HAVE_REGEX, 1, [REs support])
			AC_DEFINE_UNQUOTED(HAVE_BSD_REGEX, 1, [BSD REs])
			want_regex_impl=no
		fi
	fi
fi

dnl **********************
dnl check for zlib library
dnl **********************
_cppflags=${CPPFLAGS}
_ldflags=${LDFLAGS}

AC_ARG_WITH(zlib-includes,
[  --with-zlib-includes=DIR   where you have Zlib includes],[
	if test "$withval" != "no" -a "$withval" != "yes"; then
		CPPFLAGS="${CPPFLAGS} -I$withval"
	fi
])

AC_ARG_WITH(zlib-libraries,
[  --with-zlib-libraries=DIR  where you have Zlib libraries],[
	if test "$withval" != "no" -a "$withval" != "yes"; then
		LDFLAGS="${LDFLAGS} -L$withval"
	fi
])

AC_CHECK_HEADERS(zlib.h,
	AC_CHECK_LIB(z, gzopen,[
		AC_DEFINE_UNQUOTED(HAVE_ZLIB, 1, [have libz])
		x_libs="$x_libs -lz"],
		CPPFLAGS=${_cppflags}
		LDFLAGS=${_ldflags}),
	CPPFLAGS=${_cppflags}
	LDFLAGS=${_ldflags})

dnl **************************
dnl check for Berkeley DB 1.8x
dnl **************************
have_db_h="no"
have_db185_h="no"
AC_CHECK_HEADER(db1/db.h,
[
  AC_DEFINE_UNQUOTED(HAVE_DB1_H, 1, [have db1/db.h])
  have_db_h="yes"
],[	
  AC_MSG_CHECKING([for txn_begin in db.h])
  AC_EGREP_HEADER(txn_begin, db.h,
  [
    have_DB_VERSION_STRING="yes"
    AC_MSG_RESULT($have_DB_VERSION_STRING)
    AC_CHECK_HEADER(db_185.h, 
      [
	AC_DEFINE_UNQUOTED(HAVE_DB185_H, 1, [have db185.h])
	have_db185_h="yes"
      ],[
	AC_CHECK_HEADER(db4/db_185.h,
  	  [
	    AC_DEFINE_UNQUOTED(HAVE_DB4_DB185_H, 1, [have db4/db185.h])
	    have_db185_h="yes"
	  ],[
	    AC_CHECK_HEADER(db3/db_185.h,
	    [
	      AC_DEFINE_UNQUOTED(HAVE_DB3_DB185_H, 1, [have db3/db185.h])
	      have_db185_h="yes"
	    ],[
	      AC_CHECK_HEADER(db2/db_185.h,
	      [
	        AC_DEFINE_UNQUOTED(HAVE_DB2_DB185_H, 1, [have db2/db185.h])
	        have_db185_h="yes"
	      ])
	    ])
          ])
        ])
      ],[
	have_db_h="yes";
	have_DB_VERSION_STRING="no";
	AC_MSG_RESULT($have_DB_VERSION_STRING)]
     )]
)

if test $have_db185_h = "yes"; then
	found_db_lib="no";
	AC_DEFINE_UNQUOTED(DB_COMPATIBILITY_API, 1,
		[Berkeley DB 1.8x comatibility])
	AC_CHECK_FUNC(__db185_open, [
		AC_DEFINE_UNQUOTED(HAVE_BDB_18x, 1, [Berkeley DB 1.8x])
		found_db_lib="yes"])
	if test $found_db_lib = "no"; then
		AC_CHECK_LIB(db-4.4, __db185_open, [
			AC_DEFINE_UNQUOTED(HAVE_BDB_18x, 1, [Berkeley DB 1.8x])
			x_libs="$x_libs -ldb-4.4"
			found_db_lib="yes"])
	fi
	if test $found_db_lib = "no"; then
		AC_CHECK_LIB(db-4.3, __db185_open, [
			AC_DEFINE_UNQUOTED(HAVE_BDB_18x, 1, [Berkeley DB 1.8x])
			x_libs="$x_libs -ldb-4.3"
			found_db_lib="yes"])
	fi
	if test $found_db_lib = "no"; then
		AC_CHECK_LIB(db-4.1, __db185_open, [
			AC_DEFINE_UNQUOTED(HAVE_BDB_18x, 1, [Berkeley DB 1.8x])
			x_libs="$x_libs -ldb-4.1"
			found_db_lib="yes"])
	fi
	if test $found_db_lib = "no"; then
		AC_CHECK_LIB(db-4.0, __db185_open, [
			AC_DEFINE_UNQUOTED(HAVE_BDB_18x, 1, [Berkeley DB 1.8x])
			x_libs="$x_libs -ldb-4.0"
			found_db_lib="yes"])
	fi
	if test $found_db_lib = "no"; then
		AC_CHECK_LIB(db-3.1, __db185_open, [
			AC_DEFINE_UNQUOTED(HAVE_BDB_18x, 1, [Berkeley DB 1.8x])
			x_libs="$x_libs -ldb-3.1"
			found_db_lib="yes"])
	fi
	if test $found_db_lib = "no"; then
		AC_CHECK_LIB(db-3.0, __db185_open, [
			AC_DEFINE_UNQUOTED(HAVE_BDB_18x, 1, [Berkeley DB 1.8x])
			x_libs="$x_libs -ldb-3.0"
			found_db_lib="yes"])
	fi
	if test $found_db_lib = "no"; then
		AC_CHECK_LIB(db2, dbopen, [
			AC_DEFINE_UNQUOTED(HAVE_BDB_18x, 1, [Berkeley DB 1.8x])
			x_libs="$x_libs -ldb2"
			found_db_lib="yes"])
	fi
	if test $found_db_lib = "no"; then
		AC_CHECK_LIB(db, __db185_open,
			AC_CHECK_LIB(db, txn_open, , [
				AC_DEFINE_UNQUOTED(HAVE_BDB_18x, 1,
					[Berkeley DB 1.8x])
				x_libs="$x_libs -ldb"
				found_db_lib="yes"])
		)
	fi
fi

dnl *******************************
dnl IPv6 tests
dnl *******************************

AC_ARG_ENABLE(ipv6,
	[  --disable-ipv6             do not compile with IPv6 support],
	WITH_IPV6=$enableval, WITH_IPV6="yes")

if test "$WITH_IPV6" = yes; then
	have_ipv6_func="yes"
	AC_CHECK_FUNCS(inet_pton,,have_ipv6_func="no")
	AC_CHECK_FUNCS(inet_ntop,,have_ipv6_func="no")
	AC_CHECK_FUNCS(getaddrinfo,,have_ipv6_func="no")
	AC_CHECK_FUNCS(freeaddrinfo,,have_ipv6_func="no")
	AC_CHECK_FUNCS(gai_strerror,,have_ipv6_func="no")

	if test $have_ipv6_func = "no"; then
		if test -d /usr/inet6/include; then
			CPPFLAGS="$CPPFLAGS -I/usr/inet6/include"
		fi
		if test -d /usr/inet6/lib; then
			LDFLAGS="$LDFLAGS -I/usr/inet6/lib"
		fi
		AC_CHECK_LIB(inet6, getaddrinfo,
			have_ipv6_func="yes"; IPV6_LIBS="-linet6")
	fi

	AC_MSG_CHECKING([for IPv6 support])
	have_ipv6_support="no"
	if test $have_ipv6_func = "yes"; then
		AC_LINK_IFELSE([AC_LANG_PROGRAM([[ #include <sys/types.h>
#include <sys/socket.h>
#include <netinet/in.h>
		]], [[
				struct sockaddr_in6 sa6;
				struct in6_addr a6;
				sa6.sin6_addr.s6_addr;
				sa6.sin6_family = AF_INET6;
				return sizeof(a6);
		]])],[have_ipv6_support="yes"],[have_ipv6_func="no"])
	fi
	AC_MSG_RESULT($have_ipv6_support)

	if test $have_ipv6_func = "yes"; then
		AC_DEFINE_UNQUOTED(HAVE_INET6, 1, [IPv6 support])
		x_libs="$x_libs $IPV6_LIBS"
	fi
fi

AC_MSG_CHECKING([for struct sockaddr_storage])
have_sockaddr_storage="no"
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
#include <sys/socket.h>
	]], [[struct sockaddr_storage ss; return sizeof(ss);]])],[
	AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_STORAGE, 1,
		[have declared struct sockaddr_storage])
	have_sockaddr_storage="yes"],[])
AC_MSG_RESULT($have_sockaddr_storage)

dnl *******************************
dnl misc portability checkings
dnl *******************************

AC_CHECK_FUNCS(gettimeofday)

AC_MSG_CHECKING([for tm_gmtoff inside struct tm])
ac_tm_gmtoff="no"
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm mtm; mtm.tm_gmtoff; return 0;]])],[
	AC_DEFINE_UNQUOTED(HAVE_GMTOFF, 1, [have tm_gmtoff inside struct tm])
	ac_tm_gmtoff="yes"],[])
AC_MSG_RESULT($ac_tm_gmtoff)

AC_FUNC_FNMATCH
AC_CHECK_FUNCS(setenv usleep mkstemp vsnprintf)
AC_CHECK_FUNCS(fstatvfs, , [AC_CHECK_FUNCS(fstatfs)])
AC_CHECK_FUNC(lstat, , x_cflags="$x_cflags -Dlstat=stat")
AC_CHECK_FUNC(flock, ac_flock="yes", ac_flock="no")

if eval "test x$ac_flock = xyes"; then
	AC_DEFINE_UNQUOTED(HAVE_FLOCK, 1, [have flock() in libc])
else
	AC_MSG_CHECKING([for fcntl file locking])
	ac_fcntl_lock="no"
	AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <unistd.h>
#include <fcntl.h>]], [[
	fcntl(0,F_SETLK,F_WRLCK);
	fcntl(0,F_SETLK,F_UNLCK);
]])],[ac_fcntl_lock="yes"],[])
	AC_MSG_RESULT($ac_fcntl_lock)
	if eval "test x$ac_fcntl_lock = xyes"; then
		AC_DEFINE_UNQUOTED(HAVE_FCNTL_LOCK, 1, [fcntl() file locking])
	fi
fi

AC_MSG_CHECKING([for tzset])
ac_tzset="no" 
AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[
	tzset();
]])],[ac_tzset="yes"],[])
AC_MSG_RESULT($ac_tzset)
if eval "test x$ac_tzset = xyes"; then
	AC_DEFINE_UNQUOTED(HAVE_TZSET, 1, [have timezon function tzset()])
fi

_saved_LIBS="$LIBS"
LIBS="$EXTRA_LIBS"
AC_MSG_CHECKING([h_errno accesibility])
ac_h_errno="no" 
AC_LINK_IFELSE([AC_LANG_PROGRAM([[
#include <sys/types.h>
#include <netdb.h>
]], [[
	h_errno = 0;
]])],[ac_h_errno="yes"],[])
if eval "test x$ac_h_errno = xyes"; then
	AC_MSG_RESULT($ac_h_errno)
else
	ac_h_errno="no";
	AC_LINK_IFELSE([AC_LANG_PROGRAM([[
#define _XOPEN_SOURCE_EXTENDED
#define _INCLUDE_XOPEN_SOURCE_EXTENDED
#include <sys/types.h>
#include <netdb.h>
	]], [[
		h_errno = 0;
	]])],[ac_h_errno="need to define XOPEN_SOURCE_EXTENDED"],[])
	if eval "test x$ac_h_errno = xyes"; then
		AC_MSG_RESULT($ac_h_errno)
		x_cflags="$x_cflags -D_XOPEN_SOURCE_EXTENDED -D_INCLUDE_XOPEN_SOURCE_EXTENDED"
	else

		AC_LINK_IFELSE([AC_LANG_PROGRAM([[
			extern int h_errno;
		]], [[
			h_errno = 0;
		]])],[ac_h_errno="yes"],[])
		if eval "test x$ac_h_errno = xyes"; then
			AC_MSG_RESULT([need to declare h_errno])
			AC_DEFINE_UNQUOTED(NEED_DECLARE_H_ERRNO, 1,
				[libc doesn't export h_errno variable])
		else
			AC_MSG_RESULT([imposible to access h_errno - pavuk will probably not build])
		fi
	fi
fi
LIBS="$_saved_LIBS"

# Can we assume varargs are passed in order on the stack and ints == ptrs?
AC_RUN_IFELSE([AC_LANG_SOURCE([
#include <stdio.h>
int main(void) {
printf("checking data sizes for DLLISTTYPE... void * (%d), long (%d)... %s\n",
sizeof(void *), sizeof(long),
(sizeof(long) > (sizeof(void *))) ? "long" : "void *");
return (sizeof(long) > (sizeof(void *))) ? 20 : 0;
}
])],[DLLISTMODE="void *"],[DLLISTMODE="long"],[DLLISTMODE="void *"])
AC_DEFINE_UNQUOTED(DLLISTTYPE, $DLLISTMODE, [largest data type])

AC_CHECK_FUNC(tcgetpgrp, [
	AC_DEFINE_UNQUOTED(HAVE_TERMIOS, 1, [Define if you have tcgetpgrp()])
	AC_MSG_CHECKING([whether getpgrp() needs PID parameter])
	AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <unistd.h>
			int main()
			{
				if (getpgrp() == -1)
					return 0;
				else
					return 1;
			}
		]])],[
		AC_DEFINE_UNQUOTED(GETPGRP_NEED_PID, 1,
			[getpgrp() need PID parameter])
		AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)
	],[])]
)

AC_CHECK_HEADERS(sys/param.h sys/stat.h sys/mount.h sys/vfs.h \
	sys/statvfs.h sys/statfs.h arpa/inet.h)

dnl *******************************
dnl test for gnu dprint
dnl *******************************

AC_CHECK_LIB(c, dprintf, AC_DEFINE_UNQUOTED(HAVE_DPRINTF, 1, [dprintf]))

dnl *******************************
dnl misc final config stuffs
dnl *******************************

x_cflags="$CFLAGS $x_cflags"
CFLAGS=""
x_libs="$LDFLAGS $x_ldflags $x_libs $EXTRA_LIBS"


AC_SUBST(GNOME_PREFIX)
AC_SUBST(MSUBDIRS)
AC_SUBST(NWSMAKEFILE)
AC_SUBST(MSGFMT)
AC_SUBST(ICONV)
AC_SUBST(WINDRES)
AC_SUBST(MSGFMTSTATS)
AC_SUBST(DEPS)
AC_SUBST(x_libs)
AC_SUBST(x_cflags)

AC_SUBST(PAVUK_PO)
AC_SUBST(PAVUK_MO)
AC_SUBST(PAVUK_POX)
AC_SUBST(PAVUK_UPO)
AC_SUBST(PAVUK_UMO)
AC_SUBST(PAVUK_ALLMO)
AC_SUBST(PAVUK_ALLPO)
AC_SUBST(PAVUK_LANG)
AC_SUBST(PAVUK_UTFMODE)

echo "LDFLAGS=$x_libs"
echo "CPPFLAGS=$CPPFLAGS"
echo "CFLAGS=$x_cflags"

AC_CONFIG_FILES([Makefile src/Makefile icons/Makefile man/Makefile po/Makefile man/pavuk.1])
AC_OUTPUT