configure.in

openGFS , a kind of file system.

dnl Process this file with autoconf to produce a configure script.
AC_INIT(cmd/gclient.c)
AM_INIT_AUTOMAKE(gnbd, 0.0.91)
AM_CONFIG_HEADER(config.h)

dnl Checks for programs.
AC_PROG_CC
AC_PROG_MAKE_SET

dnl Checks for libraries.
dnl Replace `main' with a function in -lpthread:
AC_CHECK_LIB(pthread, pthread_create)

dnl Checks for header files.
AC_HEADER_DIRENT
AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h sys/time.h unistd.h)

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_OFF_T
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_STRUCT_ST_RDEV
AC_HEADER_TIME

dnl Checks for library functions.
AC_PROG_GCC_TRADITIONAL
AC_HEADER_MAJOR
AC_FUNC_MMAP
AC_TYPE_SIGNAL
AC_CHECK_FUNCS(mkdir mkfifo select socket strerror strstr strtoul)

dnl Check for Linux kernel specifics.
AC_MSG_CHECKING(for kernel source)
AC_ARG_WITH(kernel-source,
[  --with-kernel-source=DIRECTORY	Specify kernel source location],
[
	if test -z "$withval" -o ! -d "$withval" -o ! -f "$withval/init/main.c"; then
	    AC_MSG_RESULT(invalid)
	    AC_ERROR([The directory $withval does not contain a valid kernel source tree])
	else
	    ktree=$withval
	fi
],
[
	ktree=/usr/src/linux
	if test -z "$ktree" -o ! -d "$ktree" -o ! -f "$ktree/include/linux/version.h"; then
	    AC_MSG_RESULT(invalid)
	    AC_ERROR([The directory $ktree does not contain a valid and configured kernel source tree])
	fi
])
AC_MSG_RESULT($ktree)
AC_SUBST(ktree)

AC_MSG_CHECKING(for kernel version)
AC_TRY_RUN(
[#include <$ktree/include/linux/version.h>
#include <stdio.h>

main()
{
	FILE *f;

	if (!(f=fopen("conftestval", "w")))
		exit(1);
	fprintf(f, "%s\n", UTS_RELEASE);
	exit(0);
}
], kver=`cat conftestval`, kver=, kver=)
AC_MSG_RESULT($kver)
AC_SUBST(kver)

AC_MSG_CHECKING(for kernel module location)
AC_ARG_WITH(module-dir,
[  --with-module-dir=DIRECTORY		Specify where modules will be installed],
[
	if test -z "$withval"; then
	    AC_MSG_RESULT(invalid)
	    AC_ERROR([--with-module-dir needs an argument])
	else
	    moddir=$withval
	fi
],
[moddir=/lib/modules/$kver/gnbd])
AC_MSG_RESULT($moddir)
AC_SUBST(moddir)

AC_MSG_CHECKING(for kernel-space compiler)
AC_ARG_WITH(kcc,
[  --with-kcc=PROGRAM			Specify compiler to use for modules],
[
	if test -z "$withval" -o ! -x "$withval"; then
	    AC_MSG_RESULT(invalid)
	    AC_ERROR(The kernel-space compiler is not an executable)
	else
	    KCC=$withval
	fi
],
[
	KCC=gcc
	case "$target_cpu" in
	sun4u)
	    KCC=sparc64-linux-gcc
	esac
])
AC_MSG_RESULT($KCC)
AC_SUBST(KCC)

AC_MSG_CHECKING(for kernel-space compiler options)
AC_ARG_WITH(kcflags,
[  --with-kcflags=FLAGS			Specify CFLAGS to use for modules],
[
	if test -z "$withval"; then
	    AC_MSG_RESULT(invalid)
	    AC_ERROR([--with-kcflags needs an argument])
	else
	    KCFLAGS=$withval
	fi
],
[
	KCFLAGS="-O2 -fomit-frame-pointer -fno-strict-aliasing"
	case "$target_cpu" in
	alpha)
		KCFLAGS="$KCFLAGS -mno-fp-regs -ffixed-8";;
	powerpc)
		KCFLAGS="$KCFLAGS -msoft-float";;
	sparc64)
		KCFLAGS="$KCFLAGS -m64 -mno-fpu -mcpu=ultrasparc -mcmodel=medlow -ffixed-g4"
		KCFLAGS="$KCFLAGS -fcall-used-g5 -fcall-used-g7 -Wno-sign-compare";;
	esac
])
AC_MSG_RESULT($KCFLAGS)
AC_SUBST(KCFLAGS)

AC_MSG_CHECKING(for kernel-space linker)
AC_ARG_WITH(kld,
[  --with-kld=PROGRAM			Specify linker to use for modules],
[
	if test -z "$withval" -o ! -x "$withval"; then
	    AC_MSG_RESULT(invalid)
	    AC_ERROR(The kernel-space compiler is not an executable)
	else
	    KLD=$withval
	fi
],
[
	KLD=ld
	case "$target_cpu" in
	sun4u)
	    KLD="ld -m elf64_sparc -L/usr/lib"
	esac
])
AC_MSG_RESULT($KLD)
AC_SUBST(KLD)


AC_OUTPUT([
Makefile
cmd/Makefile
kern/Makefile
srv/Makefile
include/Makefile
doc/Makefile
extras/Makefile
gnbd.spec
])