sort.asp

blue space 蓝色空间下载系统精简版---大家分享

<%@LANGUAGE="VBSCRIPT" CODEPAGE="936"%>
<!--#include file="../inc/oConn.asp" -->
<!--#include file="../inc/HeadDH.asp" -->
<!--#include file="Function.asp" -->
<%
Call PrintHead("蓝色空间 软件下载 分类列表")
Call DisplayPage()
Call PrintFoot()

Sub DisplayPage()
	Dim strHtml
	strHtml = PrintListTable()&ResponseTable(1)&UserAddress()
	strHtml = strHtml & "<TABLE align='center' cellspacing='2' cellpadding='1'>"&vbCrLf
	strHtml = strHtml & "<TR>"&vbCrLf
	strHtml = strHtml & "<TD valign='top'>"
	strHtml = strHtml & SearchForm()&ResponseTable(1)
	strHtml = strHtml & AllHotList()&ResponseTable(1)
	strHtml = strHtml & "</TD>"&vbCrLf
	strHtml = strHtml & "<TD valign='top'>"
	strHtml = strHtml & IndexClassList()
	strHtml = strHtml & "</TD>"&vbCrLf
	strHtml = strHtml & "</TR>"&vbCrLf
	strHtml = strHtml & "</TABLE>"
	Call CloseConn()
	Print strHtml
End Sub

Function UserAddress()
	Dim strHtml,strTmp
	strTmp = "软件分类"
	strHtml = "<table width='"&MaxTableWidth&"' bgcolor='#ffffff' align='center' cellspacing='0'  cellpadding='5'>"&vbCrLf
	strHtml = strHtml & "<tr><td>"&vbCrLf
	strHtml = strHtml & "你的位置："&DownIndexUrl&" 列表"&vbCrLf
	strHtml = strHtml & "</td></tr></table>"&vbCrLf

	UserAddress = strHtml
End Function

Function IndexClassList()
	Dim objRs,strHtml
	strHtml = "<!--软件分类列表Start-->"&vbCrLf
	strHtml = strHtml & "<TABLE align='center' width='"&ListTableWidth&"' cellspacing='1' cellpadding='4'  style=""background:#cccccc"">"&vbCrLf
	strHtml = strHtml & "<tr class='thetitle1'><td colspan='2' style=""border:1 solid #ffffff"">软件分类</td></tr>"
	strSQL = "Select SoftBigClassID,SoftBigClassName From "&BigClassTable&""
	Set objRs = oConn.Execute(strSQL)
	If Not objRs.Eof Then
		Do While Not objRs.Eof
			strHtml = strHtml & "<TR style=""background:#ffffff"">"&vbCrLf
			strHtml = strHtml & "<TD align='center'><a href='SoftListB.asp?SortID="&objRs(0)&"'>"&objRs(1)&"</a></TD>"&vbCrLf
			strHtml = strHtml & "<TD width='490' style=""line-height:180%"">"&SubClassList(objRs(0))&"</TD>"&vbCrLf
			strHtml = strHtml & "</TR>"&vbCrLf
			objRs.MoveNext
			If objRs.Eof Then Exit Do
		LOOP
	End If
	Set objRs = Nothing
	strHtml = strHtml & "</TABLE>"&vbCrLf
	strHtml = strHtml & "<!--软件分类列表End-->"&vbCrLf

	IndexClassList = strHtml
End Function

Function SubClassList(fClassID)
	Dim objRs,strHtml,i
	strSQL = "Select SoftClassID,SoftClassSmallName From "&ClassTable&" Where SoftBigClassID="&fClassID&""
	Set objRs = oConn.Execute(strSQL)
	If Not objRs.Eof Then
		i = 1
		Do While Not objRs.Eof
			strHtml = strHtml & "&nbsp;&nbsp;&nbsp;&nbsp;<a href='SoftListS.asp?SortID="&objRs(0)&"'>"&objRs(1)&"</a>"&vbCrLf
			objRs.MoveNext
			If objRs.Eof Then Exit Do
			i = i + 1
			If i>6 Then
				i = 1
				strHtml = strHtml & "<br>"
			End If
		LOOP
	End If
	Set objRs = Nothing

	SubClassList = strHtml
End Function
%>