llqdaima.txt

制作浏览器的源代码

Private Sub Combo1_Click()
WebBrowser1.Navigate Combo1.Text
End Sub

Private Sub Combo1_KeyDown(KeyCode As Integer, Shift As Integer)
Dim I As Long
Dim existed As Boolean
If KeyCode = 13 Then
   If Left(Combo1.Text, 7) <> "http://" Then
      Combo1.Text = "http://" + Combo1.Text
   End If
   WebBrowser1.Navigate Combo1.Text         '打开Combo1中的网址
   For I = 0 To Combo1.ListCount - 1
       If Combo1.List(I) = Combo1.Text Then
          existed = True
          Exit For
       Else
          existed = False
       End If
   Next
   If Not existed Then
      Combo1.AddItem (Combo1.Text)
   End If
End If
End Sub
Private Sub Form_Load()                      '窗体加载
Combo1.Text = ""
Combo1.Top = Toolbar1.Height
Combo1.Left = 0
WebBrowser1.Top = Combo1.Top + Combo1.Height
WebBrowser1.Left = 0
Form_Resize
StatusBar1.Style = sbrSimple
ProgressBar1.ZOrder

End Sub
Private Sub Form_Resize()                     '当窗体大小发生改变时，如最大化时
Combo1.Width = Form1.Width - 100
WebBrowser1.Width = Combo1.Width
WebBrowser1.Height = Form1.Height - Combo1.Height - 1000
ProgressBar1.Top = Me.Height - StatusBar1.Height - 330
ProgressBar1.Left = 0.25 * StatusBar1.Width
ProgressBar1.Width = 0.25 * Me.Width - 250

End Sub
Private Sub Toolbar1_ButtonClick(ByVal Button As MSComctlLib.Button) '双击工具栏后输入的代码
On Error Resume Next                          '基本按钮的功能设置
Select Case Button.Key
  Case "Back"                                 '后退按钮
      WebBrowser1.GoBack
  Case "Forward"                              '前进按钮
      WebBrowser1.GoForward
  Case "Refresh"                              '刷新按钮
      WebBrowser1.Refresh
  Case "Home"                                 '主页按钮
      WebBrowser1.GoHome
  Case "Search"                               '搜索按钮
      WebBrowser1.GoSearch
  Case "Stop"                                 '停止按钮
      WebBrowser1.Stop
      Me.Caption = WebBrowser1.LocationName
End Select
End Sub

Private Sub WebBrowser1_DownloadBegin() 
StatusBar1.SimpleText = "Now Linking……"     '下载开始时显示"Now Linking……

End Sub

Private Sub WebBrowser1_DownloadComplete()
StatusBar1.SimpleText = "Link Finished"       '下载结束时显示Link Finished
ProgressBar1.Value = 0
End Sub

Private Sub WebBrowser1_ProgressChange(ByVal Progress As Long, ByVal ProgressMax As Long)
If ProgressMax = 0 Then Exit Sub               '关于Progressbar1的设置
ProgressBar1.Max = ProgressMax
If Progress <> -1 And Progress <= ProgressMax Then
   ProgressBar1.Value = Progress
End If
End Sub

Private Sub WebBrowser1_TitleChange(ByVal Text As String)
    Combo1.Text = WebBrowser1.LocationURL
End Sub