configure.in

网络爬虫程序

AC_INIT([pavuk],[0.9.35])
AC_CONFIG_SRCDIR([src/pavuk.c])
AC_CONFIG_HEADERS([ac-config.h])
AM_INIT_AUTOMAKE

ALL_LINGUAS="cs de es fr it ja pl sk uk"

REVISION=`date +%Y-%m-%dT%H:%M`
AC_DEFINE_UNQUOTED(REVISION, "$REVISION", [revision number of software])
AC_SUBST(REVISION)
AC_PREFIX_DEFAULT(/usr/local)

CFLAGS="$CFLAGS $v_cflags"

AC_ARG_ENABLE(debug, [  --disable-debug         turn off debugging],
	WITH_DEBUG=$enableval, WITH_DEBUG="yes")

if eval "test x$WITH_DEBUG = xyes"; then
	AC_DEFINE_UNQUOTED(DEBUG, 1,
		[Define if you want to compile with debuging options])
fi

AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_MAKE_SET
AC_PROG_RANLIB

AC_CANONICAL_HOST
case $host_os in
  *cygwin* ) ISCYGWIN=yes;;
	 * ) ISCYGWIN=no;;
esac
AC_DEFINE_UNQUOTED(HOSTTYPE, "$host_os", [Set host type])

if eval "test x$ISCYGWIN = xyes"; then
	AC_MSG_CHECKING([style of cygwin paths])
	if test -d /cygdrive/C; then
		ac_cygwin_paths_style=new
		AC_DEFINE_UNQUOTED(HAVE_NEWSTYLE_CYGWIN, 1,
			[Define if you have cygwin with new paths style])
	else
		ac_cygwin_paths_style=old
	fi
	AC_MSG_RESULT($ac_cygwin_paths_style)

	AC_MSG_CHECKING([whether the C compiler (${CC-cc}) supports -fnative-struct])
	echo 'void f(){}' > conftest.c
	if test -z "`${CC-cc} -fnative-struct -c conftest.c 2>&1`"; then
		ac_ccfnativestruct_opt=yes
		CFLAGS="$CFLAGS -fnative-struct"
	else
		ac_ccfnativestruct_opt=no
	fi
	rm -f conftest*
	AC_MSG_RESULT($ac_ccfnativestruct_opt)

	WINDRES="windres"
	DEPS="pavuk.exe: pavukrc.ro"
fi

AC_MSG_CHECKING([whether using broken Apple precompiler])
AC_RUN_IFELSE([AC_LANG_SOURCE([[
	void exit(int);
	int main()
	{
#ifdef __APPLE_CPP__
		exit(0);
#else
		exit(1);
#endif
	}
]])],[
	AC_MSG_RESULT([yes])
	CPPFLAGS="$CPPFLAGS -no-cpp-precomp"
],[AC_MSG_RESULT(no)],[])

AC_PATH_PROG(AT, at, at)
AC_PATH_PROG(GZIP, gzip, gzip)
AC_HEADER_STDC
AC_PATH_X
AC_PATH_XTRA

AC_SYS_LONG_FILE_NAMES
AC_C_BIGENDIAN

if eval "test x$GCC = xyes"; then
  if eval "! echo $CFLAGS | grep \\-Wall" > /dev/null 2> /dev/null; then
    CFLAGS="$CFLAGS -Wall"
  fi

  if eval "test x$enable_ansi = xyes"; then
    if eval "! echo $CFLAGS | grep \\-ansi" > /dev/null 2> /dev/null; then
      CFLAGS="$CFLAGS -ansi"
    fi

    if eval "! echo $CFLAGS | grep \\-pedantic" > /dev/null 2> /dev/null; then
      CFLAGS="$CFLAGS -pedantic"
    fi
  fi
fi

GTK_LIBS=''
GTK_VERSION='1'
X_LIBS="$X_EXTRA_LIBS"
INTL_LIBS=''
SSL_LIBS=''
EXTRA_LIBS=''

AC_CHECK_TYPE(ssize_t, long)

AC_CHECK_LIB(nsl, gethostname, EXTRA_LIBS="$EXTRA_LIBS -lnsl")
AC_CHECK_LIB(socket, socket, EXTRA_LIBS="$EXTRA_LIBS -lsocket")

dnl **************************
dnl SOCKS tests
dnl **************************

AC_ARG_ENABLE(socks,
	[  --disable-socks            do not use SOCKS proxy support], 
	WITH_SOCKS=$enableval, WITH_SOCKS="yes")

AC_ARG_WITH(socks-includes,
	[  --with-socks-includes=DIR  where you have socks includes],
	WITH_SOCKS_INC="$withval")

if test -n "$WITH_SOCKS_INC"; then
	CPPFLAGS="$CPPFLAGS -I$WITH_SOCKS_INC"
fi

AC_ARG_WITH(socks-libraries,
	[  --with-socks-libraries=DIR where you have socks libraries],
	WITH_SOCKS_LIB="$withval")
if test -n "$WITH_SOCKS_LIB"; then
	LDFLAGS="$LDFLAGS -L$WITH_SOCKS_LIB"
fi

if eval test x$WITH_SOCKS = xyes; then
	SOCKS_LIBS=''

	AC_CHECK_HEADER(socks.h, AC_DEFINE_UNQUOTED(HAVE_SOCKS_H, 1, [<socks.h>]))
	AC_CHECK_LIB(socks5, SOCKSinit,
		SOCKS_LIBS="$SOCKS_LIBS -lsocks5")
	if test -z "$SOCKS_LIBS"; then
		AC_CHECK_LIB(socks, Rconnect, SOCKS_LIBS="$SOCKS_LIBS -lsocks")
		if test -n "$SOCKS_LIBS"; then
			AC_CHECK_LIB(resolv, main, SOCKS_LIBS="$SOCKS_LIBS -lresolv")
                fi
	fi
	if test -n "$SOCKS_LIBS"; then
		x_libs="$x_libs $SOCKS_LIBS"
		AC_DEFINE_UNQUOTED(SOCKS, 1, [Socks proxy support])
	fi
fi

X_LIBS="$X_LIBS $EXTRA_LIBS"

dnl *************************
dnl gettext libintl tests
dnl *************************
AC_ARG_ENABLE(nls,
	[  --disable-nls              do not use Native Language Support], 
	WITH_NLS=$enableval, WITH_NLS="yes")

AC_ARG_WITH(intl-includes,
	[  --with-intl-includes=DIR   where you have gettext includes],
	WITH_INTL_INC="$withval")
if test -n "$WITH_INTL_INC"; then
	CPPFLAGS="$CPPFLAGS -I$WITH_INTL_INC"
fi

AC_ARG_WITH(intl-libraries,
	[  --with-intl-libraries=DIR  where you have gettext libraries],
	WITH_INTL_LIB="$withval")
if test -n "$WITH_INTL_LIB"; then
	LDFLAGS="$LDFLAGS -L$WITH_INTL_LIB"
fi

AC_ARG_ENABLE(utf-8,
	[  --enable-utf-8             create language files with UTF-8], 
	WITH_UTF=$enableval, WITH_UTF="no")
if eval "test x$WITH_UTF = xyes"; then
	PAVUK_UTFMODE="umo"
else
	PAVUK_UTFMODE="mo"
fi

if eval "test x$WITH_NLS = xyes"; then
	AC_CHECK_LIB(c, gettext, INTL_LIBS=" ";_INTL_LIB="c")
	if test -z "$INTL_LIBS"; then
		AC_CHECK_LIB(intl, gettext, INTL_LIBS="-lintl";_INTL_LIB="intl")
	fi
	if test -n "$INTL_LIBS"; then
		MSUBDIRS="$MSUBDIRS po"
		x_libs="$x_libs $INTL_LIBS"
		AC_DEFINE_UNQUOTED(GETTEXT_NLS, 1, [gettext intl stuffs])
		AC_CHECK_LIB($_INTL_LIB, _nl_msg_cat_cntr, 
			AC_DEFINE_UNQUOTED(HAVE_CAT_CNTR, 1,
				[have _nl_msg_cat_cntr in libintl]))
	fi

	INST_LANG=""
	if test -n "$LINGUAS"; then
		for i in $LINGUAS; do
			for j in $ALL_LINGUAS; do
				if test "$i" = "$j"; then
					INST_LANG="$INST_LANG $j"
				fi
			done
		done
	else
		INST_LANG="$ALL_LINGUAS"
	fi
	PAVUK_LANG=""
	PAVUK_PO=""
	PAVUK_MO=""
	PAVUK_POX=""
	PAVUK_UPO=""
	PAVUK_UMO=""
	for i in $INST_LANG; do
		PAVUK_LANG="$PAVUK_LANG $i"
		PAVUK_PO="$PAVUK_PO $i.po"
		PAVUK_MO="$PAVUK_MO $i.mo"
		PAVUK_POX="$PAVUK_POX $i.pox"
		PAVUK_UPO="$PAVUK_UPO $i.upo"
		PAVUK_UMO="$PAVUK_UMO $i.umo"
	done
	PAVUK_ALLPO=""
	PAVUK_ALLMO=""
	for i in $ALL_LINGUAS; do
		PAVUK_ALLPO="$PAVUK_ALLPO $i.po"
		PAVUK_ALLMO="$PAVUK_ALLMO $i.mo"
	done

	AC_CHECK_PROG(MSGFMT, msgfmt, msgfmt, echo)
	if eval "test x$MSGFMT = xmsgfmt"; then
		AC_MSG_CHECKING([whether have GNU gettext msgfmt])
		_tmp_grp=`msgfmt -h 2>&1 | grep '\--statistics'`
		if test -n "$_tmp_grp" ; then
			MSGFMTSTATS="--statistics -c -v"
			AC_MSG_RESULT([yes])
		else
			AC_MSG_RESULT([no])
		fi
	fi
	AC_CHECK_PROG(ICONV, iconv, iconv, echo)
fi

dnl *************************
dnl SSL support tests
dnl *************************
AC_ARG_ENABLE(ssl,
	[  --disable-ssl              do not compile with SSL support],
	WITH_SSL=$enableval, WITH_SSL="yes")

AC_ARG_WITH(ssl, [  --with-ssl=[none/auto/openssl/ssleay/nss] select type of used SSL layer],
	WITH_SSL_VAL="$withval", WITH_SSL_VAL="auto")

case "$WITH_SSL_VAL" in
	none | auto | nss | openssl | ssleay) ;;
	*) AC_MSG_ERROR("Bad selection in --with-ssl option !");;
esac

if eval "test x$WITH_SSL_VAL = xnone"; then
	want_ssl_impl=no
else
	want_ssl_impl=yes
fi

dnl *************************
dnl OpenSSL libraries tests
dnl *************************
AC_ARG_WITH(ssl-includes,
	[  --with-ssl-includes=DIR    where you have SSLeay includes],
	WITH_SSL_INC="$withval")
if test -n "$WITH_SSL_INC"; then
	CPPFLAGS="$CPPFLAGS -I$WITH_SSL_INC"
fi

AC_ARG_WITH(ssl-libraries,
	[  --with-ssl-libraries=DIR   where you have SSLeay libraries],
	WITH_SSL_LIB="$withval")
if test -n "$WITH_SSL_LIB"; then
	LDFLAGS="$LDFLAGS -L$WITH_SSL_LIB"
fi

AC_ARG_WITH(egd-socket,
	[  --with-egd-socket=NAME     use NAME for the EGD socket],
		egd_socket_name="$withval", egd_socket_name="" )
if test -n "$egd_socket_name"; then
	AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name", 
		[path to EGD/PRNGD socket])
fi

if test x$want_ssl_impl = xyes -a x$WITH_SSL = xyes; then
	if eval "test x$WITH_SSL_VAL = xauto -o \
		x$WITH_SSL_VAL = xopenssl -o x$WITH_SSL_VAL = ssleay"; then

		AC_MSG_CHECKING(for OpenSSL installation directory)
		if test -z "$WITH_SSL_LIB"; then
			for i in "/usr/local/openssl" \
				 "/usr/local/ssl" \
				 "/usr/ssl" \
				 "/usr/openssl" \
				 "/opt/ssl" \
				 "/opt/openssl"; do
					if test -d "$i"; then
						WITH_SSL_PFX="$i"
					fi
			done
		fi
		if test -n "$WITH_SSL_PFX"; then
			CPPFLAGS="$CPPFLAGS -I$WITH_SSL_PFX/include"
			LDFLAGS="$LDFLAGS -L$WITH_SSL_PFX/lib"
			AC_MSG_RESULT([$WITH_SSL_PFX])
		else
			AC_MSG_RESULT([unknown])
		fi
		AC_CHECK_LIB(ssl, SSLv23_client_method, SSL_LIBS="-lssl",
				 ,-lcrypto $EXTRA_LIBS)
		if test -n "$SSL_LIBS"; then
			AC_CHECK_LIB(ssl, TLSv1_client_method,
				TLS1=yes, TLS1=no, -lcrypto $EXTRA_LIBS)
			AC_CHECK_LIB(crypto, RAND_egd, RAND_EGD=yes)
			AC_CHECK_HEADER(ssl.h, SSLEAY=yes, SSLEAY=no)
			AC_CHECK_HEADER(openssl/ssl.h, OPENSSL=yes, OPENSSL=no)
			if eval "test x$SSLEAY = xno -a  x$OPENSSL = xno"; then
				AC_MSG_WARN("SSLeay or OpenSSL headers not found --\> use --disable-ssl option or set --with-ssl-includes to apropriate location")
			fi
			AC_CHECK_LIB(crypto, SSLeay,
				SSL_LIBS="$SSL_LIBS -lcrypto", SSL_LIBS='')
		fi
		if test -n "$SSL_LIBS"; then
			want_ssl_impl="no"
		fi

		if test -n "$SSL_LIBS"; then
			x_libs="$x_libs $SSL_LIBS"
			AC_DEFINE_UNQUOTED(USE_SSL, 1, [want SSL support])
			AC_DEFINE_UNQUOTED(USE_SSL_IMPL_OPENSSL, 1,
				[use OpenSSL for SSL support])
			if eval "test x$OPENSSL = xyes"; then
				AC_DEFINE_UNQUOTED(OPENSSL, 1,
					[have new OpenSSL not old SSLeay libs])
			fi
			if eval "test x$TLS1 = xyes"; then
				AC_DEFINE_UNQUOTED(WITH_SSL_TLS1, 1,
					[have new OpenSSL with TLS1 support])
			fi
			if eval "test x$RAND_EGD = xyes"; then
				AC_DEFINE_UNQUOTED(HAVE_RAND_EGD, 1,
					[OpenSSL lib contains EGD/PRNGD support])
			fi
		fi
	fi
fi

dnl *************************
dnl NSS - Mozilla SSL tests
dnl *************************
AC_ARG_WITH(nss-includes,
	[  --with-nss-includes=DIR    where you have NSS includes],
	WITH_NSS_INC="$withval")
if test -n "$WITH_NSS_INC"; then
	CPPFLAGS="$CPPFLAGS -I$WITH_NSS_INC"
fi

AC_ARG_WITH(nspr-includes,
	[  --with-nspr-includes=DIR   where you have NSPR includes],
	WITH_NSPR_INC="$withval")
if test -n "$WITH_NSPR_INC"; then
	CPPFLAGS="$CPPFLAGS -I$WITH_NSPR_INC"
fi

AC_ARG_WITH(nss-libraries,
	[  --with-nss-libraries=DIR   where you have NSS libraries],
	WITH_NSS_LIB="$withval")
if test -n "$WITH_NSS_LIB"; then
	LDFLAGS="$LDFLAGS -L$WITH_NSS_LIB"
fi

AC_ARG_WITH(nspr-libraries,
	[  --with-nspr-libraries=DIR  where you have NSPR libraries],
	WITH_NSPR_LIB="$withval")
if test -n "$WITH_NSPR_LIB"; then
	LDFLAGS="$LDFLAGS -L$WITH_NSPR_LIB"
fi

AC_ARG_WITH(nspr-config,
	[  --with-nspr-config=DIR     path o nspr-config script],
	WITH_NSPR_CONF="$withval")


if test x$want_ssl_impl = xyes -a x$WITH_SSL = xyes; then
	if eval "test x$WITH_SSL_VAL = xauto -o x$WITH_SSL_VAL = xnss"; then
		if test -z "$WITH_NSPR_CONF"; then
			AC_CHECK_PROG(NSPR_CONFIG, nspr-config, "yes";WITH_NSPR_CONF="nspr-config", "no")

		fi
		if test -n "$WITH_NSPR_CONF"; then
			NSPR_LIBS=`"$WITH_NSPR_CONF" --libs`
			NSPR_CFLAGS=`"$WITH_NSPR_CONF" --cflags`
		else
			NSPR_LIBS="-lplc4 -lplds4 -lnspr4"
			NSPR_CFLAGS=""
		fi
		AC_CHECK_HEADERS(prio.h nss.h ssl.h smime.h, [
			saved_LDFLAGS="$LDFLAGS"
			saved_CFLAGS="$CFLAGS"
			LDFLAGS="$LDFLAGS -lssl3 -lsmime -lnss3 -lsectool -lpkcs7 $NSPR_LIBS"
			CFLAGS="$CFLAGS $NSPR_CFLAGS"
			AC_TRY_LINK_FUNC(NSS_Init, NSS_LIBS="-lssl3 -lsmime -lnss3 -lsectool -lpkcs7 $NSPR_LIBS"; want_ssl_impl="no")
			LDFLAGS="$saved_LDFLAGS"
			CFLAGS="$saved_CFLAGS"
		])
		AC_MSG_CHECKING(for Mozilla NSS3 support)
		if test -z "$NSS_LIBS"; then
			AC_MSG_RESULT([no])
		else
			AC_MSG_RESULT([yes])
		fi

		if test -n "$NSS_LIBS"; then
			x_libs="$x_libs $NSS_LIBS"
			AC_DEFINE_UNQUOTED(USE_SSL, 1, [want SSL support])
			AC_DEFINE_UNQUOTED(USE_SSL_IMPL_NSS, 1,
				[use Mozilla NSS3 for SSL support])
		fi
	fi
fi


dnl *********************
dnl test for NTLM support
dnl *********************
AC_ARG_ENABLE(ntlm,
	[  --disable-ntlm             do not compile with NTLM auth support],
	WITH_NTLM=$enableval, WITH_NTLM="yes")

AC_ARG_WITH(desimpl, [  --with-desimpl=[none/auto/libcrypto/libdes/libmcrypt/libgcrypt] select DES library],
	WITH_DESIMPL_VAL="$withval", WITH_DESIMPL_VAL="auto")