guisoundmanagermain.pas

来自「一整套声音录制控件」· PAS 代码 · 共 88 行

unit guiSoundManagerMain;

interface

uses
  guiAudioDevice,
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, WaveMixer, ExtCtrls, ComCtrls;

type
  TfrmSoundManagerMain = class(TForm)
    AudioMixer1: TAudioMixer;
    TreeView1: TTreeView;
    procedure FormShow(Sender: TObject);
    procedure TreeView1Change(Sender: TObject; Node: TTreeNode);
    procedure FormCreate(Sender: TObject);
    procedure TreeView1Deletion(Sender: TObject; Node: TTreeNode);
  private
    FSelectedDevice : TfrmAudioDevice;
  public
    { Public declarations }
  end;

var
  frmSoundManagerMain: TfrmSoundManagerMain;

implementation

{$R *.dfm}

procedure TfrmSoundManagerMain.FormCreate(Sender: TObject);
var
  I,J:Integer;
  frmDevice:TfrmAudioDevice;
  trnDevice:TTreeNode;
begin
  for I:=0 to AudioMixer1.MixerCount-1 do
  begin
    AudioMixer1.MixerID := I;
    trnDevice := TreeView1.Items.Add(
      TreeView1.TopItem, AudioMixer1.MixerName
    );
    for J:=0 to AudioMixer1.DestinationCount-1 do
    begin
      AudioMixer1.DestinationID := J;
      frmDevice := TfrmAudioDevice.CreateDevice(Self, Self, I, J);
      TreeView1.Items.AddChildObject(
        trnDevice, AudioMixer1.DestinationName, frmDevice
      );
    end;
    trnDevice.Expand(False);
  end;
end;

procedure TfrmSoundManagerMain.FormShow(Sender: TObject);
begin
  if (TreeView1.Selected = nil) and (TreeView1.TopItem.Count > 0) then
      TreeView1.Selected := TreeView1.TopItem.Item[0];
end;

procedure TfrmSoundManagerMain.TreeView1Change(Sender: TObject;
  Node: TTreeNode);
begin
  if FSelectedDevice <> Nil then
  begin
    FSelectedDevice.Hide;
    FSelectedDevice := Nil;
  end;
  if Node.Data <> Nil then
  begin
    FSelectedDevice := Node.Data;
    FSelectedDevice.Show;
    FSelectedDevice.Update;
  end;
end;

procedure TfrmSoundManagerMain.TreeView1Deletion(Sender: TObject;
  Node: TTreeNode);
begin
  if Assigned(Node.Data) then
  begin
    TfrmAudioDevice(Node.Data).Free;
    Node.Data := nil;
  end;
end;

end.