configure.in

avi player 使用Linux下 GDK,GTK

AC_INIT(src/main.c)
AM_CONFIG_HEADER(include/config.h)

AM_INIT_AUTOMAKE(sinek,0.7)

dnl Checks for programs
AC_PROG_CC
AC_PROG_INSTALL

dnl Checks for header files
AC_HEADER_STDC
AC_CHECK_HEADERS(unistd.h strings.h errno.h)

dnl Checks for typedefs and structures
AC_C_CONST
AC_C_INLINE
AC_TYPE_SIZE_T

dnl Check -Wall flag of GCC
if test "x$GCC" = "xyes"; then
  if test -z "`echo "$CFLAGS" | grep "\-Wall" 2> /dev/null`" ; then
    CFLAGS="$CFLAGS -Wall"
  fi
fi


dnl
dnl i18n
dnl
ALL_LINGUAS="de es fr ru"
AM_GNU_GETTEXT dnl (use-libtool)
if test x"$USE_INCLUDED_LIBINTL" = x"yes"; then
   INTLDIR="-I\$(top_builddir)/intl -I\$(top_srcdir)/intl"
fi
AC_SUBST(INTLDIR)


dnl
dnl Checks for libraries
dnl
PKG_CHECK_MODULES(GLIB2, glib-2.0 >= 2.0.0)
PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.0.0)

AM_PATH_XINE(0.9.9,, AC_MSG_ERROR(*** You should install xine-lib first ***))
XINE_LOCALEDIR="`echo $xine_locale_dir|sed -e 's/\^'$escapedprefix/'\${prefix}'/`"
AC_SUBST(XINE_LOCALEDIR)
AC_DEFINE_UNQUOTED(XINE_LOCALEDIR, "$XINE_LOCALEDIR")

AC_PATH_X
XTEST_LIBS=""
AC_CHECK_LIB(Xtst, XTestFakeKeyEvent,
        XTEST_LIBS="-lXtst -L$x_libraries"
        AC_DEFINE(HAVE_XTEST),
        ,
        "-L$x_libraries")
AC_SUBST(XTEST_LIBS)

AC_ARG_ENABLE(guile,
[  --disable-guile         disable use of guile scripting],
        guile=$enableval, guile=yes)
if test "$guile" = yes; then
    AM_PATH_GUILE(lala, AC_DEFINE(USE_GUILE), [guile=no])
fi
AM_CONDITIONAL(DO_GUILE, test "x$guile" = "xyes")


dnl
dnl Checks for functions
dnl
AC_CHECK_FUNCS(getopt_long)


dnl
dnl Some include paths ( !!! DO NOT REMOVE !!! )
dnl
INCLUDES='-I$(top_srcdir) -I$(top_builddir) -I$(top_builddir)/include -I$(top_srcdir)/include -I$(prefix)/include $(INTLDIR)'
AC_SUBST(INCLUDES)


dnl
dnl Create the makefiles
dnl
AC_OUTPUT([
Makefile
pixmaps/Makefile
include/Makefile
src/Makefile
intl/Makefile
po/Makefile.in
m4/Makefile
sinek.spec
])