fractal5.dcl

关于分形的lisp程序.是曼氏分形和Julia分形的合集.

//主对话框fractal.dcl
fractal : dialog {
  key = "ALL";
  label = "参数控制";
  is_cancel = true;
  spacer;
  : row {
    : column {
      : row {
        : column {
          : boxed_radio_column {
            key = "R1";
            label = "图像类型";
            value = "T2";
            : radio_button {
              key = "T1";
              label = "Mandelbrot";
            }
            : radio_button {
              key = "T2";
              label = "Julia";
            }
          }
          : boxed_row {
            label = "迭代次方(选2-6)";
            : slider {
              key = "L1";
              min_value = 2;
              max_value = 6;     
              small_increment = 1;
              big_increment = 1;
              value = 2;
            }
            : text {
              key = "S1";
              value = "2";
            }
          }
        }
        : boxed_row {
          label= "左下角和右上角坐标(绘制范围)";
          : column {
            : edit_box {
              key = "X1";
              label = "X1:";
              value = -1.5;
              width = 27;
            }
            : edit_box {
              key = "Y1";
              label = "Y1:";
              value = -1.5;
            }
            : edit_box {
              key = "X2";
              label = "X2:";
              value = 1.5;
            }
            : edit_box {
              key = "Y2";
              label = "Y2:";
              value = 1.5;
            }
            spacer;
          }
          : column {
            spacer;
            : button {
              key = "P1";
              label= "点取";
            }
            spacer;
          }
        }
      }
      : row {   
        : boxed_column {
          label= "精度控制";
          : edit_box {
            key = "J1";
            label = "迭代次数";
            value = 255;
          }
          : edit_box {
            key = "J2";
            label = "图像像素";
            value = "256 256";
          }
          : edit_box {
            key = "J3";
            label = "逃逸半径";
            value = 20;
          }
          spacer;
        }
        : boxed_column {
          key = "A1";
          label= "Julia集初始值";
          : row {
            : edit_box {
              key = "X0";
              label = "X:";
              value = 0.00;
            }
            : text {
              label= " 如:0.00";
              fixed_width = true;
            }
          }
          : row {
            : edit_box {
              key = "Y0";
              label = "Y:";
              value = 0.66;
            }
            : text {
              label= " 如:0.66";
              fixed_width = true;
            }
          }
          : row {
            : text {
              label = "推荐列表";
            }
            : popup_list {
              key = "L2";
              list = "0.0 0.66\n0.7453 0.11301\n0 1.0\n1.0 0\n-1.0 0\n0 -1.0\n-0.10281 0.95723"
                     "\n-0.76 -0.08\n-0.46 0.57\n-0.12256 0.74486\n-1.16 -0.25\n-1.25 -0.01"
                     "\n-0.199 -0.66\n0.25 0.52\n-0.615 -0.43\n-0.77 0.08\n-0.48176 -0.53163"
                     "\n-0.2 0.75\n0.11 0.66\n0.5 0.55\n0.32 0.04\n0.34 0.45\n-0.618 0.618";
              value = 0;
              width = 19;
            }
          }
          spacer;
        }
      }
      : boxed_radio_row {
        key = "R3";
        label = "逃逸控制";
        value = "T3";
        : radio_button {
          key = "T3";
          label = "标准方式";
        }
        : radio_button {
          key = "T4";
          label = "X 逃逸";
        }
        : radio_button {
          key = "T5";
          label = "Y 逃逸";
        }
        : radio_button {
          key = "T6";
          label = "斑纹";
        }
        : radio_button {
          key = "T7";
          label = "自定义";
          fixed_width = true;
        }
      }
      : boxed_column {
        label = "颜色控制";
        : row { 
          : text {
            label = "渐变方式";
          }
          spacer_1;
          : toggle {
            key = "M1";
            label = "色泽度";
            value = "1";
          }
          : toggle {
            key = "M2";
            label = "饱和度";
          }
          : toggle {
            key = "M3";
            label = "明暗度";
          }
          : toggle {
            key = "M4";
            label = "红绿蓝";
          }
        }
        : row {
          fixed_width = true;
          : edit_box {
            key = "G1";
            label = "颜色梯度";
            width = 22.5;
            fixed_width = true;
            value = 3;
          }
          : button {
            key = "P2";
            label= "初始色";
            fixed_width = true;
          }
          : text {
            key = "C2";
            label = "255 255 255";
          }
          : swatch {
            key = "I1";
            width = 7.5;
            aspect_ratio = 0.4;
            fixed_width = true;
            fixed_height = true;
            color = 7;
          }
        }
        spacer;
      }
    }
    : boxed_column {
      label = "图像预览";
      spacer;
      : image_button {
        key = "I2";
        height = 20;
        aspect_ratio = 1;
        fixed_width = true;
        fixed_height = true;
        alignment = centered;
        color = -2;
      }
      spacer;
      : row {
        fixed_width = true;
        alignment = centered;
        : image_button {
          key = "I3";
          height = 1.5;
          aspect_ratio = 1;
          fixed_width = true;
          fixed_height = true;
          color = -15;
        }
        : slider {
          width = 31;
        }
        : image_button {
          key = "I4";
          height = 1.5;
          aspect_ratio = 1;
          fixed_width = true;
          fixed_height = true;
          color = -15;
        }
      }
      spacer;
      : button {
        key = "P3";
        label = "预览";
        width = 31;
        alignment = centered;
      }
      spacer;
    }
  }
  : row {
    : row {
      width =62;
      fixed_width = true;
      spacer_0;
      : button {
        key = "D1";
        label = "默认参数";
        fixed_width = true;
      }
      : button {
        key = "D2";
        label = "恢复上次";
        fixed_width = true;
      }
      : button {
        key = "D3";
        label = "保存参数";
        fixed_width = true;
      }
      spacer_0;
    }
    ok_cancel_help;
  } 
}