exam602.asm

我在汇编课上完成的一些作业（上机常见习题）和汇编课本上的几个例题

;已知m*n矩阵A的元素aij按行序存放在以BUFA为首地址的字节存储区中，
;试编写程序，求每行元素之和si，其中aij为8位二进制数。
stack segment stack
      db 200 dup(0)
stack ends
data segment
     bufa db 11h,12h,13h,14h,15h
          db 21h,22h,23h,24h,25h
          db 31h,32h,33h,34h,35h
          db 41h,42h,43h,44h,45h
     m=4
     n=5
     bufs dw m dup(?)
data ends
code segment
     assume cs:code, ds:data, ss:stack
begin: mov ax, data
       mov ds, ax
       lea si, bufa          ;为si、di置循环初值
       lea di, bufs
       mov bx, 1             ;1—>bx，即1—>i
lopi: mov dx, 0              ;0—>dx，即0—>si
      mov cx, 1              ;1—>cx，即1—>j
lopj: mov al, [si]
      cbw
      add dx, ax
      inc si                 ;si增1，指向下一个aij
      inc cx                 ;j+1—>j
      cmp cx, n              ;若j<=n转lopj
      jbe lopj
      mov [di], dx           ;(dx)=si—>[di]
      mov ax, [di]
      call outax
      mov dl, 20h
      mov ah, 2
      int 21h
      add di, 2              ;di增2，指向bufs区中下一可用字单元
      inc bx                 ;i+1—>i
      cmp bx, m              ;若i<=m转lopi，计算下一行元素之和
      jbe lopi
      mov ax, 4c00h
      int 21h
;显示子程序，入口参数为ax
outax  proc far      ;显示AX的内容
       push bx       ;保护现场
       push cx
       push dx
       mov bx, ax
       mov ch, 04    ;数据位计数器
rot:  mov cl, 4      ;数据位数有4bit
      rol bx, cl     ;将最高4bit移
      mov al, bl     ;到bl最低4bit
      and al, 0fh    ;并取出送到al
      add al, 30h    ;转换为ASCII码
      cmp al, 3ah    ;al>'9'?
      jb print       ;是'0' ~ '9'转
      add al,07      ;是'A' ~ 'F'再加7
print:  mov ah, 02
        mov dl, al
        int 21h      ;显示al字符
        dec ch       ;四位已经显示完没?
        jnz rot      ;还没有，转ROT
        pop dx       ;恢复现场
        pop cx
        pop bx
        ret          ;返回
outax  endp          ;子程序结束

code ends
     end begin