conn.asp

信息超市现免费提供, 供学习研究之用. 目前无法完整建站

<%
'//////////////////////////////////////////////////////////
'数据库配制
'//////////////////////////////////////////////////////////

'资源库文件地址
Dim ResourceDBPath
	Select Case LCase(Request.ServerVariables("SERVER_NAME"))
	Case "www.35china.cn"
	ResourceDBPath = Ced_RootPath & "/IMarket/DataBase/Shanghai.mdb"
	Case "www.sz0512.com"
	ResourceDBPath = Ced_RootPath & "/demo/DataBase/Suzhou.mdb"
	Case Else
	ResourceDBPath = Ced_RootPath & "/DataBase/DataBase.mdb"
	End Select
Dim ConnStr
	ConnStr = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(ResourceDBPath)
Dim Conn
	Set Conn = Server.CreateObject("ADODB.Connection")
	Conn.Open ConnStr
	
Class Db_Class
	'////////////////////////////////////////////////////////////
	'///函数名：Close                                         ///
	'///作  用：关闭数据库连接                                ///
	'///参  数：无                                            ///
	'////////////////////////////////////////////////////////////
	Public Function Close()
		Conn.Close
		Set Conn = NoThing
	End Function
	
	'////////////////////////////////////////////////////////////
	'///函数名：DoCompact                                     ///
	'///作  用：压缩数据库                                    ///
	'///参  数：无                                            ///
	'////////////////////////////////////////////////////////////
	Public Function DoCompact()
	Dim I
	Dim TargetDB,ResourceDB
	Dim oJetEngine
	Dim Fso
	Const Jet_Conn_Partial = "Provider=Microsoft.Jet.OLEDB.4.0; Data source="
	Set oJetEngine = Server.CreateObject("JRO.JetEngine")
	Set Fso= Server.CreateObject(FsoObjectStr)
	'关闭数据库链接
	Conn.Close
	Set Conn=Nothing
	ResourceDB = Server.MapPath(ResourceDBPath)
	If Fso.FileExists(ResourceDB) Then
		'建立临时文件
		TargetDB=Server.MapPath(ResourceDBPath&".bak")
		If Fso.FileExists(TargetDB) Then
			Fso.DeleteFile(TargetDB)
		End If
		oJetEngine.CompactDatabase Jet_Conn_Partial&ResourceDB,Jet_Conn_Partial&TargetDB
		Fso.DeleteFile ResourceDB
		Fso.MoveFile TargetDB,ResourceDB
	End If
	Set Fso=Nothing
	Set oJetEngine=Nothing
	Response.Write("<script>alert(""<操作成功>\n数据库压缩完成!"");window.history.back();</script>")
	Response.End()
	End Function
	
	'////////////////////////////////////////////////////////////
	'///函数名：DoCompact                                     ///
	'///作  用：压缩数据库                                    ///
	'///参  数：无                                            ///
	'////////////////////////////////////////////////////////////
	Public Function DoBakDB()
	Dim I
	Dim TargetDB,ResourceDB
	Dim Fso
	Set Fso= Server.CreateObject(FsoObjectStr)
	'关闭数据库链接
	Conn.Close
	Set Conn=Nothing
	ResourceDB=Server.MapPath(ResourceDBPath)
	If Fso.FileExists(ResourceDB) Then
		'原数据库文是否存在
		If Fso.FileExists(ResourceDB) Then
			'建立原备份文件
			TargetDB=Server.MapPath(ResourceDBPath & Year(Now()) & Right("00" & Month(Now()),2) & Right("00" & Day(Now()),2) & ".asp")
			Fso.CopyFile ResourceDB,TargetDB,True
		End If
	End If

	Set Fso=Nothing
	Response.Write("<script>alert(""<操作成功>\n数据库备份完成!"");window.history.back();</script>")
	Response.End()
	End Function
End Class
%>