function.asp

与asp相关的技术 如数据库和网页设计 很有用的哦

<%
if session("user_type")<>"T" then
	response.redirect "../../../index.asp"
end if
%>
<%
'该函数用来求出总页数
Function getPageTotal(forumid)
	Dim db
	set db=server.createobject("ADODB.CONNECTION")
	db.open Application("strConn")
	dim rs,strSql
	strSql="Select * From bbs Where forumid=" & forumid
	Set rs=Server.CreateObject("ADODB.Recordset")
	rs.Open strSql,db,1 
	rs.PageSize=15           '每页15条
	getPageTotal=rs.PageCount
	rs.close
	Set rs=Nothing
	db.Close
	Set db=Nothing
End Function

'该函数用来返回id对应的bbsfather字段值
Function getFather(id)
	Dim db
	set db=server.createobject("ADODB.CONNECTION")
	db.open Application("strConn")
	dim rs,strSql
	strSql="Select * From bbs Where id=" & id
	Set rs=db.Execute(strSql)
	getFather=rs("father")
	rs.close
	Set rs=Nothing
	db.Close
	Set db=Nothing
End Function

'该函数用来求出显示页码的最小值
Function minPage(page_no,page_total)
	Dim numTemp
	numTemp=(int((page_no-1)/10))*10+1
	If numTemp<=0 Then 
		numTemp=1
	End If
	minPage=numTemp
End Function

'该函数用来求出显示页码的最大值
Function maxPage(page_no,page_total)
	Dim numTemp
	numTemp=(int((page_no-1)/10))*10+10
	If numTemp>page_total Then 
		numTemp=page_total
	End If
	maxPage=numTemp
End Function

'该函数用来在标题前显示前导空格
Function viewnull(myFather)
	Dim strTemp,numTemp,I,strNull
	strTemp=Split(myFather,"/")
	numTemp=UBound(strTemp)
	If numTemp=1 Then
		strNull="●&nbsp;"
	Else
		For I=0 To numTemp-1
			strNull=strNull & "&nbsp;&nbsp;"
		Next 
		strNull=strNull & "○&nbsp;"
	End If
	viewnull=strNull
End Function

'该函数用来处理客户提交的文本
Function myReplace(myString)
	myString=Replace(myString,"&","&amp;")         '替换&为字符实体&amp;
	myString=Replace(myString,"<","&lt;")          '替换<
	myString=Replace(myString,">","&gt;")          '替换>
	myString=Replace(myString,chr(13),"<br>")      '替换回车符  
	myString=Replace(myString,chr(32),"&nbsp;")    '替换空格符
	myString=Replace(myString,chr(9)," &nbsp; &nbsp; &nbsp; &nbsp;")     '替换Tab缩进符
	myString=Replace(myString,chr(39),"&acute;")       '替换单引号
	myString=Replace(myString,chr(34),"&quot;")        '替换双引号
	myReplace=myString                             '返回函数值
End Function

'该函数用来返回文章的father编号
Function GetFatherCode(bbsid)
	Dim numTemp
	numTemp=1000000000+bbsid
	GetFatherCode=Mid(Cstr(numTemp),2) & "/"
End Function	

'该函数用来返回栏目名称
Function GetForumName(forumid)
	Dim db
	set db=server.createobject("ADODB.CONNECTION")
	db.open Application("strConn")
	dim rs,strSql
	strSql="Select * From bbs_forum Where id=" & forumid
	Set rs=db.Execute(strSql)
	GetForumName=rs("forumname")
	rs.close
	Set rs=Nothing
	db.Close
	Set db=Nothing
End Function	

%>