telephone.asm

实现LPC936对电话模块的控制,936是一个51核的处理器,用户通过串口可以控制lpc936的各个功能,是51编程比较完备的范例

;/*
;	telephone.asm
;	cpu  = lpc936
;	Fosc = 11.0592Mhz
;	
;	simulate telephone block:
;		function:
;			1) send & receive dtmf
;			2) monitor switch
;			3) simulate bus
;			4) sample
;			5) uart
;			6) hook operate
;			7) scan ring
;			8) message manage & status report
;	
;	redefine port function:
;	Bit 0    1   2   3    4   5   6    7
;	 P0 -    Md0 Md1 Md2  Md3 Rs0 Wr   Rd
;	 P1 Tx   Rx  Rts Cts  Dsr -   Dtr  -
;	 P2 Tout -   Mon R/To Cs  Irq HK   R/Rg
;	 P3 -    -
;	Describe:
;		Simulate Bus Pin define: Md0~Md3(Data in/out) Rs0(Address out) Wr Rd Cs Irq
;		Uart Function Pin define: Tx(in) Rx(out) Rts(out) Cts(in) Dsr(in) Dtr(out)
;		Telephone Interface Pin define: Tout(AD input) Mon(monitor Switch output)
;						R/To(Tone Signal input=AD input) 
;						HK(hook Switch output)
;						R/Rg(Ring Status input)
;	
;	Copyright For MaRF
;*/


$INCLUDE (REG936.INC)
;//define constant
SAMPLE_SIZE_MASK	EQU	7Fh	;sample buffer size = 128 byte

PHONE_DIAL_SIZE_MASK	EQU	3Fh	;size = 64 byte
PHONE_DIAL_SIZE		EQU	40h

UART_TX_SIZE		EQU	80h	;
UART_TX_SIZE_MASK	EQU	7Fh	;
UART_RX_SIZE		EQU	40h	;
UART_RX_SIZE_MASK	EQU	3Fh	;
UART_RX_HIGH_MASK	EQU	0E0h	;
UART_RX_LOW_MASK	EQU	0F0h	;


MSG_FINISH_DIAL		EQU	40h

MSG_START_SAMPLE	EQU	30h
MSG_STOP_SAMPLE		EQU	31h
MSG_SAMPLE_DATA		EQU	32h
MSG_SET_SAMPLE_INTERVAL	EQU	33h

MSG_START_DIAL		EQU	34h
MSG_STOP_DIAL		EQU	35h
MSG_SET_DIAL_PARAMETER	EQU	36h
MSG_SET_HOLD_PERIOD	EQU	37h
MSG_SET_HOOK_PERIOD	EQU	38h

MSG_HOOK		EQU	39h
MSG_SND_DTMF		EQU	3ah
MSG_STOP_DTMF		EQU	3bh
MSG_MONITOR		EQU	3ch
	
MSG_RING		EQU	3dh
MSG_SYSTEM_TIMER	EQU	3eh
MSG_ERROR		EQU	45h
MSG_BUSY		EQU	42h
MSG_SUCCESS		EQU	53h

CRC_INITIAL		EQU	64h

MSG_RX_SIZE_MASK	EQU	1Fh
MSG_TX_SIZE_MASK	EQU	1Fh

;//Reg Default Value			;bit0                                    bit7
TMOD_VALUE	EQU		01h	;T0M0 T0M1 T0C/T T0GATE T1M0 T1M1 T1C/T T1GATE
TAMOD_VALUE	EQU		00h	;T0M2   -    -      -   T1M2  -     -      -
TLODER		EQU		93FFh	;(FFFF - TLODER)*(2/Fosc) = Timer(10ms)
TENABLE0	EQU		02h	;IEN0.0
TPRIORITYH	EQU		00h	;IP0H.1
TPRIORITYL	EQU		00h	;IP0L.1

UTXENABLE	EQU		40h	;IEN1.6
URXENABLE	EQU		10h	;IEN0.4
UTXPRIORITYH	EQU		00h	;IP1H.0
UTXPRIORITYL	EQU		00h	;IP1L.0
URXPRIORITYH	EQU		00h	;IP0H.4
URXPRIORITYL	EQU		00h	;IP0L.4

SSTAT_VALUE	EQU		60h
SCON_VALUE	EQU		50h
;//Reg Function redefine
phone_dial_counter		data		08h

sample_head		data		09h
sample_tail		data		0ah
sample_counter		data		0bh
sample_interval		data		0ch
sample_length		data		0dh
sample_save		data		0eh

bus_reg			data		0fh

uart_tx_head		data		10h
uart_tx_tail		data		11h
uart_tx_length		data		12h
uart_rx_head		data		13h
uart_rx_tail		data		14h
uart_rx_length		data		15h

dtmf_on_period		data		16h
dtmf_off_period		data		17h
hook_updown_period	data		18h
hold_period		data		19h

phone_dial_head		data		1ah
phone_dial_tail		data		1bh
phone_dial_length	data		1ch
phone_dial_temp		data		1dh

tone_check_period	data		1eh
mute_check_period	data		1fh

time_stamp		data		28h

msg_rece_index		data		2ch
msg_rece_length		data		2dh

msg_send_index		data		2eh
msg_send_length		data		2fh
;//bit function redefine
sample_start_flag	bit		00h

uart_tx_running_flag	bit		01h
uart_enable_term	bit		02h
uart_enable_flow	bit		03h
uart_opened		bit		04h

phone_dial_start	bit		05h
dial_return_ok_flag 	bit		06h
phone_dial_code_flag	bit		07h

phone_tone_check_enable	bit		08h
phone_tone_check_flag	bit		09h

dsr_save_status		bit		0ah
dsr_return_ok_flag	bit		0bh
ring_save_status	bit		0ch
ring_return_ok_flag	bit		0dh

msg_rece_ready_flag	bit		0eh
msg_send_ready_flag	bit		0fh

sample_return_ok_flag	bit		10h
tone_return_ok_flag	bit		11h
;//extern ram redefine
sample_buffer		xdata		0000h

uart_tx_buffer		xdata		0080h
uart_rx_buffer		xdata		00C0h

phone_dial_buffer	xdata		0100h

msg_rece_buffer		xdata		0140h
msg_send_buffer		xdata		0160h

dsr_timer_stamp_buffer	xdata		0180h
ring_timer_stamp_buffer	xdata		0188h
dial_timer_stamp_buffer	xdata		0190h
sample_timer_stamp_buffer xdata		0198h
timer_stamp_buffer	xdata		01a0h
tone_timer_stamp_buffer	xdata		01a8h

;//pin redefine
PHONE_SAMPLE		bit		p2.3
PHONE_HOOK		bit		p2.6
PHONE_RING		bit		p2.7
PHONE_MONITOR		bit		p2.2

UART_RTS		bit		p1.2
UART_CTS		bit		p1.3
UART_DTR		bit		p1.6
UART_DSR		bit		p1.4

BUS_CS			bit		p2.4
BUS_WR			bit		p0.6
BUS_RD			bit		p0.7
BUS_RS0			bit		p0.5
BUS_IRQ			bit		p2.5
BUS_MD0			bit		p0.1
BUS_MD1			bit		p0.2
BUS_MD2			bit		p0.3
BUS_MD3			bit		p0.4

;//
_main:
mov	SP,#80h
mov	PSW,#00h
mov	P0M1,#00h
mov	P0M2,#0FFh
mov	P1M1,#18h	;	00011000
mov	P1M2,#0E5h	;	11100101
mov	P2M1,#00h
mov	P2M2,#00h
mov	P3M1,#00h
mov	P3M2,#01h
anl	TRIM,#3Fh
mov	DIVM,#00h

lcall	_bus_initial
lcall	_package_init
lcall	_uart_initial
lcall	_phone_8889_initial
lcall 	_sample_init
lcall	_dial_init
lcall	_timer_initial
lcall	phone_init
clr	A
lcall	_uart_open
setb	EA
;//主循环
_main_cyc:
lcall	_package_read
lcall	_package_write
lcall	_uart_scan
lcall	_phone_dial
lcall	_msg_proc
lcall	_RING_STATUS_ALARM
lcall	_ring_alarm_return_timer
lcall	_DSR_STATUS_ALARM
lcall	_dsr_status_alarm_return
lcall	_sample_start_return
lcall	_tone_start_return
lcall	_dial_stop_ok
lcall	_SAMPLE_DATA_REBACK
sjmp 	_main_cyc


_package_init:
clr	msg_send_ready_flag
mov	msg_send_length,#00h
mov	msg_send_index,#00h

clr	msg_rece_ready_flag
mov	msg_rece_length,#00h
mov	msg_rece_index,#00h
ret

;/-----------------------
;
;
;10+20*m+(m+1)PC(UART_READ)
;/-----------------------
_package_read:
lcall	_uart_read			;?2
jnc	_package_read_exit		;?2
jnz	$+6h				;?2
setb	msg_rece_ready_flag		;?1
mov	msg_rece_index,#00h		;?2
ret					;?1
push	ACC				;?1
mov	DPTR,#msg_rece_buffer		;?2
mov	A,msg_rece_length		;?1
add	A,DPL				;?1
mov	DPL,A				;?1
pop	ACC				;?1
movx	@DPTR,A				;?2
inc	msg_rece_length			;?1
anl	msg_rece_length,#MSG_RX_SIZE_MASK	;?2
sjmp	_package_read			;2
_package_read_exit:
ret

;/-------------------------
;
;
;
;17*n+11+n*PC(UART_WRITE)，n表示写入多少个字符
;/-------------------------
_package_write:
jb	msg_send_ready_flag,$+4h	;2
ret
_package_write_cyc:
mov	A,msg_send_index		;1
cjne	A,msg_send_length,$+10h		;2	17*n+9+2
mov	msg_send_index,#00h		;2
mov	msg_send_length,#00h		;2
clr	msg_send_ready_flag		;1
ret					;1
mov	DPTR,#msg_send_buffer		;2
mov	A,msg_send_index		;1
add	A,DPL				;1
mov	DPL,A				;1
movx	A,@DPTR				;2
lcall	_uart_write			;2
jc	$+3h				;2
ret					
inc	msg_send_index			;1
sjmp	_package_write_cyc		;2

;//

;//********************************CRC FUNCTION********************************
CRC_TAB:DB 	 00h,  5eh, 0bch, 0e2h,  61h,  3fh, 0ddh,  83h
 	DB	0c2h,  9ch,  7eh,  20h, 0a3h, 0fdh,  1fh,  41h
 	DB	 9dh, 0c3h,  21h,  7fh, 0fch, 0a2h,  40h,  1eh
 	DB	 5fh,  01h, 0e3h, 0bdh,  3eh,  60h,  82h, 0dch
 	DB	 23h,  7dh,  9fh, 0c1h,  42h,  1ch, 0feh, 0a0h
 	DB	0e1h, 0bfh,  5dh,  03h,  80h, 0deh,  3ch,  62h
 	DB	0beh, 0e0h,  02h,  5ch, 0dfh,  81h,  63h,  3dh
 	DB	 7ch,  22h, 0c0h,  9eh,  1dh,  43h, 0a1h, 0ffh
	DB	 46h,  18h, 0fah, 0a4h,  27h,  79h,  9bh, 0c5h
 	DB	 84h, 0dah,  38h,  66h, 0e5h, 0bbh,  59h,  07h
 	DB	0dbh,  85h,  67h,  39h, 0bah, 0e4h,  06h,  58h
 	DB	 19h,  47h, 0a5h, 0fbh,  78h,  26h, 0c4h,  9ah
 	DB	 65h,  3bh, 0d9h,  87h,  04h,  5ah, 0b8h, 0e6h
 	DB	0a7h, 0f9h,  1bh,  45h, 0c6h,  98h,  7ah,  24h
 	DB	0f8h, 0a6h,  44h,  1ah,  99h, 0c7h,  25h,  7bh
 	DB	 3ah,  64h,  86h, 0d8h,  5bh,  05h, 0e7h, 0b9h
 	DB	 8ch, 0d2h,  30h,  6eh, 0edh, 0b3h,  51h,  0fh
 	DB	 4eh,  10h, 0f2h, 0ach,  2fh,  71h,  93h, 0cdh
 	DB	 11h,  4fh, 0adh, 0f3h,  70h,  2eh, 0cch,  92h
 	DB	0d3h,  8dh,  6fh,  31h, 0b2h, 0ech,  0eh,  50h
 	DB	0afh, 0f1h,  13h,  4dh, 0ceh,  90h,  72h,  2ch
 	DB	 6dh,  33h, 0d1h,  8fh,  0ch,  52h, 0b0h, 0eeh
 	DB	 32h,  6ch,  8eh, 0d0h,  53h,  0dh, 0efh, 0b1h
 	DB	0f0h, 0aeh,  4ch,  12h,  91h, 0cfh,  2dh,  73h
 	DB	0cah,  94h,  76h,  28h, 0abh, 0f5h,  17h,  49h
 	DB	 08h,  56h, 0b4h, 0eah,  69h,  37h, 0d5h,  8bh
 	DB	 57h,  09h, 0ebh, 0b5h,  36h,  68h,  8ah, 0d4h
 	DB	 95h, 0cbh,  29h,  77h, 0f4h, 0aah,  48h,  16h
 	DB	0e9h, 0b7h,  55h,  0bh,  88h, 0d6h,  34h,  6ah
 	DB	 2bh,  75h,  97h, 0c9h,  4ah,  14h, 0f6h, 0a8h
 	DB	 74h,  2ah, 0c8h,  96h,  15h,  4bh, 0a9h, 0f7h
 	DB	0b6h, 0e8h,  0ah,  54h, 0d7h,  89h,  6bh,  35h

_crc_calculate:
xrl	A,B
mov	DPTR,#CRC_TAB
movc	A,@A+DPTR
ret

;//********************************End Crc FUNCTION****************************

;//*******************************UART FUNCTION***********************************
;Uart_Baud_Tabl:DB 50h,0B0h,10h,70h,30h,0F0h, 70h,0F0h,0F0h,0F0h ;110592l
;Uart_Baud_Tabh:DB 00h, 00h,01h,01h,02h, 02h, 04h, 08h, 11h, 23h ;110592h
Uart_Baud_Tabl:DB 58h,0C0h,29h,90h,61h, 31h,0D2h,0B4h, 78h, 00h ;120000l
Uart_Baud_Tabh:DB 00h, 00h,01h,01h,02h, 03h, 04h, 09h, 13h, 27h ;120000h

;--------------------
;
;
;--------------------
_uart_initial:
mov	uart_tx_length,#00h
mov	uart_tx_head,#00h
mov	uart_tx_tail,#00h
mov	uart_rx_length,#00h
mov	uart_rx_head,#00h
mov	uart_rx_tail,#00h
clr	uart_opened
clr	uart_tx_running_flag
clr	uart_enable_term
clr	uart_enable_flow
setb	UART_DTR
setb	UART_RTS
mov	SSTAT,#SSTAT_VALUE
mov	SCON,#SCON_VALUE
orl	IP1H,#UTXPRIORITYH
orl	IP1,#UTXPRIORITYL
orl	IP0H,#URXPRIORITYH
orl	IP0,#URXPRIORITYL
ret

;--------------------
;Function	Open Uart
;parameter	ACC=baudrate
;return 	NULL
;--------------------
_uart_open:
anl	A,#0fh
push	ACC
mov	BRGCON,#02h
mov	DPTR,#Uart_Baud_Tabl
movc	A,@A+DPTR
mov	BRGR0,A
pop	ACC
mov	DPTR,#Uart_Baud_Tabh
movc	A,@A+DPTR
mov	BRGR1,A
mov	BRGCON,#03h
clr	uart_tx_running_flag
setb	uart_opened
mov	uart_rx_length,#00h
mov	uart_rx_head,#00h
mov	uart_rx_tail,#00h
orl	IEN1,#UTXENABLE
orl	IEN0,#URXENABLE
clr	UART_RTS
clr	UART_DTR
ret

;--------------------
;
;
;--------------------
_uart_close:
setb	UART_RTS
setb	UART_DTR
mov	A,#UTXENABLE
cpl	A
anl	IEN1,#UTXENABLE
mov	A,#URXENABLE
cpl	A
anl	IEN0,#URXENABLE
mov	uart_tx_head,#00h
mov	uart_tx_tail,#00h
mov	uart_tx_length,#00h
clr	uart_tx_running_flag
clr	uart_opened
clr	uart_enable_flow
clr	uart_enable_term
mov	BRGCON,#02h
ret

;--------------------
;
;18
;--------------------
_uart_write:
push	ACC
mov	A,uart_tx_length		
cjne	A,#UART_TX_SIZE,$+7h
pop	ACC
clr	C
ret
mov	DPTR,#uart_tx_buffer		
mov	A,uart_tx_tail			
add	A,DPL				
mov	DPL,A				
pop	ACC				
movx	@DPTR,A				
inc	uart_tx_tail			
anl	uart_tx_tail,#UART_TX_SIZE_MASK	
inc	uart_tx_length
setb	C
ret

;--------------------
;
;15
;--------------------
_uart_read:
mov	A,uart_rx_length
jnz  	$+4h
clr	C
ret
mov	DPTR,#uart_rx_buffer
mov	A,uart_rx_head
add	A,DPL			
mov	DPL,A			
movx 	A,@DPTR	
inc	uart_rx_head		
anl	uart_rx_head,#UART_RX_SIZE_MASK	
dec	uart_rx_length
setb	C
ret

;--------------------
;
;38
;--------------------
_uart_scan:
jnb	uart_enable_flow,_uart_scan_bursttx
jnb	UART_RTS,_uart_scan_bursttx
mov	A,uart_rx_length
anl	A,#UART_RX_LOW_MASK
jnz	_uart_scan_bursttx
clr	UART_RTS
_uart_scan_bursttx:
jnb	uart_opened,_uart_scan_exit
jb	uart_tx_running_flag,_uart_scan_exit
jnb	uart_enable_term,$+6h
jb	UART_DSR,_uart_scan_exit
jnb	uart_enable_flow,$+6h
jb	UART_CTS,_uart_scan_exit
mov	A,uart_tx_length
jnz	$+4h
sjmp	_uart_scan_exit
mov	DPTR,#uart_tx_buffer
mov	A,uart_tx_head
add	A,DPL
mov	DPL,A
movx	A,@DPTR
setb	uart_tx_running_flag
mov	SBUF,A
inc	uart_tx_head
anl	uart_tx_head,#UART_TX_SIZE_MASK
dec	uart_tx_length
_uart_scan_exit:
ret

;--------------------
;
;35
;--------------------
_uart_rxint:
push	PSW
push	ACC
push	DPL
push	DPH

clr	RI
mov	A,uart_rx_length
cjne	A,#UART_RX_SIZE,$+5h
sjmp	_uart_rxint_flow
mov	DPTR,#uart_rx_buffer
mov	A,uart_rx_tail
add	A,DPL
mov	DPL,A
mov	A,SBUF
movx	@DPTR,A
inc	uart_rx_tail
anl	uart_rx_tail,#UART_RX_SIZE_MASK
inc	uart_rx_length
_uart_rxint_flow:
jnb	uart_enable_flow,_uart_rxint_exit
jb	UART_RTS,_uart_rxint_exit
mov	A,uart_rx_length
anl	A,#UART_RX_HIGH_MASK
jz	_uart_rxint_exit
setb	UART_RTS

_uart_rxint_exit:
pop	DPH
pop	DPL
pop	ACC
pop	PSW
reti

;--------------------
;
;
;37
;--------------------
_uart_txint:
push	PSW
push	ACC
push	DPL
push	DPH

clr	TI

jnb	uart_enable_term,$+6h
jb	UART_DSR,_uart_txint_clrrunflag
jnb	uart_enable_flow,$+6h
jb	UART_CTS,_uart_txint_clrrunflag
mov	A,uart_tx_length
jnz	$+4h
sjmp	_uart_txint_clrrunflag
mov	DPTR,#uart_tx_buffer
mov	A,uart_tx_head
add	A,DPL
mov	DPL,A
movx	A,@DPTR
mov	SBUF,A
inc	uart_tx_head
anl	uart_tx_head,#UART_TX_SIZE_MASK
dec	uart_tx_length
sjmp	$+4h
_uart_txint_clrrunflag:
clr	uart_tx_running_flag