📄 dysend.asp
字号:
<%
'=========================================================
' 『动感在线』版权所有(C) Donggan.Net
' 您可以自由应用本程序于合法的个人或商业行为。
' 您必须保留版权信息。
'=========================================================
' Version:1.3
' Date: 2003-01-10
' Script Written by xubin
'=========================================================
' Copyright (C) 1999-2002 Donggan.Net. All rights reserved.
' Web: http://www.Donggan.net
' Email: webmaster@Donggan.net,webmaster@mail.Donggan.net
'=========================================================
%>
<!--#Include File="conn.asp" -->
<!--#Include File="procedure.asp" -->
<!--#Include File="Language.asp" -->
<%
Dim td,Tomail,ranid
'Call loaderror()
Call showwebdata()
Call Language_var(Language,"dysend")
%>
<html>
<head>
<title><%=webname%> | <%=Language_dysend(0)%></title>
<meta http-equiv="Content-Type" content="text/html; charSet=<%=Language_charSet%>">
<link rel="stylesheet" href="images/styles.css" type="text/css">
</head>
<body leftmargin="0" Topmargin="0" marginwidth="0" marginheight="0" background="images/greystrip.gIf">
<!--#Include File="head.asp" --><br>
<%
'获得订阅/退订邮件
td = Request.Form("td")
Tomail=trim(Request.Form("fsemail"))
'判断邮件地址时候正确
If IsValidEmail(Tomail)<>TRUE Then
errortext=Language_dysend(5)
Call showerror1()
End If
'判断是否为退订,如果是则跳转到tuiding.asp
If td<>"" Then
Response.Cookies("Donggan")("mailtuiding")=Tomail
Response.Redirect "tuiding.asp"
Response.End
End If
'判断邮件是否已经订阅
If IsdyEmail(Tomail) Then
errortext=Language_dysend(6)
Call showerror1()
End If
'获得发送确认信基本信息
Set rs=Server.Createobject("adodb.recordset")
sql="select * from Management "
rs.open sql,conn,1,3
WebName = rs("WebName")
emailbody = rs("qrx")
SMTPHost = rs("SMTPHost")
FromMail = rs("FromMail")
FromName = rs("FromName")
SMTPUser = rs("SMTPUser")
SMTPPass = rs("SMTPPass")
Mailzj = rs("SetMailzj")
CodeBit = rs("CodeBit")
rs.close
'根据当前网址,生成确认地址
addr0 = Request.Servervariables("server_name")
addr1 = Request.Servervariables("url")
addr1=replace(addr1,"dysend.asp","check.asp")
addr="http://"&addr0&addr1
'如果当前的邮件不在临时数据库中,则生成确认码.否则使用临时库中的随机码
If IsqrEmail(Tomail)=FALSE Then
savemail=TRUE
Ranid=makerndid(CodeBit)
'如果随机码重复,则再次生成一个新的随机码
Do While IsqrRanid(Ranid)
Ranid=makerndid(CodeBit)
Loop
End If
'确认连接
qylink=addr&"?ranid="&ranid
MailFormat="html"
emailbody=emailbody &"<font size=2>＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝<br>" & vbcrlf
emailbody=emailbody &Language_dysend(7)&"<br>" & vbcrlf
emailbody=emailbody &"<a href="&qylink&">"&Language_dysend(8)&"</a><br><br>" & vbcrlf
emailbody=emailbody &qylink& vbcrlf &"<br>"&Language_dysend(9)&"<br>" & vbcrlf
emailbody=emailbody &"＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝<br>" & vbcrlf
emailbody=emailbody &Language_dysend(10)&"<br>" & vbcrlf
emailbody=emailbody &"＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝</font><br>" & vbcrlf
mailbody=emailbody
mailSubject = Language_dysend(11)
dengji=1
%>
<!--#Include File="zujian.asp" -->
<%
Call sendmail()
'判断发送邮件是否出错误
If ErrStr <> "" Then %>
<FONT COLOR="#FF0000"><B><%=Language_dysend(1)%><i><% = ErrStr %></I>.</B> <br><%=Language_dysend(2)%></FONT>
<%Else
'发送成功
'将临时邮件地址加入数据库
If savemail=TRUE Then
'如果还没有加入临时数据库则填加新邮件
Set rs=Server.CreateObject("Adodb.RecordSet")
sql="select * from tempmail where (id is null)"
rs.open sql,conn,1,3
rs.addnew
rs("email")=Tomail
rs("ranid")=ranid
rs.update
rs.close
End If
'显示成功发送信息
Set rs=conn.execute("select dy from Management")
%>
<center><FORM method="post" action="<%=weburl%>" target="_parent">
<table border="1" cellspacing="0" cellpadding="0" width="550" bordercolor="#7C96B8" bordercolordark="#FFFFFF" height="132" >
<tr>
<td height="20" colspan="2" bgcolor="#7C96B8" background="images/mmTo.gIf" width="546"><DIV style="FILTER: dropshadow(color=#FFFFFF, offx=1, offy=1, positive=1); WIDTH: 100%; CURSOR: hAND; POSITION: relative">
<p align="center"><font color="#336699"><%=Language_dysend(3)%></font></div></td>
</tr>
<tr>
<td height="84" colspan="2" width="546"><%=rs("dy")%></td>
</tr>
<tr>
<td colspan="2" align="center" bgcolor="#7C96B8" height="20" background="images/mmTo.gIf" width="546"> <input name="bank" type="Submit" value="<%=Language_dysend(4)%>" class="Tips_bo">
</td>
</tr>
</table>
</FORM>
</center>
<%End If
'关闭销毁对象
Set rs=nothing
conn.close
Set conn=nothing
%>
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -