startup.s

研究了两周的IAP

 
 ;GBLA EN_CRP   ;GBLA伪指令是定义一个全局变量，初始值为0
                ;EN_CRP变量是用来使能flash加密的。


;/************************************************************
;功能：定义堆栈的大小(以字为单位)
;说明：
;************************************************************/
SVC_STACK_LEGTH         EQU         0
FIQ_STACK_LEGTH         EQU         0
IRQ_STACK_LEGTH         EQU         256       ;256 by jhl 20070113
ABT_STACK_LEGTH         EQU         0
UND_STACK_LEGTH         EQU         0


;NoInt       EQU 0x80

;USR32Mode   EQU 0x10
;SVC32Mode   EQU 0x13
;SYS32Mode   EQU 0x1f
;IRQ32Mode   EQU 0x12
;FIQ32Mode   EQU 0x11

    IMPORT __use_no_semihosting_swi

;The imported labels
;引入的外部标号在这声明
    IMPORT  FIQ_Exception                   ;Fast interrupt exceptions handler 快速中断异常处理程序
    IMPORT  __main                          ;The entry point to the main function C语言主程序入口 
    IMPORT  TargetResetInit                 ;initialize the target board 目标板基本初始化

;The emported labels
;给外部使用的标号在这声明
    EXPORT  bottom_of_heap
    EXPORT  StackUsr
    
    EXPORT  Reset
    EXPORT __user_initial_stackheap
    




;/************************************************************
;功能：中断向量表 interrupt vectors
;说明：这与51系列单片机的中断向量表很相似。外围设备用到的中断有
;irq和fiq
;************************************************************/
    CODE32
    AREA    vectors,CODE,READONLY
        ENTRY
Reset
        LDR     PC, ResetAddr
        LDR     PC, UndefinedAddr
        LDR     PC, SWI_Addr
        LDR     PC, PrefetchAddr
        LDR     PC, DataAbortAddr
        DCD     0xb9205f80
        LDR     PC, [PC, #-0xff0]   ;irq
        LDR     PC, FIQ_Addr        ;fiq

ResetAddr           DCD     ResetInit
UndefinedAddr       DCD     Undefined
SWI_Addr            DCD     SoftwareInterrupt
PrefetchAddr        DCD     PrefetchAbort
DataAbortAddr       DCD     DataAbort
Nouse               DCD     0
IRQ_Addr            DCD     0
FIQ_Addr            DCD     FIQ_Handler


;未定义指令
Undefined
        B       Undefined

;软中断
SoftwareInterrupt			
        B       SoftwareInterrupt	

;取指令中止
PrefetchAbort
        B       PrefetchAbort
        
;取数据中止
DataAbort
        B       DataAbort
        
;快速中断
FIQ_Handler
        STMFD   SP!, {R0-R3, LR}
        BL      FIQ_Exception
        LDMFD   SP!, {R0-R3, LR}
        SUBS    PC,  LR,  #4
 
        
;/************************************************************
;功能:初始化堆栈 	
;说明:
;************************************************************/
InitStack    
        MOV     R0, LR
;Build the SVC stack
;设置管理模式堆栈
        MSR     CPSR_c, #0xd3		
        LDR     SP, StackSvc	
;Build the IRQ stack	
;设置中断模式堆栈
        MSR     CPSR_c, #0xd2
        LDR     SP, StackIrq
;Build the FIQ stack
;设置快速中断模式堆栈
        MSR     CPSR_c, #0xd1
        LDR     SP, StackFiq
;Build the DATAABORT stack
;设置中止模式堆栈
        MSR     CPSR_c, #0xd7
        LDR     SP, StackAbt
;Build the UDF stack
;设置未定义模式堆栈
        MSR     CPSR_c, #0xdb
        LDR     SP, StackUnd
;Build the SYS stack
;设置系统模式堆栈
        ;MSR     CPSR_c, #0xdf
        MSR     CPSR_c, #0x5f;//使能irq中断
        LDR     SP, =StackUsr-32;//by jhl

        MOV     PC, R0


;/************************************************************
;功能:复位初始化 	
;说明: 	
;************************************************************/
ResetInit 
        BL      InitStack               ;初始化堆栈 Initialize the stack
        BL      TargetResetInit         ;目标板基本初始化 Initialize the target board
                                        ;跳转到c语言入口 Jump to the entry point of C program
        B       __main
        
        
 

;/*********************************************************************************************************
;** unction name 	函数名称: 	__user_initial_stackheap
;** Descriptions 	功能描述: 	Initial the function library stacks and heaps, can not deleted!   库函数初始化堆和栈，不能删除
;** input parameters 	输　入:   	reference by function library 参考库函数手册
;** Returned value   	输　出 :  	reference by function library 参考库函数手册
;** Used global variables 全局变量: 	None 无
;** Calling modules 	调用模块: 	None 无
;** 
;** Created by 		作　者: 	Chenmingji 陈明计
;** Created Date 	日　期: 	2004/02/02 2004年2月2日
;**-------------------------------------------------------------------------------------------------------
;** Modified by 	
;** Modified date 	
;**-------------------------------------------------------------------------------------------------------
;********************************************************************************************************/
__user_initial_stackheap    
    LDR   r0,=bottom_of_heap
;    LDR   r1,=StackUsr
    MOV   pc,lr
 


;/************************************************************
;功能：堆栈的起始地址(栈顶地址)
;说明：
;************************************************************/
StackSvc           DCD     SvcStackSpace + (SVC_STACK_LEGTH - 1)* 4
StackIrq           DCD     IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4
StackFiq           DCD     FiqStackSpace + (FIQ_STACK_LEGTH - 1)* 4
StackAbt           DCD     AbtStackSpace + (ABT_STACK_LEGTH - 1)* 4
StackUnd           DCD     UndtStackSpace + (UND_STACK_LEGTH - 1)* 4


;/************************************************************
;功能：芯片加密 Code Read Protection (CRP)
;说明：0x1FC (User flash sector 0) with value 0x87654321
;************************************************************/
    IF :DEF: EN_CRP
        IF  . >= 0x1fc
            INFO    1,"\n Please delete some source before this line."
        ENDIF

        WHILE . < 0x1fc
        NOP
        WEND

        DCD     0x87654321 ;/*当此数为0x87654321时，用户程序被保护 */
    ENDIF


;/************************************************************
;功能：分配堆栈空间 MyStacks
;说明：
;************************************************************/   
        AREA    MyStacks, DATA, NOINIT, ALIGN=2
SvcStackSpace      SPACE   SVC_STACK_LEGTH * 4  ;管理模式堆栈空间
IrqStackSpace      SPACE   IRQ_STACK_LEGTH * 4  ;中断模式堆栈空间
FiqStackSpace      SPACE   FIQ_STACK_LEGTH * 4  ;快速中断模式堆栈空间
AbtStackSpace      SPACE   ABT_STACK_LEGTH * 4  ;中止义模式堆栈空间
UndtStackSpace     SPACE   UND_STACK_LEGTH * 4  ;未定义模式堆栈


;/************************************************************
;功能：Heap
;说明：
;************************************************************/
        AREA    Heap, DATA, NOINIT
bottom_of_heap    SPACE   1


;/************************************************************
;功能：Stacks
;说明：
;************************************************************/
        AREA    Stacks, DATA, NOINIT
StackUsr

    END
;/*********************************************************************************************************
;**                            End Of File
;********************************************************************************************************/