📄 6-8.html
字号:
<HTML>
<HEAD>
<TITLE>联机阅读</TITLE>
</HEAD>
<SCRIPT LANGUAGE="VBS">
<!--
'定义公用变量
'tid为计时器变量
dim tid
'tid_autoread变量表示自动阅读的计时器变量
dim tid_autoread
'now0表示闹钟自动计时的开始时间
dim now0
'用户选择的闹钟的时间长度
dim selectedtime
'以下变量与自动阅读有关
'scrolldelay表示自动阅读的浏览速度
'lasttop表示上一次纵向滚动条滚动的位置,它用来判断滚动条是否停滚了
'lastleft表示上一次横向滚动条滚动的位置,它用来判断滚动条是否停滚了
dim scrolldelay,lasttop,lastleft
scrolldelay=100
lasttop=0
lastleft=0
'闹钟计时程序
sub clockon
'得到当时的时间
now1=Time()
'计算与起始时间的间隔
dif=datediff("s",now0,now1)
'如果此间隔大于闹钟的定时间隔
if (dif>selectedtime) then
'则关闭闹钟
clockoff
'显示提示信息
msgbox "阅读时间到!"
'frm1.t1.value=""
else
'否则,显示当前时间
'frm1.t1.value=cstr(now1)
'启动计时器,间隔为1秒,符合正常的时钟标准
tid=setTimeout("clockon",1000)
end if
end sub
'关闭闹钟
sub clockoff
clearTimeout(tid)
end sub
'改变阅读文章的背景
sub changebackground(i)
'根据不同的背景号来改变背景
select case i
case 1
'建立对象引用,这个对象引用指向显示阅读文章的窗口frame3
set fr=parent.frames("FRAME3")
'改变阅读窗口的前景色和背景图案
fr.document.fgColor="#ffee00"
case 2
'建立对象引用,这个对象引用指向显示阅读文章的窗口frame3
set fr=parent.frames("FRAME3")
'改变阅读窗口的背景色和前景色
fr.document.fgColor="#ffff00"
fr.document.bgColor="#000000"
case 3
'建立对象引用,这个对象引用指向显示阅读文章的窗口frame3
set fr=parent.frames("FRAME3")
'改变阅读窗口的前景色和背景图案
fr.document.fgColor="#0000ff"
case 4
'建立对象引用,这个对象引用指向显示阅读文章的窗口frame3
set fr=parent.frames("FRAME3")
'改变阅读窗口的前景色和背景图案
fr.document.fgColor="#00ff00"
end select
end sub
'改变文章内容
sub changecontent(i)
'生成文章名
urls="SHE00"&(i+1)&".html"
'建立对象引用,这个对象引用指向显示阅读文章的窗口frame3
set fr=parent.frames("FRAME3")
'改变该窗口的链接属性,指向新的文章链接
fr.location.href=urls
'将背景选择回0,即默认的选择
frm1.r1(0).checked=true
end sub
'当用户选择另一本书时改变书的标题
sub changetitle(str)
'建立对象引用,这个对象引用指向显示图书标题的窗口frame1
set tmp=parent.frames("frame1")
'建立对象引用,这个对象引用指向frame1的boottitle对象
set tmp2=tmp.document.all("booktitle")
'将其内容改为新的字串
tmp2.innerText=str
'背景选择回0
frm1.r1(0).checked=true
'文章选择回0
frm1.sel2.selectedIndex =0
end sub
'点击自动阅读键
sub but2_onclick
'切换开启自动阅读和取消自动阅读的标题
if frm1.but2.value ="自动阅读" then
'建立对象引用,指向frame3
set tmp=Parent.frames("frame3")
frm1.but2.value="取消自动阅读"
'开启自动阅读过程
tid_autoread=setinterval("scrollpage",scrolldelay)
else
frm1.but2.value="自动阅读"
'停止自动阅读过程
clearinterval(tid_autoread)
'位置回0
lasttop=0
lastleft=0
end if
end sub
'滚动右侧的阅读文章,产生自动阅读的效果
sub scrollpage
'建立对象,指向frame3
set tmp=Parent.frames("frame3")
'采用scrollto方法将滚动条滚动到指定的地点
'先纵向滚动,滚动步长为1.5
'if frm1.t1.value="" then
' k=1.5
'else
' k=-1.5
'end if
tmp.scrollto tmp.document.body.scrollleft,tmp.document.body.scrolltop+k
'由于当滚动到顶部时,浏览器自动不再增加scrollleft或scroolltop
'判断是否横向滚动到头
if tmp.document.body.scrollleft<=lastleft then
'将lastleft清零
lastleft=0
'将滚动条下移并横向回0
tmp.scrollto 0,tmp.document.body.scrolltop+10
'判断是否纵向滚动到头
if tmp.document.body.scrolltop<=lasttop then
'如果是,点击button2,关闭自动阅读功能
but2_onclick
else
'如果不是,纪录此次滚动位置
lasttop=tmp.document.body.scrolltop
end if
else
'如果横向没有滚动到头,记下此次滚动位置
lastleft=tmp.document.body.scrollleft
end if
end sub
-->
</SCRIPT>
<BODY BACKGROUND="back083.gif">
<FORM NAME="frm1">
<font face="楷体_GB2312" color=blue><strong>
<center>
<h1>
射雕英雄传
</h1>
<center>
选择章节
<SELECT NAME="sel2" ONCHANGE="changecontent frm1.sel2.selectedIndex">
<OPTION SELECTED>第一章
<OPTION>第二章
<OPTION>第三章
<OPTION>第四章
</SELECT><br><br>
选择适合您的文档样式<br>
<INPUT TYPE=radio NAME="r1" VALUE=1 CHECKED ONFOCUS="changebackground 1">古典型
<INPUT TYPE=radio NAME="r1" VALUE=2
ONFOCUS="changebackground(2)">醒目型<br>
<INPUT TYPE=radio NAME="r1" VALUE=3
ONFOCUS="changebackground(3)">云雾型
<INPUT TYPE=radio NAME="r1" VALUE=4
ONFOCUS="changebackground(4)">热烈型<br>
<br><br>
自动浏览功能：
<br>
<SELECT NAME="sel4" ONCHANGE="scrolldelay=frm1.sel4.value">
<OPTION SELECTED VALUE="100">中速
<OPTION VALUE="30">快速
<OPTION VALUE="200">慢速
</SELECT>
<INPUT NAME="but2" TYPE=button VALUE="自动阅读">
</strong></font>
</FORM>
</BODY>
</HTML>⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -