📄 addscore.asp

📁 (1)开发学生成绩管理系统的总体任务是实现企学生管理的系统化和自动化.学生管理为学校提供学生质料管理,课程设置管理,成绩数据管理,访问权限管理等,为学生提供了方便的个人信息查询等. (2)本系统的主

💻 ASP

字号:

<% @ LANGUAGE = "VBScript" %>
<HTML>
<HEAD>
<TITLE>录入成绩</TITLE>
<STYLE>
P, TABLE, INPUT, SELECT{FONT-SIZE: 9pt}
</STYLE>
</HEAD>
<BODY>
<%
If Session("UserName") = "" Or Session("Level") < 2 Then
  Response.Write "你没有访问本页面的权限！"
  Response.End
End If
%>
<P><A HREF = "index.asp">返回首页</A>|
<A HREF = "editscore.asp">修改成绩</A>|
<A HREF = "deletescore1.asp">删除成绩</A>|
<A HREF="browsescore.asp">查询成绩</A></P>
<DIV ALIGN = "center">
<!-- #include virtual = "/adovbs.inc" -->
<%
Dim cnn, rstSt, rstCo, rstSc, sSQL
' 定义函数chk，当参数e为True时返回字符串“SELECTED”
Function chk( e )
  If e = True Then
    chk = " SELECTED "
  End If
End Function
Set cnn = Server.CreateObject("ADODB.Connection")
Set rstSt = Server.CreateObject("ADODB.Recordset")
Set rstCo = Server.CreateObject("ADODB.Recordset")
Set rstSc = Server.CreateObject("ADODB.Recordset")
cnn.ConnectionString = "PROVIDER=SQLOLEDB;DATA SOURCE=g6;" & _
  "UID=sa;;DATABASE=test"
cnn.Open
Set rstSt = cnn.Execute("SELECT * FROM students " & _
  " ORDER BY student_num", , adCmdText) 
Set rstCo = cnn.Execute("courses", , adCmdTable)
StudentID = CInt(Request.Form("lstStudentID"))
CourseID = CInt(Request.Form("lstCourseID"))
Score = Trim(Request.Form("txtScore"))
If rstSt.EOF And rstCo.EOF Then
%>
<P><FONT COLOR="red">学生表和课程表为空，请先录入学生资料和课程设置数据！</FONT></P>
<% Else %>
<FORM METHOD="post" ACTION="addscore.asp">
<TABLE BGCOLOR = "#D6D3CE" CELLSPACING = "3" CELLPADDING = "3" WIDTH = "378">
<TR>
<TH COLSPAN = "2" BGCOLOR = "#0034FF">
<FONT COLOR = "#FFFFFF">录入成绩</FONT></TH>
</TR>
<TR>
<TD WIDTH = "30%" ALIGN = "right">学生：</TD>
<TD><SELECT SIZE = "1" NAME = "lstStudentID">
<% While Not rstSt.EOF %>
<OPTION <% = chk(StudentID = rstSt("student_id")) %>
VALUE=<% = rstSt("student_id") %>>
<% = rstSt("student_num") %>－<% = rstSt("student_name") %></OPTION>
<%
  rstSt.MoveNext
  Wend
%>
</SELECT></TD>
</TR>
<TR>
<TD WIDTH = "30%" ALIGN = "right">课程：</TD>
<TD><SELECT SIZE = "1" NAME = "lstCourseID">
<% While Not rstCo.EOF %>   
<OPTION <% = chk(CourseID = rstCo("course_id")) %> 
VALUE=<% = rstCo("course_id") %>>
<% = rstCo("course_id") %>－<% = rstCo("course_name") %></OPTION>
<%
  rstCo.MoveNext
  Wend
%>
</SELECT>
</TD>
</TR>
<TR>
<TD WIDTH = "30%" ALIGN = "right">成绩：</TD>
<TD><INPUT TYPE = "text" NAME = "txtScore" SIZE = "22"></TD>
</TR>
<TR ALIGN = "center">
<TD COLSPAN = "2"><INPUT TYPE = "submit" VALUE = "保存成绩" 
NAME = "btnSave">&nbsp;
<INPUT TYPE = "reset" VALUE = "全部重写" NAME = "btnReset"></TD>
</TR>
</TABLE>
</FORM>
<% End If %>
<%
If Score <> "" Then 
  sSQL = "SELECT * FROM scores WHERE student_id=" & StudentID & _
    " AND course_id=" & CourseID
  Set rstSc = cnn.Execute(sSQL, , adCmdText)
  If Not rstSc.EOF Then
%>
<HR NOSHADE SIZE = "1" COLOR ="red">
<P><FONT COLOR = "red">这门课程成绩已经存在，若要修改，请单击“修改成绩”链接！
</FONT></P>
<%
Else
  sSQL = "INSERT  into scores(student_id, course_id, score) VALUES("
  sSQL = sSQL & StudentID & "," & CourseID & "," & CDbl(Score) & ")"
  cnn.Execute sSQL, , adCmdText
%>
<HR NOSHADE SIZE="1" COLOR="red"><P><B>成绩保存成功！</B></P>
<% End If %>
<% End If %>
</DIV>
</BODY>
</HTML>

⌨️ 快捷键说明

复制代码 Ctrl + C

搜索代码 Ctrl + F

全屏模式 F11

切换主题 Ctrl + Shift + D

显示快捷键 ?

增大字号 Ctrl + =

减小字号 Ctrl + -