configure.ac

About: Paco (pacKAGE oRGANIZER) is a simple, yet powerful tool to aid package management when insta

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.
#

AC_INIT([paco], [2.0.3], [[e-mail]])
AC_CONFIG_SRCDIR([paco/Log.h])
AC_CONFIG_AUX_DIR([build])
AM_INIT_AUTOMAKE([ \
 	-Wall \
 	foreign \
 	no-installinfo \
 	no-texinfo.tex
])
AM_MAINTAINER_MODE
AC_CONFIG_HEADERS([config.h])
AC_CONFIG_FILES([ \
	Makefile \
	lib/Makefile \
	lib/paco/Makefile \
	lib/paco-log/Makefile \
	paco/Makefile \
	gpaco/Makefile \
	scripts/Makefile \
	doc/Makefile \
	doc/pacorc \
	doc/pacorc.5 \
	doc/paco.8 \
	doc/pacoball.8 \
	doc/rpm2paco.8 \
	doc/superpaco.8 \
	doc/paco.pc \
])

m4_include([build/pkg.m4])

AC_DEFINE([NDEBUG], [1], [Disable assertions])
AC_DEFINE([G_DISABLE_ASSERT], [1], [Disable assertions])

#RELEASEDATE="`date +'%d %B %Y'`"
RELEASEDATE="17 July 2007"
AC_DEFINE_UNQUOTED([RELEASEDATE], ["$RELEASEDATE"], [Release date])
AC_SUBST([RELEASEDATE])

INCLUDE="/"
AC_DEFINE_UNQUOTED([INCLUDE], ["$INCLUDE"], [List of paths to scan])
AC_SUBST([INCLUDE])

EXCLUDE="/dev:/tmp"
for dir in /usr/src /selinux /sys /usr/share/info/dir; do
	test -e "$dir" && EXCLUDE="$EXCLUDE:$dir"
done
AC_DEFINE_UNQUOTED([EXCLUDE], ["$EXCLUDE"], [List of paths to skip])
AC_SUBST([EXCLUDE])

AC_ARG_ENABLE([gpaco],
	AC_HELP_STRING([--disable-gpaco],
		[disable compiling gpaco (the GTKMM port of paco)]),
	[enable_gpaco=$enableval], [enable_gpaco=yes])
AM_CONDITIONAL([ENABLE_GPACO], [test x"$enable_gpaco" = x"yes"])

AC_ARG_ENABLE([scripts],
	[AC_HELP_STRING([--enable-scripts],
		[install the auxiliary scripts (see README)])],
	[], [enable_scripts=no])
AM_CONDITIONAL([ENABLE_SCRIPTS], [test x"$enable_scripts" = x"yes"])

AC_ARG_WITH([paco-logdir],
	[AC_HELP_STRING([--with-paco-logdir=DIR],
		[paco log directory [default=/var/log/paco]])],
	[LOGDIR=$withval], [LOGDIR=/var/log/paco]
)
AC_DEFINE_UNQUOTED([LOGDIR], ["$LOGDIR"], [Default paco logs directory])
AC_SUBST([LOGDIR])

AC_GNU_SOURCE

AC_PROG_MAKE_SET
AC_PROG_LIBTOOL
AC_PROG_RANLIB

AC_PROG_CC
AC_PROG_CXX
AC_C_INLINE

AM_CONDITIONAL(HAVE_GCC, [test x"$GCC" = x"yes" \
	|| test x"$ac_cv_prog_ac_ct_CC" = x"gcc"])
AM_CONDITIONAL([HAVE_GXX], [test x"$GXX" = x"yes" \
	|| test x"$ac_cv_prog_ac_ct_CXX" = x"g++"])

AC_TYPE_MODE_T
AC_TYPE_OFF_T
AC_CHECK_TYPE([off64_t], [unsigned long])
AC_CHECK_TYPE([uint], [unsigned int])
AC_CHECK_TYPE([ulong], [unsigned long])

# Whether dlopen() requires -ldl LDFLAG
AC_CHECK_LIB([dl], [dlopen])

# GTKMM
if test x"$enable_gpaco" = x"yes"; then
	PKG_CHECK_MODULES([GTKMM], [gtkmm-2.4 >= 2.8])
fi


# headers
AC_HEADER_SYS_WAIT
AC_HEADER_TIME
AC_CHECK_HEADERS([ \
	termios.h \
	sys/ioctl.h \
	sys/param.h \
	sys/mount.h \
	sys/vfs.h \
	sys/statfs.h \
	sys/statvfs.h \
])

# functions
AC_CHECK_FUNCS([ \
	open64 \
	creat64 \
	truncate64 \
	fopen64 \
	freopen64 \
	statfs \
	statvfs \
	setenv \
	strcasecmp \
	strncasecmp \
])

# getopt_long
AC_CHECK_FUNC([getopt_long], [have_getopt="yes"], [have_getopt="no"])
AM_CONDITIONAL([NEED_GETOPT], [test x"$have_getopt" = x"no"])

# Struct winsize
AC_CHECK_MEMBER([struct winsize.ws_col],
	[AC_DEFINE([HAVE_STRUCT_WINSIZE], [1], [struct winsize])],
	[], [
	#ifdef HAVE_TERMIOS_H
	#	include <termios.h>
	#endif
	#ifdef HAVE_SYS_IOCTL_H
	#	include <sys/ioctl.h>
	#endif
	])

AH_BOTTOM([
	#include "config-bot.h"
])

AC_OUTPUT