frmcgpod.frm

企业的进销存源码

Dim oCgPodhs As CgPodhs
Dim oCgPodh As CgPodh
Dim oCgPod As CgPod

Private Sub Command_Click(Index As Integer)
On Error GoTo Errorhandle

   Select Case Index
   Case CmdAdd
         AddRecord
   Case CmdDel
         Delrecord "CgPod"
   Case CmdDelh
         Delrecord "CgPodH"
   Case CmdSave
         SaveRecord
   End Select

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_AfterEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long)
On Error GoTo Errorhandle

   SetControlToFlex

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_BeforeEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long, Cancel As Boolean)
On Error GoTo Errorhandle
   
   If oCgPodh Is Nothing Then
      Cancel = True
   End If

   Select Case Flex(FlexCgPod).ColKey(Col)
   Case "CgPod_HWBMCODE"
         
   Case "CgPodQTY", "CgPodPRICE", "CgPodDDAT", "CgPodBZ"
         If oCgPod Is Nothing Then
            Cancel = True
         End If
         
         
         
   End Select

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Form_Load()
On Error GoTo Errorhandle
  
   Flex(FlexCgPod).Editable = flexEDKbdMouse
   
   Flex(FlexCgPodh).ColKey(1) = "CgPodHDOCNO"
   Flex(FlexCgPodh).ColKey(2) = "CgPodHDAT"
   Flex(FlexCgPodh).ColKey(3) = "CgPodH_KHCODE"
   
   Flex(FlexCgPod).ColKey(1) = "CgPod_HWBMCODE"
   Flex(FlexCgPod).ColKey(2) = "CgPod_HWBMMC"
   Flex(FlexCgPod).ColKey(3) = "CgPod_HWBMDW"
   Flex(FlexCgPod).ColKey(4) = "CgPodQTY"
   Flex(FlexCgPod).ColKey(5) = "CgPodPRICE"
   Flex(FlexCgPod).ColKey(6) = "CgPodAMT"
   Flex(FlexCgPod).ColKey(7) = "CgPodDDAT"
   Flex(FlexCgPod).ColKey(8) = "CgPodBZ"
   
   FillComboWithSql Me, Combo(CBxCgPod_KhCode), "SELECT KHCODE,KHNO FROM KHREC WHERE KHTYPE=2 ORDER BY KHCODE", "KHNO"
   
   LoadDataIntoGrid "CgPodH"
   
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub LoadDataIntoGrid(Index As String)
   Dim ItemStr As String
   Dim mCgPodh As CgPodh
   Dim mCgPod As CgPod
On Error GoTo Errorhandle
   
   Select Case UCase(Index)
   Case "CGPODH"
   
      Flex(FlexCgPodh).Rows = 1
      
      Set oCgPodhs = New CgPodhs
      oCgPodhs.Fillbydb
         
      For Each mCgPodh In oCgPodhs
         ItemStr = vbTab & mCgPodh.CgPodhDocno & vbTab & mCgPodh.CgPodhDat & vbTab & mCgPodh.Kh.KhCode
         Flex(FlexCgPodh).AddItem ItemStr
         Flex(FlexCgPodh).RowData(Flex(FlexCgPodh).Rows - 1) = mCgPodh.CgPodhKey
      Next
      If Flex(FlexCgPodh).Rows > 1 Then
         Flex(FlexCgPodh).Row = 1
         Set oCgPodh = oCgPodhs(CStr(Flex(FlexCgPodh).RowData(1)))
         SetValueToControl
      Else
         Set oCgPodh = Nothing
         Clearcontrol
      End If
   
   Case "CGPOD"
   
      Flex(FlexCgPod).Rows = 1
      Flex(FlexCgPod).AddItem ""
      
      oCgPodh.CgPods.Fillbydb oCgPodh
      
      For Each mCgPod In oCgPodh.CgPods
         ItemStr = vbTab & mCgPod.Hwbm.HwBmCode & vbTab & mCgPod.Hwbm.HwBmMc & vbTab & mCgPod.Hwbm.HwBmDw & vbTab & mCgPod.CgPodQty & vbTab & mCgPod.CgPodPrice & vbTab & mCgPod.CgPodAmt & vbTab & mCgPod.CgPodDDat & mCgPod.CgPodBz
         Flex(FlexCgPod).AddItem ItemStr, Flex(FlexCgPod).Rows - 1
         Flex(FlexCgPod).RowData(Flex(FlexCgPod).Rows - 2) = mCgPod.CgPodKey
      Next
      If Flex(FlexCgPod).Rows > 2 Then
         Flex(FlexCgPod).Row = 1
         Set oCgPod = oCgPodh.CgPods(CStr(Flex(FlexCgPod).RowData(1)))
      Else
         Set oCgPod = Nothing
      End If
   
   End Select

Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub AddRecord()
On Error GoTo Errorhandle

   Set oCgPodh = New CgPodh
   Set oCgPod = Nothing
   Clearcontrol
   Text(TxtCgPodDocno).SetFocus
   
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Clearcontrol()
On Error GoTo Errorhandle

   Text(TxtCgPodDocno).Text = ""
   Text(DtpCgPodDat).Text = ""
   Combo(CBxCgPod_KhCode).Text = ""
   
   Flex(FlexCgPod).Rows = 1
   Flex(FlexCgPod).AddItem ""
   
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub SaveRecord()
On Error GoTo Errorhandle
    
   SetValueToObject

   If oCgPodh.CgPodhId = -1 Then
      oCgPodhs.Add oCgPodh
      ChgGrid "ADD"
   Else
      oCgPodh.Save
      ChgGrid "CHG"
   End If
   
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub SetValueToObject()
   Dim mCgPod As CgPod
   Dim I As Integer
On Error GoTo Errorhandle

   oCgPodh.CgPodhDocno = Trim(Text(TxtCgPodDocno).Text)
   oCgPodh.CgPodhDat = Dtp(DtpCgPodDat).Value
   oCgPodh.CgPodh_KhCode = Trim(Combo(CBxCgPod_KhCode).Text)
   
   For I = 1 To Flex(FlexCgPod).Rows - 2
      Set mCgPod = oCgPodh.CgPods(CStr(Flex(FlexCgPod).RowData(I)))
      mCgPod.CgPod_HwBmCode = Trim(Flex(FlexCgPod).TextMatrix(I, Flex(FlexCgPod).ColIndex("CgPod_HWBMCODE")))
      mCgPod.CgPodQty = Val(Flex(FlexCgPod).TextMatrix(I, Flex(FlexCgPod).ColIndex("CgPodQTY")))
      mCgPod.CgPodPrice = Val(Flex(FlexCgPod).TextMatrix(I, Flex(FlexCgPod).ColIndex("CgPodPRICE")))
      mCgPod.CgPodDDat = Trim(Flex(FlexCgPod).TextMatrix(I, Flex(FlexCgPod).ColIndex("CgPodDDAT")))
      mCgPod.CgPodBz = Trim(Flex(FlexCgPod).TextMatrix(I, Flex(FlexCgPod).ColIndex("CgPodBZ")))
   Next
   
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub ChgGrid(RecordName As String)
   Dim ItemStr As String
On Error GoTo Errorhandle
   
   If RecordName = "ADD" Then
      ItemStr = vbTab & oCgPodh.CgPodhDocno & vbTab & oCgPodh.CgPodhDat & vbTab & oCgPodh.Kh.KhCode
      Flex(FlexCgPodh).AddItem ItemStr
      Flex(FlexCgPodh).RowData(Flex(FlexCgPodh).Rows - 1) = oCgPodh.CgPodhKey
      Flex(FlexCgPodh).Row = Flex(FlexCgPodh).Rows - 1
   Else
      Flex(FlexCgPodh).TextMatrix(Flex(FlexCgPodh).Row, Flex(FlexCgPodh).ColIndex("CgPodHDOCNO")) = oCgPodh.CgPodhDocno
      Flex(FlexCgPodh).TextMatrix(Flex(FlexCgPodh).Row, Flex(FlexCgPodh).ColIndex("CgPodHDAT")) = oCgPodh.CgPodhDat
      Flex(FlexCgPodh).TextMatrix(Flex(FlexCgPodh).Row, Flex(FlexCgPodh).ColIndex("CgPodH_KHCODE")) = oCgPodh.Kh.KhCode
   End If

Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Delrecord(Index As String)
On Error GoTo Errorhandle


   Select Case UCase(Index)
   Case "CGPODH"
   
         If Flex(FlexCgPodh).Rows = 1 Then
            Exit Sub
         End If
      
         If MsgBox("您真的要删除当前整张单据吗？", vbYesNo) = vbYes Then
            oCgPodhs.Remove CStr(oCgPodh.CgPodhKey)
            Flex(FlexCgPodh).RemoveItem Flex(FlexCgPodh).Row
            If Flex(FlexCgPodh).Rows = 1 Then
               Set oCgPod = Nothing
               Set oCgPodh = Nothing
               Clearcontrol
            Else
               Set oCgPodh = oCgPodhs(CStr(Flex(FlexCgPodh).RowData(Flex(FlexCgPodh).Row)))
               SetValueToControl
            End If
         End If
   
   
   Case "CGPOD"
   
         If Flex(FlexCgPod).Row = Flex(FlexCgPod).Rows - 1 Then
            Exit Sub
         End If
      
         If MsgBox("您真的要删除单据当前行吗？", vbYesNo) = vbYes Then
            oCgPodh.CgPods.Remove CStr(oCgPod.CgPodKey)
            Flex(FlexCgPod).RemoveItem Flex(FlexCgPod).Row
            If Flex(FlexCgPod).Rows = 2 Then
               Set oCgPod = Nothing
               Flex(FlexCgPodh).RemoveItem Flex(FlexCgPodh).Row
               If Flex(FlexCgPodh).Rows = 1 Then
                  Set oCgPodh = Nothing
               Else
                  Set oCgPodh = oCgPodhs(CStr(Flex(FlexCgPodh).RowData(Flex(FlexCgPodh).Row)))
                  SetValueToControl
               End If
            Else
               If Flex(FlexCgPod).Row = Flex(FlexCgPod).Rows - 1 Then
                  Flex(FlexCgPod).Row = Flex(FlexCgPod).Row - 1
               End If
               Set oCgPod = oCgPodh.CgPods(CStr(Flex(FlexCgPod).RowData(Flex(FlexCgPod).Row)))
            End If
         End If
      
   End Select
   
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Flex_RowColChange(Index As Integer)
On Error GoTo Errorhandle

   Select Case Index
   Case FlexCgPodh
   
         If Flex(FlexCgPodh).Rows > 1 Then
            Set oCgPodh = oCgPodhs(CStr(Flex(FlexCgPodh).RowData(Flex(FlexCgPodh).Row)))
            SetValueToControl
         Else
            Set oCgPodh = Nothing
            Clearcontrol
         End If
   
   Case FlexCgPod
   
         If Flex(FlexCgPod).Row <> Flex(FlexCgPod).Rows - 1 Then
            Set oCgPod = oCgPodh.CgPods(CStr(Flex(FlexCgPod).RowData(Flex(FlexCgPod).Row)))
         Else
            Set oCgPod = Nothing
         End If
   
   End Select
   
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub SetValueToControl()
On Error GoTo Errorhandle

   Text(TxtCgPodDocno).Text = oCgPodh.CgPodhDocno
   Dtp(DtpCgPodDat).Value = oCgPodh.CgPodhDat
   Combo(CBxCgPod_KhCode).Text = oCgPodh.Kh.KhCode
   
   LoadDataIntoGrid "CgPod"
   
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Form_Unload(Cancel As Integer)
On Error GoTo Errorhandle

   Set oCgPodhs = Nothing
   Set oCgPodh = Nothing
   Set oCgPod = Nothing
   
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub SetControlToFlex()
   Dim mCurCol As Integer
   Dim mCurRow As Integer
On Error GoTo Errorhandle

   
   mCurRow = Flex(FlexCgPod).Row
   mCurCol = Flex(FlexCgPod).Col
   
   Select Case Flex(FlexCgPod).ColKey(Flex(FlexCgPod).Col)
   Case "CgPod_HWBMCODE"
         If oCgPod Is Nothing Then
            AddNewRecord
         Else
            oCgPod.CgPod_HwBmCode = Trim(Flex(FlexCgPod).TextMatrix(mCurRow, mCurCol))
            Flex(FlexCgPod).TextMatrix(mCurRow, Flex(FlexCgPod).ColIndex("CgPod_HWBMMC")) = oCgPod.Hwbm.HwBmMc
            Flex(FlexCgPod).TextMatrix(mCurRow, Flex(FlexCgPod).ColIndex("CgPod_HWBMDW")) = oCgPod.Hwbm.HwBmDw
         End If
   
   Case "CgPodQTY"
         If Not oCgPod Is Nothing Then
            oCgPod.CgPodQty = Val(Flex(FlexCgPod).TextMatrix(Flex(FlexCgPod).Row, mCurCol))
            Flex(FlexCgPod).TextMatrix(Flex(FlexCgPod).Row, Flex(FlexCgPod).ColIndex("CgPodAMT")) = oCgPod.CgPodAmt
         End If
   
   Case "CgPodPRICE"
         If Not oCgPod Is Nothing Then
            oCgPod.CgPodPrice = Val(Flex(FlexCgPod).TextMatrix(Flex(FlexCgPod).Row, mCurCol))
            Flex(FlexCgPod).TextMatrix(Flex(FlexCgPod).Row, Flex(FlexCgPod).ColIndex("CgPodAMT")) = oCgPod.CgPodAmt
         End If
   
   Case "CgPodDAT"
         If Not oCgPod Is Nothing Then
            oCgPod.CgPodDDat = Trim(Flex(FlexCgPod).TextMatrix(Flex(FlexCgPod).Row, mCurCol))
         End If
   
   Case "CgPodBZ"
         If Not oCgPod Is Nothing Then
            oCgPod.CgPodBz = Trim(Flex(FlexCgPod).TextMatrix(Flex(FlexCgPod).Row, mCurCol))
         End If
   
   End Select


Exit Sub
Errorhandle:
   'Flex(FlexCgPod).TextMatrix(mCurRow, mCurCol) = mCurColOldValue
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub AddNewRecord()
   Dim mCurRow As Integer
On Error GoTo Errorhandle

   mCurRow = Flex(FlexCgPod).Row

   If Trim(Flex(FlexCgPod).TextMatrix(mCurRow, Flex(FlexCgPod).Col)) <> "" Then
      Set oCgPod = New CgPod
      Set oCgPod.CgPodh = oCgPodh
      oCgPod.CgPod_HwBmCode = Trim(Flex(FlexCgPod).TextMatrix(mCurRow, Flex(FlexCgPod).Col))
      oCgPodh.CgPods.Add oCgPod, 0
      Flex(FlexCgPod).TextMatrix(mCurRow, Flex(FlexCgPod).ColIndex("CgPod_HWBMMC")) = oCgPod.Hwbm.HwBmMc
      Flex(FlexCgPod).TextMatrix(mCurRow, Flex(FlexCgPod).ColIndex("CgPod_HWBMDW")) = oCgPod.Hwbm.HwBmDw
      Flex(FlexCgPod).RowData(Flex(FlexCgPod).Rows - 1) = oCgPod.CgPodKey
      Flex(FlexCgPod).AddItem ""
   End If

Exit Sub
Errorhandle:
   Set oCgPod = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Form_Resize()
On Error GoTo Errorhandle
   Resize_ALL Me
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub