userlist.asp

来自「flashchat 基于flash的聊天室」· ASP 代码 · 共 49 行

<%@Language = "VBScript"%>
<%
Option Explicit
Response.Buffer = True
Response.Expires = -1000

Dim vChatUsers, vChatMoods, vUser, vUserCount, vResult, vThisUser
Dim vRoomNo, vMyName, vDisplayedUserCount

vRoomNo = Session("RoomNo")
vMyName = Session("ChatName")

vUserCount = Application("UserCount" & vRoomNo)
If vUserCount > 0 Then
	vChatUsers = Application("ChatUsers" & vRoomNo)
	vChatMoods = Application("ChatMoods" & vRoomNo)
	For vUser = 0 To vUserCount - 1
		vThisUser = vChatUsers(vUser)
		If vThisUser = vMyName & "[kicked]" Then
			Session("Kicked") = "True"
			Session("ChatName") = vMyName & "[kicked]"
			Response.Write "Result=Kicked"
			Response.Flush
			Response.End
		ElseIf vThisUser = vMyName & "[banned]" Then
			Session("Kicked") = "True"
			Session("ChatName") = vMyName & "[banned]"
			Response.Cookies("BannedFromChat") = "True"
			Response.Cookies("BannedFromChat").Expires = "January 1, 2030"
			Response.Write "Result=Kicked"
			Response.Flush
			Response.End
		Else
			If Instr(vThisUser,"[kicked]") = 0 And Instr(vThisUser,"[banned]") = 0 Then
				vDisplayedUserCount = vDisplayedUserCount + 1
				vResult = vResult & "User" & vDisplayedUserCount & "=" & vThisUser & "&"
				vResult = vResult & "Mood" & vDisplayedUserCount & "=" & vChatMoods(vUser) & "&"
			End If
		End If
	Next
	vResult = vResult & "UserCount=" & vDisplayedUserCount
Else
	vResult = "UserCount=0"
End If
Response.Write vResult & "&Me=" & Session("ChatName") & "&Result=OK&Room=" & Session("RoomNo")
Response.Flush
Response.End
%>