link2106_ram.ld

The latest release, ver 1.16 of the ARM (7TDMI, 720T, 920T) port for uC/OS-II V2.61 (and higher) inc

/**************************************************************************
*                                                                         *
*   PROJECT     : ARM port for uC/OS-II                                   *
*                                                                         *
*   MODULE      : LINK2106_RAM.ld                                         *
*                                                                         *
*   AUTHOR      : Michael Anburaj                                         *
*                 URL  : http://geocities.com/michaelanburaj/             *
*                 EMAIL: [e-mail]                       *
*                                                                         *
*   SPONSORS    : Thanks to Martin Li ([e-mail]) & Don Williams    *
*                 ([e-mail]) for sponsoring hardware.            *
*                                                                         *
*   PROCESSOR   : LPC2106 (32 bit ARM7TDMI-S RISC core from Philips)      *
*                                                                         *
*   TOOL-CHAIN  : GCC                                                     *
*                                                                         *
*   DESCRIPTION :                                                         *
*   This is the Linker script file for RAM builds.                        *
*                                                                         *
**************************************************************************/


ENTRY(_start)

/* Memory Definitions */
MEMORY
{
  rom (rx) : ORIGIN = 0x00000000, LENGTH = 0x00020000
  ram (rw) : ORIGIN = 0x40000000, LENGTH = 0x00010000
}

/* Section Definitions */
SECTIONS
{
  /* first section is .text which is used for code */
  .text 0x40001000 :
  {
    init.o (.text)             /* Startup code */
    *(.text)                   /* remaining code */
    *(.rodata)                 /* read-only data (constants) */
    *(.rodata*)
    *(.glue_7)
    *(.glue_7t)
  } > ram

  . = ALIGN(4);
  _etext = . ;
  PROVIDE (etext = .);

  /* .data section which is used for initialized data */
  .data :
  {
    _data = .;
    *(.data)
  } > ram

  . = ALIGN(4);
  _edata = . ;
  PROVIDE (edata = .);

  /* .bss section which is used for uninitialized data */
  .bss (NOLOAD) :
  {
    _bss = . ;
    *(.bss)
    *(COMMON)
    . = ALIGN(4);
  } > ram

  . = ALIGN(4);
  _end = . ;
  PROVIDE (end = .);
}


/* ********************************************************************* */