outax.asm

我在汇编课上完成的一些作业（上机常见习题）和汇编课本上的几个例题

;入口参数：要显示的数存入ax中。
;出口参数：无。
;显示子程序，入口参数为ax
outax  proc far      ;显示AX的内容
       push bx       ;保护现场
       push cx
       push dx
       mov bx, ax
       mov ch, 04    ;数据位计数器
rot:  mov cl, 4      ;数据位数有4bit
      rol bx, cl     ;将最高4bit移
      mov al, bl     ;到bl最低4bit
      and al, 0fh    ;并取出送到al
      add al, 30h    ;转换为ASCII码
      cmp al, 3ah    ;al>'9'?
      jb print       ;是'0' ~ '9'转
      add al,07      ;是'A' ~ 'F'再加7
print:  mov ah, 02
        mov dl, al
        int 21h      ;显示al字符
        dec ch       ;四位已经显示完没?
        jnz rot      ;还没有，转ROT
        pop dx       ;恢复现场
        pop cx
        pop bx
        ret          ;返回
outax  endp          ;子程序结束


;显示子程序，入口参数为al
aldisp   proc
         push ax
         push dx
         push ax
         mov dl, al
         shr dl, 1
         shr dl, 1
         shr dl, 1
         shr dl, 1
         or dl, 30h
         cmp dl, 39h
         jbe aldisp1
         add dl, 7
aldisp1: mov ah, 2
         int 21h
         pop dx
         and dl, 0fh
         or dl, 30h
         cmp dl, 39h
         jbe aldisp2
         add dl, 7
aldisp2: mov ah, 2
         int 21h
         pop dx
         pop ax
         ret
aldisp endp

;回车、换行功能子程序
dpcrlf proc          ;具有默认属性的过程
       push ax       ;保护寄存器：顺序压入堆栈
       push dx
       mov dl, 0dh   ;回车控制字符为0dh
       mov ah, 2
       int 21h
       mov dl, 0ah   ;换行控制字符为0ah
       mov ah, 2
       int 21h
       pop dx        ;恢复寄存器：逆序弹出堆栈
       pop ax
       ret           ;子程序返回
dpcrlf endp          ;过程结束