configure.in

网络爬虫程序

case "$WITH_DESIMPL_VAL" in
	none | auto | libcrypto | libdes | libmcrypt | libgcrypt) ;;
	*) AC_MSG_ERROR("Bad selection in --with-desimpl option !");;
esac


if eval "test x$WITH_NTLM = xyes"; then
	have_crypto_lib="no"
	if test -n "$SSL_LIBS" -a "$WITH_DESIMPL_VAL" = auto ; then
		have_crypto_lib="yes" 
		_have_ntlm="yes"
		AC_CHECK_LIB(crypto, MD4_Init,
			AC_DEFINE_UNQUOTED(HAVE_OPENSSL_MD4, 1,
				[libcrypto from OpenSSL contains MD4 cipher]))
	fi
	if test x$have_crypto_lib = "xno"; then 
		if test "$WITH_DESIMPL_VAL" = auto -o \
			"$WITH_DESIMPL_VAL" = libmcrypt; then
			
			AC_CHECK_HEADER(mcrypt.h, AC_CHECK_LIB(ltdl, lt_dlopen,
				AC_CHECK_LIB(mcrypt, mcrypt_module_open, [
					have_crypto_lib="yes" 
					_have_ntlm="yes"
					x_libs="$x_libs -lmcrypt -lltdl"
					AC_DEFINE_UNQUOTED(HAVE_MCRYPT, 1,
						[have libmcrypt])], , -ltdl),
				AC_CHECK_LIB(mcrypt, mcrypt_module_open, [
					have_crypto_lib="yes" 
					_have_ntlm="yes"
					x_libs="$x_libs -lmcrypt"
					AC_DEFINE_UNQUOTED(HAVE_MCRYPT, 1,
						[have libmcrypt])])
			))
		fi

	fi
	if test x$have_crypto_lib = "xno"; then 
		if test "$WITH_DESIMPL_VAL" = auto -o \
			"$WITH_DESIMPL_VAL" = libgcrypt; then
			AC_CHECK_PROG(LIBGCRYPT_CONFIG, libgcrypt-config,
				"yes", "no")
			if test "$LIBGCRYPT_CONFIG" = "yes"; then
				AC_MSG_CHECKING([libgcrypt settings])
				have_crypto_lib="yes"
				_have_ntlm="yes"
				x_libs="$x_libs `libgcrypt-config --libs`"
				x_cflags="$x_cflags `libgcrypt-config --cflags`"
				AC_DEFINE_UNQUOTED(HAVE_GCRYPT, 1,
					[gcrypt support for NTLM])
				AC_MSG_RESULT([done])
			fi
		fi
	fi
	if test x$have_crypto_lib = "xno"; then 
		if test "$WITH_DESIMPL_VAL" = auto -o \
			"$WITH_DESIMPL_VAL" = libcrypto; then
			if test -z "$WITH_SSL_PFX"; then
				AC_MSG_CHECKING(for OpenSSL installation directory)
				if test -z "$WITH_SSL_LIB"; then
					for i in "/usr/local/openssl" \
						 "/usr/local/ssl" \
						 "/usr/ssl" \
						 "/usr/openssl" \
						 "/opt/ssl" \
						 "/opt/openssl"; do
							if test -d "$i"; then
							    WITH_SSL_PFX="$i"
							fi
					done
				fi
				if test -n "$WITH_SSL_PFX"; then
					CPPFLAGS="$CPPFLAGS -I$WITH_SSL_PFX/include"
					LDFLAGS="$LDFLAGS -L$WITH_SSL_PFX/lib"
					AC_MSG_RESULT([$WITH_SSL_PFX])
				else
					AC_MSG_RESULT([unknown])
				fi
				AC_CHECK_HEADER(openssl/des.h, [
					AC_DEFINE_UNQUOTED(OPENSSL, 1,
					[have new OpenSSL not old SSLeay libs])]
				)
			fi
			AC_CHECK_LIB(crypto, des_ecb_encrypt, [
				have_crypto_lib="yes",
				have_crypto_lib="no"])
			AC_CHECK_LIB(crypto, MD4_Init,
				AC_DEFINE_UNQUOTED(HAVE_OPENSSL_MD4, 1,
				[libcrypto from OpenSSL contains MD4 cipher]))
			if test x$have_crypto_lib = "xyes"; then 
				x_libs="$x_libs -lcrypto"
				_have_ntlm="yes"
			fi
		fi
	fi
	if test x$have_crypto_lib = "xno"; then 
		if test "$WITH_DESIMPL_VAL" = auto -o \
			"$WITH_DESIMPL_VAL" = libdes; then
			AC_CHECK_LIB(des, des_ecb_encrypt, [
				x_libs="$x_libs -ldes"
				_have_ntlm="yes"])
		fi
	fi
	if eval "test x$_have_ntlm = xyes"; then
		AC_DEFINE_UNQUOTED(ENABLE_NTLM, 1, [NTLM authorization support])
		AC_MSG_CHECKING([whether NTLM structures are properly aligned])
		AC_RUN_IFELSE([AC_LANG_SOURCE([[
			#define ____ACCONFIG_TEST___
			#include "src/ntlm_auth.h"
			int main()
			{
				if ((sizeof(ntlm_type_1_msg_t) != (NTLM_MSG1_SIZE)) ||
				    (sizeof(ntlm_type_2_msg_t) != (NTLM_MSG2_SIZE)) ||
				    (sizeof(ntlm_type_3_msg_t) != (NTLM_MSG3_SIZE)))
				{
					exit(1);
				}
				exit(0);
			}
		]])],[AC_MSG_RESULT(yes)],[AC_DEFINE_UNQUOTED(NTLM_UNPACKED_STRUCT, 1,
			improper alignment of NTLM structures)
		AC_MSG_RESULT(no)],[])
	fi
fi

dnl ******************************
dnl checks for threading libraries
dnl ******************************
AC_ARG_ENABLE(threads,
	[  --enable-threads           compile with multithreading support],
	WITH_THREADS=$enableval, WITH_THREADS="no")
if eval "test x$WITH_THREADS = xyes"; then
	AC_MSG_CHECKING([whether the C compiler (${CC-cc}) supports -pthread])
	echo 'void f(){}' > conftest.c
	if test -z "`${CC-cc} -pthread -c conftest.c 2>&1`"; then
		ac_ccpthread_opt=yes
		x_cflags="$x_cflags -pthread"
		AC_DEFINE_UNQUOTED(HAVE_MT, 1, [multithreading support])
		x_libs="-pthread $x_libs"
		HAVE_MT="yes"
	else
		ac_ccpthread_opt=no
	fi
	rm -f conftest*
	AC_MSG_RESULT($ac_ccpthread_opt)


	if test "$ac_ccpthread_opt" = "no"; then
		AC_CHECK_LIB(pthread, pthread_create, x_libs="$x_libs -lpthread";HAVE_MT="yes";PTHREAD_LIB="pthread")
		AC_CHECK_LIB(pthreads, pthread_create, x_libs="$x_libs -lpthreads";HAVE_MT="yes";PTHREAD_LIB="pthreads")
		if test -z "$HAVE_MT"; then
			AC_CHECK_FUNC(pthread_create, HAVE_MT="yes")
		fi
		if test "$HAVE_MT" = "yes"; then
			AC_DEFINE_UNQUOTED(HAVE_MT, 1, [multithreading support])
			x_cflags="$x_cflags -D_REENTRANT"
		fi
	fi

	if test "$HAVE_MT" = "yes"; then
		AC_CHECK_FUNCS(gethostbyname_r)
		if test "$ac_cv_func_gethostbyname_r" = "no"; then
			if test -n "$PTHREAD_LIB"; then
				AC_CHECK_LIB($PTHREAD_LIB, gethostbyname_r,
					AC_DEFINE_UNQUOTED(HAVE_GETHOSTBYNAME_R,
					1,
					[threadsafe gethostbyname_r function]),
					[ AC_CHECK_LIB(c_r, gethostbyname_r,
						x_libs="$x_libs -lc_r"
						AC_DEFINE_UNQUOTED(
							HAVE_GETHOSTBYNAME_R, 1,
							[threadsafe gethostbyname_r function]))
					])
				
			fi
		fi
	fi
fi

dnl ****************************
dnl misc GUI and GTK tests
dnl ****************************
AC_ARG_ENABLE(gtk,
	[  --disable-gtk              do not compile with GTK interface],
	WITH_GTK=$enableval, WITH_GTK="yes")

AC_ARG_ENABLE(gtk2,
	[  --disable-gtk2             do not use GTK2 (fallback to GTK1)],
	WITH_GTK2=$enableval, WITH_GTK2="yes")

AC_ARG_ENABLE(gnome,
	[  --disable-gnome            don't install Gnome menu entry infos],
	WITH_GNOME=$enableval, WITH_GNOME="yes")

AC_ARG_ENABLE(tree,
	[  --disable-tree             do not compile with tree preview],
	WITH_TREE=$enableval, WITH_TREE="yes")

AC_ARG_WITH(gtk-includes,
	[  --with-gtk-includes=DIR    where you have GTK includes],
	WITH_GTK_INC="$withval")
if test -n "$WITH_GTK_INC"; then
	CPPFLAGS="$CPPFLAGS -I$WITH_GTK_INC"
fi

AC_ARG_WITH(gtk-libraries,
	[  --with-gtk-libraries=DIR   where you have GTK libraries],
	WITH_GTK_LIB="$withval")
if test -n "$WITH_GTK_LIB"; then
	LDFLAGS="$LDFLAGS -L$WITH_GTK_LIB"
fi

AC_ARG_WITH(gtk-config,
	[  --with-gtk-config=PATH     where you have GTK config script],
	WITH_GTK_CONFIG="$withval")
if test -z "$WITH_GTK_CONFIG"; then
	WITH_GTK_CONFIG="gtk-config"
fi

AC_ARG_WITH(pkg-config,
	[  --with-pkg-config=PATH     where you have pkg-config program],
	WITH_PKG_CONFIG="$withval")
if test -z "$WITH_PKG_CONFIG"; then
	WITH_PKG_CONFIG="pkg-config"
fi

if eval "test x$WITH_GTK = xyes -o x$ISCYGWIN = xyes"; then
	CFLAGS="$CFLAGS $X_CFLAGS"
	if test -n "$x_includes" -a "$x_includes" "!=" "NONE"; then
		CFLAGS="$CFLAGS -I$x_includes"
	fi

	LDFLAGS="$LDFLAGS $X_LDFLAGS"
	if test -n "$x_libraries"; then
		LDFLAGS="$LDFLAGS -L$x_libraries"
	fi

	dnl Test for X11
	AC_CHECK_LIB(X11, XOpenDisplay, X_LIBS="-lX11 $X_LIBS $X_EXTRA_LIBS", X_LIBS="", $X_EXTRA_LIBS)

	dnl Test for Xext
	if test -n "$X_LIBS"; then
		AC_CHECK_LIB(Xext, XShapeCombineRegion, X_LIBS="$X_LIBS -lXext", X_LIBS="$X_LIBS -lXext", $X_LIBS)
	fi

	dnl Test for Xmu
	if test -n "$X_LIBS"; then
		AC_CHECK_LIB(Xmu, XmuClientWindow, [
			XMU_LIBS="-lXmu"
			AC_DEFINE_UNQUOTED(HAVE_XMU, 1, [have Xmu library])
			], , $X_LIBS)
	fi

	dnl Test for gtk
	if eval "test x$WITH_GTK = xyes"; then
        	if eval "test x$WITH_GTK2 = xyes"; then
			if eval "test -x $WITH_PKG_CONFIG"; then
				PKG_CONFIG="yes"
			else
				AC_CHECK_PROG(PKG_CONFIG, $WITH_PKG_CONFIG, "yes", "no")
			fi
		fi
		if eval "test -x $WITH_GTK_CONFIG"; then
			GTK_CONFIG="yes"
		else
			AC_CHECK_PROG(GTK_CONFIG, $WITH_GTK_CONFIG, "yes", "no")
		fi
		if eval "test x$GTK_CONFIG = xno"; then
			AC_CHECK_PROG(GTK_CONFIG2, gtk-config-2.0, "yes";WITH_GTK_CONFIG="gtk-config-2.0", "no")
			GTK_CONFIG="$GTK_CONFIG2"
		fi
		if eval "test x$GTK_CONFIG = xyes -o x$PKG_CONFIG = xyes"; then
			if eval "test x$PKG_CONFIG = xyes"; then
				AC_MSG_RESULT([checking for gtk configuration using pkg-config script ...])
			else
				AC_MSG_RESULT([checking for gtk configuration using gtk-config script ...])
			fi
			if eval "test x$HAVE_MT = xyes"; then
				if eval "test x$PKG_CONFIG = xyes"; then
					GTK_LIBS=`$WITH_PKG_CONFIG --libs gtk+-2.0 gthread-2.0`
					GTK_CFLAGS=`$WITH_PKG_CONFIG --cflags gtk+-2.0 gthread-2.0`
                                        GTK_VERSION="2"
				else
					GTK_LIBS=`$WITH_GTK_CONFIG --libs gtk gthread`
					GTK_CFLAGS=`$WITH_GTK_CONFIG --cflags gtk gthread`
				fi
			else
				if eval "test x$PKG_CONFIG = xyes"; then
					GTK_LIBS=`$WITH_PKG_CONFIG --libs gtk+-2.0`
					GTK_CFLAGS=`$WITH_PKG_CONFIG --cflags gtk+-2.0`
                                        GTK_VERSION="2"
				else
					GTK_LIBS=`$WITH_GTK_CONFIG --libs`
					GTK_CFLAGS=`$WITH_GTK_CONFIG --cflags`
				fi
			fi
			AC_MSG_RESULT([	gtk LDFLAGS=$GTK_LIBS ])
			AC_MSG_RESULT([	gtk CFLAGS=$GTK_CFLAGS ])
		else
			AC_CHECK_LIB(gtk, gtk_init, GTK_LIBS="-lgtk -lgdk -lglib $X_LIBS -lm", , $X_LIBS -lgdk -lglib -lm)
		fi
		if test -n "$GTK_LIBS"; then
			GTK_LIBS="$GTK_LIBS $XMU_LIBS"
			if eval "test x$WITH_GNOME = xyes"; then
				AC_CHECK_PROG(GNOME_CONFIG, gnome-config, "yes", "no")
				if eval "test x$GNOME_CONFIG = xyes"; then
					AC_MSG_CHECKING([gnome install prefix])
					GNOME_PREFIX=`gnome-config --prefix`
					AC_MSG_RESULT([ $GNOME_PREFIX ])
				fi
			fi
		fi

		if test -n "$GTK_LIBS" ; then
			if test -n "$GTK_LIBS"; then
				x_libs="$x_libs $GTK_LIBS"
				x_cflags="$x_cflags $GTK_CFLAGS"
				AC_DEFINE_UNQUOTED(GTK_FACE, $GTK_VERSION, [with GTK+ GUI])
				AC_DEFINE_UNQUOTED(I_FACE, 1, [with GUI])
			else
				AC_MSG_WARN([pavuk will build without GUI])
			fi
			if test "$WITH_TREE" = "yes"; then
				AC_DEFINE_UNQUOTED(WITH_TREE, 1,
					[with preview dialog for HTML tree])
			fi
		fi
	fi
fi

dnl ****************************
dnl Mozilla JS engine checkings
dnl ****************************
_cppflags=${CPPFLAGS}
_ldflags=${LDFLAGS}

AC_ARG_ENABLE(js,
	[  --disable-js               do not compile with JS bindings],
	WITH_MOZJS=$enableval, WITH_MOZJS="yes")

AC_ARG_WITH(js-includes,
[  --with-js-includes=DIR     where you have Mozilla JS runtime includes],[
	if test "$withval" != "no" -a "$withval" != "yes"; then
		CPPFLAGS="${CPPFLAGS} -I$withval"
	fi
])

AC_ARG_WITH(js-libraries,
[  --with-js-libraries=DIR    where you have Mozilla JS runtime libraries],[
	if test "$withval" != "no" -a "$withval" != "yes"; then
		LDFLAGS="${LDFLAGS} -L$withval"
	fi
])

if test $WITH_MOZJS = yes; then
	if test x$ISCYGWIN = xyes; then
		CPPFLAGS="${CPPFLAGS} -DXP_PC"
	else
		CPPFLAGS="${CPPFLAGS} -DXP_UNIX"
	fi

	AC_CHECK_HEADERS(jsapi.h,
		AC_CHECK_LIB(js, JS_Init,[
			AC_DEFINE_UNQUOTED(HAVE_MOZJS, 1,
				[with JavaScript bindings])
			x_libs="$x_libs -ljs"],
			AC_CHECK_LIB(mozjs, JS_Init,[
				AC_DEFINE_UNQUOTED(HAVE_MOZJS, 1,
					[with JavaScript bindings])
				x_libs="$x_libs -lmozjs"],
				CPPFLAGS=${_cppflags}
				LDFLAGS=${_ldflags})),
		CPPFLAGS=${_cppflags}
		LDFLAGS=${_ldflags})
else
	CPPFLAGS=${_cppflags}
	LDFLAGS=${_ldflags}
fi

dnl ********************************
dnl all the various REGEX tests
dnl ********************************
AC_ARG_WITH(regex, [  --with-regex=[none/auto/posix/gnu/v8/bsd/pcre/lregex] select type of regular expressions you want to use],
	WITH_REGEX="$withval", WITH_REGEX="auto")

case "$WITH_REGEX" in
	none | auto | posix | gnu | v8 | bsd | pcre | lregex) ;;
	*) AC_MSG_ERROR("Bad selection in --with-regex option !");;
esac

if eval "test x$WITH_REGEX = xnone"; then
	want_regex_impl=no
else
	want_regex_impl=yes
	AC_CHECK_HEADERS(regex.h)
fi

dnl ********************************
dnl test for POSIX regex in libregex
dnl ********************************

if eval "test x$want_regex_impl = xyes"; then
	if eval "test x$WITH_REGEX = xauto -o x$WITH_REGEX = xlregex"; then
		AC_CHECK_LIB(regex, regcomp, [
			AC_DEFINE_UNQUOTED(HAVE_REGEX, 1, [REs support])
			AC_DEFINE_UNQUOTED(HAVE_POSIX_REGEX, 1, [POSIX REs])
			x_libs="$x_libs -lregex"; want_regex_impl="no"])
	fi
fi	


dnl ********************
dnl test for POSIX regex
dnl ********************

if eval "test x$want_regex_impl = xyes"; then
	if eval "test x$WITH_REGEX = xauto -o x$WITH_REGEX = xposix"; then
		AC_MSG_CHECKING([for POSIX regcomp()])
		ac_pregcomp="no" 
		AC_LINK_IFELSE([AC_LANG_PROGRAM([[
		#include <sys/types.h>
		#include <regex.h>
		]], [[
			regex_t pr;
			regcomp(&pr , "" , 0);
		]])],[ac_pregcomp="yes"],[])
		AC_MSG_RESULT($ac_pregcomp)
		if eval "test x$ac_pregcomp = xyes"; then
			AC_DEFINE_UNQUOTED(HAVE_REGEX, 1, [REs support])
			AC_DEFINE_UNQUOTED(HAVE_POSIX_REGEX, 1, [POSIX REs])
			want_regex_impl=no
		fi
	fi
fi

dnl ********************
dnl test for PCRE regex
dnl ********************

if eval "test x$want_regex_impl = xyes"; then
	if eval "test x$WITH_REGEX = xauto -o x$WITH_REGEX = xpcre"; then
		AC_CHECK_PROG(PCRE_CONFIG, pcre-config, "yes", "no")